reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;
reserve y for set,
  H19,H29 for StableSubgroup of G,
  N19 for normal StableSubgroup of H19,
  s1,s19,s2,s29 for CompositionSeries of G,
  fs for FinSequence of the_stable_subgroups_of G,
  f1,f2 for FinSequence,
  i,j,n for Nat;

theorem Th100:
  len s1 > 1 & s2<>s1 & s2 is strictly_decreasing & s2
is_finer_than s1 implies ex i,j st i in dom s1 & i in dom s2 & i+1 in dom s1 &
i+1 in dom s2 & j in dom s2 & i+1<j & s1.i=s2.i & s1.(i+1)<>s2.(i+1) & s1.(i+1)
  =s2.j
proof
  assume len s1 > 1;
  then len s1 >= 1+1 by NAT_1:13;
  then Seg 2 c= Seg len s1 by FINSEQ_1:5;
  then
A1: Seg 2 c= dom s1 by FINSEQ_1:def 3;
  assume
A2: s2<>s1;
  assume
A3: s2 is strictly_decreasing;
  assume
A4: s2 is_finer_than s1;
  then consider n such that
A5: len s2 = len s1 + n by Th95;
  n<>0 by A2,A4,A5,Th96;
  then
A6: 0 + len s1 < n + len s1 by XREAL_1:6;
  then Seg len s1 c= Seg len s2 by A5,FINSEQ_1:5;
  then Seg len s1 c= dom s2 by FINSEQ_1:def 3;
  then
A7: dom s1 c= dom s2 by FINSEQ_1:def 3;
  now
    set fX = {k where k is Element of NAT: k in dom s1 & s1.k=s2.k};
A8: 1 in Seg 2;
    s1.1 = (Omega).G & s2.1 = (Omega).G by Def28;
    then
A9: 1 in fX by A1,A8;
    now
      let x be object;
      assume x in fX;
      then ex k be Element of NAT st x=k & k in dom s1 & s1.k=s2.k;
      hence x in dom s1;
    end;
    then fX c= dom s1;
    then reconsider fX as finite non empty real-membered set by A9;
    set i = max fX;
    i in fX by XXREAL_2:def 8;
    then
A10: ex k be Element of NAT st i=k & k in dom s1 & s1.k=s2.k;
    then reconsider i as Element of NAT;
    take i;
    thus i in dom s1 & s1.i=s2.i by A10;
A11: now
      assume not i+1 in dom s1;
      then
A12:  not i+1 in Seg len s1 by FINSEQ_1:def 3;
      per cases by A12;
      suppose
        1>i+1;
        then 1-1>i+1-1 by XREAL_1:9;
        then 0>i;
        hence contradiction;
      end;
      suppose
A13:    i+1>len s1;
        i in Seg len s1 by A10,FINSEQ_1:def 3;
        then
A14:    i<=len s1 by FINSEQ_1:1;
        i>=len s1 by A13,NAT_1:13;
        then
A15:    i=len s1 by A14,XXREAL_0:1;
        then 0+1<=i+1 & i+1<=len s2 by A5,A6,NAT_1:13;
        then i+1 in Seg len s2;
        then
A16:    i+1 in dom s2 by FINSEQ_1:def 3;
        then reconsider
        H1=s2.i,H2=s2.(i+1) as Element of the_stable_subgroups_of G
        by A10,FINSEQ_2:11;
        reconsider H1,H2 as StableSubgroup of G by Def11;
A17:    s2.i=(1).G by A10,A15,Def28;
        then
A18:    the carrier of H1 = {1_G} by Def8;
        reconsider H2 as normal StableSubgroup of H1 by A7,A10,A16,Def28;
        1_G in H2 by Lm17;
        then 1_G in the carrier of H2 by STRUCT_0:def 5;
        then
A19:    {1_G} c= the carrier of H2 by ZFMISC_1:31;
        H2 is Subgroup of (1).G by A17,Def7;
        then the carrier of H2 c= the carrier of (1).G by GROUP_2:def 5;
        then the carrier of H2 c= {1_G} by Def8;
        then the carrier of H2 = {1_G} by A19,XBOOLE_0:def 10;
        then H1./.H2 is trivial by A18,Th77;
        hence contradiction by A3,A7,A10,A16;
      end;
    end;
    hence i+1 in dom s1;
    now
A20:  1+i>0+i by XREAL_1:6;
      assume s1.(i+1)=s2.(i+1);
      then consider k be Element of NAT such that
A21:  k>i and
A22:  k in dom s1 & s1.k=s2.k by A11,A20;
      k in fX by A22;
      hence contradiction by A21,XXREAL_2:def 8;
    end;
    hence s1.(i+1)<>s2.(i+1);
  end;
  then consider i such that
A23: i in dom s1 and
A24: i+1 in dom s1 and
A25: s1.i=s2.i and
A26: s1.(i+1)<>s2.(i+1);
  now
    consider x such that
A27: x c= dom s2 and
A28: s1 = s2 * Sgm x by A4;
    set j = (Sgm x).(i+1);
A29: x c= Seg len s2 by A27,FINSEQ_1:def 3;
     then
a29: x is included_in_Seg;
A30: i+1 in dom Sgm x by A24,A28,FUNCT_1:11;
    then j in rng Sgm x by FUNCT_1:3;
    then j in x by a29,FINSEQ_1:def 14;
    then
A31: j in Seg len s2 by A29;
    then reconsider j as Element of NAT;
A32: i+1 <= j by a29,A30,FINSEQ_3:152;
    take j;
    thus j in dom s2 by A31,FINSEQ_1:def 3;
    thus s1.(i+1)=s2.j by A24,A28,FUNCT_1:12;
    j<>i+1 by A24,A26,A28,FUNCT_1:12;
    hence i+1<j by A32,XXREAL_0:1;
  end;
  then consider j such that
A33: j in dom s2 & i+1<j and
A34: s1.(i+1)=s2.j;
  take i,j;
  thus i in dom s1 & i in dom s2 by A7,A23;
  thus i+1 in dom s1 & i+1 in dom s2 by A7,A24;
  thus j in dom s2 & i+1<j by A33;
  thus s1.i=s2.i & s1.(i+1)<>s2.(i+1) by A25,A26;
  thus thesis by A34;
end;
