reserve U for Universe;
reserve x for Element of U;
reserve U1,U2 for Universe;

theorem Th104:
  Funcs U is U-Class
  proof
A1: Funcs U c< U by Th103;
A2:
    now
      let x be Element of U;
      set FAB = {Funcs(A,B) where A, B is Element of U : not contradiction};
      id {x} in Funcs({x},{x}) in FAB;
      then id {x} in union FAB by TARSKI:def 4;
      hence {[x,x]} in Funcs U by SYSREL:13;
    end;
A3: the set of all {[x,x]} where x is Element of U c= Funcs U
    proof
      let o be object;
      assume o in the set of all {[x,x]} where x is Element of U;
      then ex x be Element of U st o = {[x,x]};
      hence thesis by A2;
    end;
A4: union the set of all {[x,x]} where x is Element of U
      = the set of all [x,x] where x is Element of U
    proof
      now
        let o be object;
        assume o in union the set of all {[x,x]} where x is Element of U;
        then consider y be set such that
A5:     o in y in the set of all {[x,x]} where x is Element of U
          by TARSKI:def 4;
        consider x be Element of U such that
A6:     y = {[x,x]} by A5;
        o = [x,x] by A6,A5,TARSKI:def 1;
        hence o in the set of all [x,x] where x is Element of U;
      end;
      hence union the set of all {[x,x]} where x is Element of U
        c= the set of all [x,x] where x is Element of U;
      now
        let o be object;
        assume o in the set of all [x,x] where x is Element of U;
        then consider x be Element of U such that
A7:     o = [x,x];
A8:     o in {[x,x]} by A7,TARSKI:def 1;
        {[x,x]} in the set of all {[x,x]} where x is Element of U;
        hence o in union the set of all {[x,x]} where x is Element of U
          by A8,TARSKI:def 4;
      end;
      hence the set of all [x,x] where x is Element of U c=
        union the set of all {[x,x]} where x is Element of U;
    end;
    now
      assume Funcs U in U;
      then the set of all {[x,x]} where x is Element of U in U
        by A3,CLASSES4:13;
      then reconsider SU = the set of all [x,x] where x is Element of U as
        Element of U by A4,CLASSES2:59;
      proj1 SU = U
      proof
        hereby
          let o be object;
          assume o in proj1 SU;
          then consider o9 be object such that
A9:       [o,o9] in SU by XTUPLE_0:def 12;
          consider x be Element of U such that
A10:      [o,o9] = [x,x] by A9;
          o = x by A10,XTUPLE_0:1;
          hence o in U;
        end;
        let o be object;
        assume o in U;
        then reconsider x = o as Element of U;
        [x,x] in SU;
        hence o in proj1 SU by XTUPLE_0:def 12;
      end;
      then U is Element of U by CLASSES4:36;
      then U in U;
      hence contradiction;
    end;
    hence thesis by A1;
  end;
