reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th102:
  for r1,r2 be non-zero Sequence of REAL,
      y1,y2 be strictly_decreasing uSurreal-Sequence st
         dom r1 = dom y1 & dom r2 = dom y2 &
         Sum(r1,y1) == Sum(r2,y2)
  holds r1=r2 & y1=y2
proof
   let r1,r2 be non-zero Sequence of REAL,
       y1,y2 be strictly_decreasing uSurreal-Sequence such that
A1:  dom r1 = dom y1 & dom r2 = dom y2 &
   Sum(r1,y1) == Sum(r2,y2);
A2:  Sum(r1,y1) = Sum(r2,y2) by A1,SURREALO:50;
A3: r1,y1,dom r1 name_like Sum(r1,y1) by Th101,A1;
A4: r2,y2,dom r2 name_like Sum(r2,y2) by Th101,A1;
   per cases by ORDINAL1:14;
   suppose
A5:  dom r1 in dom r2;
     then
A6:  dom r1 c= dom r2 by ORDINAL1:def 2;
     r2,y2,dom r1 name_like Sum(r2,y2) by A4,A6;
     then
A7:  r1|dom r1 = r2|dom r1 & y1|dom r1 = y2|dom r1 by A3,A2,Th87;
     set s = Partial_Sums(r2,y2);
     s.dom r1 = (s|succ dom r1).dom r1 by FUNCT_1:49,ORDINAL1:6
     .= Partial_Sums(r2|dom r1,y2|dom r1).dom r1 by Th85
     .= Sum(r1,y1) by A1,A7;
     hence thesis by A1,A4,A5;
   end;
   suppose
A8:  dom r1 = dom r2;
     r2,y2,dom r1 name_like Sum(r2,y2) by Th101,A1,A8;
     then r1= r1|dom r1 = r2|dom r1 =r2 & y1=y1|dom r1 = y2|dom r1 = y2
     by A8,A3,A2,Th87;
     hence thesis;
   end;
   suppose
A9:  dom r2 in dom r1;
     then
A10: dom r2 c= dom r1 by ORDINAL1:def 2;
     r1,y1,dom r2 name_like Sum(r1,y1) by A10,A3;
     then
A11: r1|dom r2 = r2|dom r2 & y1|dom r2 = y2|dom r2 by A4,A2,Th87;
     set s = Partial_Sums(r1,y1);
     s.dom r2 = (s|succ dom r2).dom r2 by ORDINAL1:6,FUNCT_1:49
     .= Partial_Sums(r1|dom r2,y1|dom r2).dom r2 by Th85
     .= Sum(r2,y2) by A1,A11;
     hence thesis by A1,A3,A9;
   end;
end;
