
theorem Th102:
  for X be non empty set, S be SigmaField of X, M be
sigma_Measure of S, f,g be PartFunc of X,ExtREAL st ( ex A be Element of S st A
= dom f & f is A-measurable ) & dom f = dom g & g is_integrable_on M & ( for
  x be Element of X st x in dom f holds |.f.x .| <= g.x ) holds f
  is_integrable_on M & Integral(M,|.f.|) <= Integral(M,g)
proof
  let X be non empty set, S be SigmaField of X, M be sigma_Measure of S, f,g
  be PartFunc of X,ExtREAL;
  assume that
A1: ex A be Element of S st A = dom f & f is A-measurable and
A2: dom f = dom g and
A3: g is_integrable_on M and
A4: for x be Element of X st x in dom f holds |. f.x .| <= g.x;
A5: ex AA be Element of S st AA = dom g & g is AA-measurable by A3;
A6: now
    let x be object;
    assume x in dom g;
    then |. f.x .| <= g.x by A2,A4;
    hence 0 <= g.x by EXTREAL1:14;
  end;
  then
A7: g is nonnegative by SUPINF_2:52;
A8: dom g = dom max+ g by MESFUNC2:def 2;
  now
    let x be object;
A9: 0 <= g.x by A7,SUPINF_2:51;
    assume x in dom g;
    hence max+g.x = max(g.x,0) by A8,MESFUNC2:def 2
      .=g.x by A9,XXREAL_0:def 10;
  end;
  then
A10: g = max+g by A8,FUNCT_1:2;
A11: dom |.f.| = dom max+|.f.| by MESFUNC2:def 2;
A12: now
    let x be object;
    assume
A13: x in dom |.f.|;
    then (|.f.|).x =|. f.x .| by MESFUNC1:def 10;
    then
A14: 0 <= (|.f.|).x by EXTREAL1:14;
    thus (max+|.f.|).x = max((|.f.|).x,0) by A11,A13,MESFUNC2:def 2
      .=(|.f.|).x by A14,XXREAL_0:def 10;
  end;
  then
A15: |.f.| = max+|.f.| by A11,FUNCT_1:2;
  consider A be Element of S such that
A16: A = dom f and
A17: f is A-measurable by A1;
A18: |.f.| is A-measurable by A16,A17,MESFUNC2:27;
A19: A = dom |.f.| by A16,MESFUNC1:def 10;
A20: for x be Element of X st x in dom |.f.| holds (|.f.|).x <= g.x
  proof
    let x be Element of X;
    assume
A21: x in dom |.f.|;
    then (|.f.|).x =|. f.x .| by MESFUNC1:def 10;
    hence thesis by A4,A16,A19,A21;
  end;
A22: now
    let x be object;
    assume x in dom |.f.|;
    then (|.f.|).x =|. f.x .| by MESFUNC1:def 10;
    hence 0 <= (|.f.|).x by EXTREAL1:14;
  end;
  then |.f.| is nonnegative by SUPINF_2:52;
  then
A23: integral+(M,|.f.|) <= integral+(M,g) by A2,A16,A5,A19,A18,A7,A20,Th85;
A24: dom |.f.| = dom max-(|.f.|) by MESFUNC2:def 3;
  now
    let x be Element of X;
    assume x in dom max-(|.f.|);
    then max+(|.f.|).x=(|.f.|).x by A24,A12;
    hence max-(|.f.|).x=0 by MESFUNC2:19;
  end;
  then
A25: integral+(M,max-|.f.|) = 0 by A19,A18,A24,Th87,MESFUNC2:26;
  integral+(M,max+g) < +infty by A3;
  then integral+(M,max+(|.f.|)) < +infty by A15,A10,A23,XXREAL_0:2;
  then |.f.| is_integrable_on M by A19,A18,A25;
  hence f is_integrable_on M by A1,Th100;
  Integral(M,g) =integral+(M,g) by A5,A6,Th88,SUPINF_2:52;
  hence thesis by A19,A18,A22,A23,Th88,SUPINF_2:52;
end;
