reserve            x for object,
               X,Y,Z for set,
         i,j,k,l,m,n for Nat,
                 r,s for Real,
                  no for Element of OrderedNAT,
                   A for Subset of [:NAT,NAT:];
reserve X,Y,X1,X2 for non empty set,
          cA1,cB1 for filter_base of X1,
          cA2,cB2 for filter_base of X2,
              cF1 for Filter of X1,
              cF2 for Filter of X2,
             cBa1 for basis of cF1,
             cBa2 for basis of cF2;
reserve T for non empty TopSpace,
        s for Function of [:NAT,NAT:], the carrier of T,
        M for Subset of the carrier of T;
reserve cF3,cF4 for Filter of the carrier of T;
reserve Rseq for Function of [:NAT,NAT:],REAL;
reserve f for Function of [#]OrderedNAT,R^1,
        seq for Function of NAT,REAL;
reserve Y for non empty TopSpace,
        x for Point of Y,
        f for Function of [:X1,X2:],Y;

theorem Th79:
  for Y being Hausdorff regular non empty TopSpace,
  f being Function of [:X1,X2:],Y st (for x being Element of X1 holds
  lim_filter(ProjMap1(f,x),cF2) <> {}) holds
  lim_filter(f,<.cF1,cF2.)) c= lim_filter(lim_in_cod2(f,cF2),cF1)
  proof
    let Y be Hausdorff regular non empty TopSpace,
        f be Function of [:X1,X2:],Y;
    assume
A1: for x1 being Element of X1 holds lim_filter(ProjMap1(f,x1),cF2) <> {};
    now
      let y0 be object;
      assume
A2:   y0 in lim_filter(f,<.cF1,cF2.));
      then reconsider y = y0 as Element of Y;
      consider cB1 be filter_base of X1 such that
      cB1 = cF1 and
A3:   <.cB1.) = cF1 by Th18;
      consider cB2 be filter_base of X2 such that
      cB2 = cF2 and
A4:   <.cB2.) = cF2 by Th18;
A5:   for U being a_neighborhood of y st U is closed holds
      ex B1 be Element of cB1, B2 be Element of cB2 st
      for z be Element of B1 holds lim_filter(ProjMap1(f,z),cF2) c= Cl Int U
      proof
        let U be a_neighborhood of y;
        assume U is closed;
        then consider B1 be Element of cB1, B2 be Element of cB2 such that
A6:     for z be Element of X1, t be Element of Y st z in B1 &
        t in lim_filter(ProjMap1(f,z),cF2) holds t in Cl Int U
          by A3,A4,A2,Th76;
        take B1,B2;
        thus thesis by A6;
      end;
      NeighborhoodSystem y c= filter_image(lim_in_cod2(f,cF2),cF1)
      proof
        let n be object;
        assume n in NeighborhoodSystem y;
        then n in the set of all A where A is a_neighborhood of y
          by YELLOW19:def 1;
        then consider A be a_neighborhood of y such that
A7:     n = A;
        y in Int A by CONNSP_2:def 1;
        then consider Q be Subset of Y such that
A8:     Q is closed and
A9:     Q c= A and
A10:    y in Int Q by YELLOW_8:27;
        Q is a_neighborhood of y by A10,CONNSP_2:def 1;
        then consider B1 be Element of cB1,B2 be Element of cB2 such that
A11:    for z be Element of B1 holds
          lim_filter(ProjMap1(f,z),cF2) c= Cl Int Q by A8,A5;
A12:    Cl Q = Q by PRE_TOPC:18,A8,TOPS_1:5;
A13:    Cl Int Q c= Cl Q by TOPS_1:16,PRE_TOPC:19;
        reconsider n1 = n as Subset of Y by A7;
        now
          lim_in_cod2(f,cF2).:B1 c= n1
          proof
            let t be object;
            assume t in lim_in_cod2(f,cF2).:B1;
            then consider u be object such that
A14:        u in dom lim_in_cod2(f,cF2) and
A15:        u in B1 and
A16:        t = lim_in_cod2(f,cF2).u by FUNCT_1:def 6;
            reconsider u1 = u as Element of X1 by A14;
            {t} = lim_filter(ProjMap1(f,u1),cF2) by A16,A1,Def7; then
A17:        t in lim_filter(ProjMap1(f,u1),cF2) by TARSKI:def 1;
            lim_filter(ProjMap1(f,u1),cF2) c= Cl Int Q by A11,A15;
            hence thesis by A7,A17,A13,A12,A9;
          end;
          hence B1 c= lim_in_cod2(f,cF2)"(n1) by FUNCT_2:95;
          dom lim_in_cod2(f,cF2) = X1 by FUNCT_2:def 1;
          hence lim_in_cod2(f,cF2)"(n1) is Subset of X1 by RELAT_1:132;
        end;
        then lim_in_cod2(f,cF2)"(n1) in cF1 by A3,CARDFIL2:def 8;
        hence thesis;
      end;
      then filter_image(lim_in_cod2(f,cF2),cF1)
        is_filter-finer_than NeighborhoodSystem y;
      hence y0 in lim_filter(lim_in_cod2(f,cF2),cF1);
    end;
    hence thesis;
  end;
