reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th86:
  for f being FinSequence of TOP-REAL 2 holds L~f is boundary
proof
  let f be FinSequence of TOP-REAL 2;
A1: L~f=union { LSeg(f,i) : 1 <= i & i+1 <= len f } by TOPREAL1:def 4;
  defpred P[Nat] means
 for R1 being Subset of TOP-REAL 2 st R1=
  union { LSeg(f,i) : 1 <= i & i+1 <= $1 } holds R1 is boundary;
A2: for k being Nat st P[k] holds P[k+1]
  proof
    let k be Nat;
A3: now
      per cases;
      case
        1<=k & k+1<=len f;
        then LSeg(f,k)=LSeg(f/.k,f/.(k+1)) by TOPREAL1:def 3;
        hence LSeg(f,k) is boundary;
      end;
      case
        not(1<=k & k+1<=len f);
        then LSeg(f,k)={} by TOPREAL1:def 3;
        hence LSeg(f,k) is boundary;
      end;
    end;
    union { LSeg(f,i2) : 1 <= i2 & i2+1 <= k } c= the carrier of TOP-REAL 2
    proof
      let z be object;
      assume z in union { LSeg(f,i2) : 1 <= i2 & i2+1 <= k };
      then consider x being set such that
A4:   z in x & x in { LSeg(f,i) : 1 <= i & i+1 <= k } by TARSKI:def 4;
      ex i st x=LSeg(f,i) & 1 <= i & i+1 <= k by A4;
      hence thesis by A4;
    end;
    then reconsider R3=union { LSeg(f,i2) : 1 <= i2 & i2+1 <= k } as Subset of
    TOP-REAL 2;
    assume for R1 being Subset of TOP-REAL 2 st R1=union { LSeg(f,i) : 1 <= i
    & i+1 <= k } holds R1 is boundary;
    then
A5: R3 is boundary;
    thus for R2 being Subset of TOP-REAL 2 st R2=union { LSeg(f,i2) : 1 <= i2
    & i2+1 <= k+1 } holds R2 is boundary
    proof
      let R2 be Subset of TOP-REAL 2;
      assume
A6:   R2=union { LSeg(f,i2) : 1 <= i2 & i2+1 <= k+1 };
A7:   R3 \/ LSeg(f,k) c= R2
      proof
        let z be object;
        assume
A8:     z in R3 \/ LSeg(f,k);
        per cases by A8,XBOOLE_0:def 3;
        suppose
          z in R3;
          then consider x being set such that
A9:       z in x & x in { LSeg(f,i2) : 1 <= i2 & i2+1 <= k } by TARSKI:def 4;
          consider i2 such that
A10:      x=LSeg(f,i2) & 1 <= i2 and
A11:      i2+1 <= k by A9;
          i2+1<k+1 by A11,NAT_1:13;
          then x in { LSeg(f,j) : 1 <= j & j+1 <= k+1 } by A10;
          hence thesis by A6,A9,TARSKI:def 4;
        end;
        suppose
A12:      z in LSeg(f,k);
          now
            per cases;
            suppose
              1<=k;
              then LSeg(f,k) in { LSeg(f,i2) : 1 <= i2 & i2+1 <= k+1 };
              hence thesis by A6,A12,TARSKI:def 4;
            end;
            suppose
              k<1;
              hence thesis by A12,TOPREAL1:def 3;
            end;
          end;
          hence thesis;
        end;
      end;
      R2 c= R3 \/ LSeg(f,k)
      proof
        let z be object;
        assume z in R2;
        then consider x being set such that
A13:    z in x & x in { LSeg(f,i2) : 1 <= i2 & i2+1 <= k+1 } by A6,TARSKI:def 4
;
        consider i2 such that
A14:    x=LSeg(f,i2) and
A15:    1 <= i2 and
A16:    i2+1 <= k+1 by A13;
        now
          per cases;
          case
            i2+1<=k;
            then x in { LSeg(f,j) : 1 <= j & j+1 <= k } by A14,A15;
            hence z in R3 or z in LSeg(f,k) by A13,TARSKI:def 4;
          end;
          case
            i2+1>k;
            then k+1<=i2+1 by NAT_1:13;
            then i2+1=k+1 by A16,XXREAL_0:1;
            hence z in R3 or z in LSeg(f,k) by A13,A14;
          end;
        end;
        hence thesis by XBOOLE_0:def 3;
      end;
      then R2=R3 \/ LSeg(f,k) by A7;
      hence thesis by A5,A3,TOPS_1:49;
    end;
  end;
  union { LSeg(f,i) : 1 <= i & i+1 <= 0 } c= {}
  proof
    let z be object;
    assume z in union { LSeg(f,i) : 1 <= i & i+1 <= 0 };
    then consider x being set such that
A17: z in x & x in { LSeg(f,i) : 1 <= i & i+1 <= 0 } by TARSKI:def 4;
    ex i st x=LSeg(f,i) & 1 <= i & i+1 <= 0 by A17;
    hence thesis;
  end;
  then
A18: P[0];
  for j holds P[j] from NAT_1:sch 2(A18,A2);
  hence thesis by A1;
end;
