
theorem Th102:
  for G1, G2 being _Graph
  for G3 being SimpleGraph of G1, G4 being SimpleGraph of G2
  for G5 being GraphComplement of G1, G6 being GraphComplement of G2
  st G4 is G3-isomorphic holds G6 is G5-isomorphic
proof
  let G1, G2 be _Graph;
  let G3 be SimpleGraph of G1, G4 be SimpleGraph of G2;
  let G5 be GraphComplement of G1, G6 be GraphComplement of G2;
  A1: G5 is GraphComplement of G3 & G6 is GraphComplement of G4 by Th101;
  assume G4 is G3-isomorphic;
  then consider f being PVertexMapping of G3, G4 such that
    A2: f is isomorphism by GLIB_011:49;
  A3: the_Vertices_of G3 = the_Vertices_of G5 &
    the_Vertices_of G4 = the_Vertices_of G6 by A1, Th98;
  then reconsider g = f as PartFunc of the_Vertices_of G5, the_Vertices_of G6;
  now
    let v,w,e be object;
    assume A4: v in dom g & w in dom g & e Joins v,w,G5;
    then A5: v <> w by GLIB_000:18;
    then A6: g.v <> g.w by A2, A4, FUNCT_1:def 4;
    A7: not ex e3 being object st e3 Joins v,w,G3
      by A1, A3, A4, A5, Th98;
    thus ex e6 being object st e6 Joins g.v,g.w,G6
    proof
      assume A8: not ex e6 being object st e6 Joins g.v,g.w,G6;
      g.v in rng f & g.w in rng f by A4, FUNCT_1:3;
      then consider e4 being object such that
        A9: e4 Joins g.v,g.w,G4 by A1, A6, A8, Th98;
      consider e3 being object such that
        A10: e3 Joins v,w,G3 by A2, A4, A9, GLIB_011:2;
      thus contradiction by A7, A10;
    end;
  end;
  then reconsider g as PVertexMapping of G5, G6 by GLIB_011:1;
  now
    let v,w,e6 be object;
    assume A11: v in dom g & w in dom g & e6 Joins g.v,g.w,G6;
    then A12: g.v <> g.w by GLIB_000:18;
    A13: v in the_Vertices_of G3 & w in the_Vertices_of G3 by A3, A11;
    g.v in rng f & g.w in rng f by A11, FUNCT_1:3;
    then A14: not ex e4 being object st e4 Joins g.v,g.w,G4
      by A1, A11, A12, Th98;
    thus ex e5 being object st e5 Joins v,w,G5
    proof
      assume not ex e5 being object st e5 Joins v,w,G5;
      then consider e3 being object such that
        A15: e3 Joins v,w,G3 by A1, A12, A13, Th98;
      consider e4 being object such that
        A16: e4 Joins f.v,f.w,G4 by A11, A15, GLIB_011:1;
      thus contradiction by A14, A16;
    end;
  end;
  then g is continuous by GLIB_011:2;
  hence thesis by A2, A3, GLIB_011:49;
end;
