
theorem Th102:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`1=a & p2`1=b
& p3`1= b & p4`2= c & c <=p1`2 & p1`2<=d & c <=p3`2 & p3`2<p2`2 & p2`2<=d & a<
p4`1 & p4`1<=b & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous one-to-one
  & g is continuous one-to-one & rng f c= closed_inside_of_rectangle(a,b,c,d) &
  rng g c= closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`1=a and
A4: p2`1=b and
A5: p3`1= b and
A6: p4`2= c and
A7: c <=p1`2 and
A8: p1`2<=d and
A9: c <=p3`2 and
A10: p3`2<p2`2 and
A11: p2`2<=d and
A12: a<p4`1 and
A13: p4`1<=b and
A14: f.0=p1 and
A15: f.1=p3 and
A16: g.0=p2 and
A17: g.1=p4 and
A18: f is continuous one-to-one and
A19: g is continuous one-to-one and
A20: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A21: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A22: -1 <=((f2).O)`2 by A2,A7,A8,A14,Th60;
A23: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A20,Th52;
  d-c >0 by A2,XREAL_1:50;
  then
A24: C >0 by XREAL_1:139;
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A25: ((g2).I)`1> -1 by A1,A2,A6,A12,A13,A17,Th66;
A26: ((g2).O)`1= 1 by A1,A4,A16,Th56;
A27: g2 is continuous one-to-one by A1,A2,A19,Th53;
  p2`2> c by A9,A10,XXREAL_0:2;
  then
A28: 1 >=((g2).O)`2 by A1,A2,A4,A11,A16,Th66;
  set x = the Element of rng f2 /\ rng g2;
A29: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A30: h.p3=f2.I by A15,FUNCT_1:13;
A31: ((f2).O)`2<=1 by A2,A7,A8,A14,Th60;
A32: f2 is continuous one-to-one by A1,A2,A18,Th53;
  b-a>0 by A1,XREAL_1:50;
  then
A33: A >0 by XREAL_1:139;
  then h is being_homeomorphism by A24,Th50;
  then
A34: h is one-to-one by TOPS_2:def 5;
A35: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then h.p2=g2.O by A16,FUNCT_1:13;
  then
A36: ((g2).O)`2> ((f2).I)`2 by A10,A33,A24,A30,Th51;
  p3`2 < d by A10,A11,XXREAL_0:2;
  then
A37: -1<=((f2).I)`2 by A2,A9,A15,Th60;
A38: ((f2).I)`1= 1 by A1,A5,A15,Th56;
A39: ((f2).O)`1= -1 by A1,A3,A14,Th54;
A40: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A21,Th52;
A41: ((g2).I)`2= -1 by A2,A6,A17,Th57;
  1>=((g2).I)`1 by A1,A2,A6,A12,A13,A17,Th66;
  then rng f2 meets rng g2 by A32,A39,A38,A22,A31,A37,A23,A27,A26,A41,A28,A25
,A40,A36,Th31,JGRAPH_6:79;
  then
A42: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng g2 by XBOOLE_0:def 4;
  then consider z2 being object such that
A43: z2 in dom g2 and
A44: x=g2.z2 by FUNCT_1:def 3;
A45: x=h.(g.z2) by A35,A43,A44,FUNCT_1:13;
A46: g.z2 in rng g by A35,A43,FUNCT_1:def 3;
  g.z2 in the carrier of TOP-REAL 2 by A43,FUNCT_2:5;
  then
A47: g.z2 in dom h by FUNCT_2:def 1;
  x in rng f2 by A42,XBOOLE_0:def 4;
  then consider z1 being object such that
A48: z1 in dom f2 and
A49: x=f2.z1 by FUNCT_1:def 3;
A50: f.z1 in rng f by A29,A48,FUNCT_1:def 3;
  f.z1 in the carrier of TOP-REAL 2 by A48,FUNCT_2:5;
  then
A51: f.z1 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A29,A48,A49,FUNCT_1:13;
  then f.z1=g.z2 by A45,A51,A47,A34,FUNCT_1:def 4;
  hence thesis by A50,A46,XBOOLE_0:3;
end;
