reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;
reserve y for set,
  H19,H29 for StableSubgroup of G,
  N19 for normal StableSubgroup of H19,
  s1,s19,s2,s29 for CompositionSeries of G,
  fs for FinSequence of the_stable_subgroups_of G,
  f1,f2 for FinSequence,
  i,j,n for Nat;

theorem Th102:
  y in rng the_series_of_quotients_of s1 implies y is strict
  GroupWithOperators of O
proof
  assume
A1: y in rng the_series_of_quotients_of s1;
  set f1=the_series_of_quotients_of s1;
A2: len f1 = 0 or len f1 >= 0+1 by NAT_1:13;
  per cases by A2;
  suppose
    len f1 = 0;
    then f1 = {};
    hence thesis by A1;
  end;
  suppose
    len f1 >= 1;
    then
A3: len s1 > 1 by Def33,CARD_1:27;
    then
A4: len s1 = len f1 + 1 by Def33;
    consider i be object such that
A5: i in dom f1 and
A6: f1.i=y by A1,FUNCT_1:def 3;
    reconsider i as Nat by A5;
A7: i in Seg len f1 by A5,FINSEQ_1:def 3;
    then
A8: 1<=i by FINSEQ_1:1;
    1<=i by A7,FINSEQ_1:1;
    then 1+1<=i+1 by XREAL_1:6;
    then
A9: 1<=i+1 by XXREAL_0:2;
A10: i<=len f1 by A7,FINSEQ_1:1;
    then 0+i<=1+i & i+1<=len f1 + 1 by XREAL_1:6;
    then i<=len s1 by A4,XXREAL_0:2;
    then i in Seg len s1 by A8;
    then
A11: i in dom s1 by FINSEQ_1:def 3;
    then s1.i in the_stable_subgroups_of G by FINSEQ_2:11;
    then reconsider H1=s1.i as strict StableSubgroup of G by Def11;
    i + 1<=len f1 + 1 by A10,XREAL_1:6;
    then i+1<=len s1 by A3,Def33;
    then i+1 in Seg len s1 by A9;
    then
A12: i+1 in dom s1 by FINSEQ_1:def 3;
    then s1.(i+1) in the_stable_subgroups_of G by FINSEQ_2:11;
    then reconsider N1=s1.(i+1) as strict StableSubgroup of G by Def11;
    reconsider N1 as normal StableSubgroup of H1 by A11,A12,Def28;
    y = H1./.N1 by A3,A5,A6,Def33;
    hence thesis;
  end;
end;
