reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th100:
  for x be Surreal ex r be non-zero Sequence of REAL,
      y be strictly_decreasing uSurreal-Sequence st
         dom r = dom y c= born_eq x & Sum(r,y) == x
proof
  let x be Surreal;
  ex r be non-zero Sequence of REAL,
    y be strictly_decreasing uSurreal-Sequence st dom r = dom y &
      r,y,dom r name_like x & Sum(r,y) == x
  proof
    assume
A1: for r be non-zero Sequence of REAL,
    y be strictly_decreasing uSurreal-Sequence st dom r = dom y &
    r,y,dom r name_like x holds not Sum(r,y) == x;
    set b= card bool succ born_eq x;
    consider r be non-zero Sequence of REAL,
      y be strictly_decreasing uSurreal-Sequence such that
A2: dom r = succ b = dom y &
    r,y,succ b name_like x by A1,Th95;
    set s = Partial_Sums(r,y);
A3: dom s = succ (succ b/\succ b) by A2,Def17
    .= succ succ b;
    s,y,r simplest_up_to dom s by Def17;
    then s,y,r simplest_up_to succ (succ b/\succ b) by A2,Def17;
    then rng born (s|succ  succ b) c= succ born_eq x by A2,Th88,Th98;
    then
A4: card rng born s c= card succ born_eq x by A3,CARD_1:11;
    born s is one-to-one by CARD_5:11;
    then
A5: card rng born s = card dom born s by CARD_1:5,WELLORD2:def 4
    .= card succ succ b by A3,Def20;
A6: card succ succ b in b by A4,A5,CARD_1:14,ORDINAL1:12;
    b in succ succ b by ORDINAL1:6,8;
    then b c= succ succ b by ORDINAL1:def 2;
    then b= card b in b by A6,ORDINAL1:12,CARD_1:11;
    hence thesis;
  end;
  then consider r be non-zero Sequence of REAL,
  y be strictly_decreasing uSurreal-Sequence such that
A7:dom r = dom y & r,y,dom r name_like x & Sum(r,y) == x;
  take r,y;
  born Sum(r,y) = born_eq Sum(r,y) = born_eq x by A7,SURREALO:33,48;
  hence thesis by A7,Th99;
end;
