reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th103:
  for sn being Real st -1<sn & sn<1 holds (sn-FanMorphE) is
  Function of TOP-REAL 2,TOP-REAL 2 & rng (sn-FanMorphE) = the carrier of
  TOP-REAL 2
proof
  let sn be Real;
  assume that
A1: -1<sn and
A2: sn<1;
  thus (sn-FanMorphE) is Function of TOP-REAL 2,TOP-REAL 2;
  for f being Function of TOP-REAL 2,TOP-REAL 2 st f=(sn-FanMorphE) holds
  rng (sn-FanMorphE)=the carrier of TOP-REAL 2
  proof
    let f be Function of TOP-REAL 2,TOP-REAL 2;
    assume
A3: f=(sn-FanMorphE);
A4: dom f=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
    the carrier of TOP-REAL 2 c= rng f
    proof
      let y be object;
      assume y in the carrier of TOP-REAL 2;
      then reconsider p2=y as Point of TOP-REAL 2;
      set q=p2;
      now
        per cases by JGRAPH_2:3;
        suppose
          q`1<=0;
          then y=(sn-FanMorphE).q by Th82;
          hence ex x being set st x in dom (sn-FanMorphE) & y=(sn-FanMorphE).x
          by A3,A4;
        end;
        suppose
A5:       q`2/|.q.|>=0 & q`1>=0 & q<>0.TOP-REAL 2;
          --(1+sn)>0 by A1,XREAL_1:148;
          then
A6:       -(-1-sn)>0;
A7:       1-sn>=0 by A2,XREAL_1:149;
          then q`2/|.q.|*(1-sn)>=0 by A5;
          then -1-sn<= q`2/|.q.|*(1-sn) by A6;
          then
A8:       -1-sn+sn<= q`2/|.q.|*(1-sn)+sn by XREAL_1:7;
          set px=|[ (|.q.|)*sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2), |.q.|*(q`2/|.q.|*
          (1-sn)+sn)]|;
A9:       px`2 = |.q.|*(q`2/|.q.|*(1-sn)+sn) by EUCLID:52;
          |.q.|<>0 by A5,TOPRNS_1:24;
          then
A10:      |.q.|^2>0 by SQUARE_1:12;
A11:      dom (sn-FanMorphE)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
A12:      1-sn>0 by A2,XREAL_1:149;
          0<=(q`1)^2 by XREAL_1:63;
          then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`2)^2<=(q`1)^2+(q`2)^2 by
JGRAPH_3:1,XREAL_1:7;
          then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
          then (q`2)^2/(|.q.|)^2 <= 1 by A10,XCMPLX_1:60;
          then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
          then q`2/|.q.|<=1 by SQUARE_1:51;
          then q`2/|.q.|*(1-sn) <= 1 *(1-sn) by A12,XREAL_1:64;
          then q`2/|.q.|*(1-sn)+sn-sn <=1-sn;
          then (q`2/|.q.|*(1-sn)+sn) <=1 by XREAL_1:9;
          then 1^2>=(q`2/|.q.|*(1-sn)+sn)^2 by A8,SQUARE_1:49;
          then
A13:      1-(q`2/|.q.|*(1-sn)+sn)^2>=0 by XREAL_1:48;
          then
A14:      sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2)>=0 by SQUARE_1:def 2;
A15:      px`1 = (|.q.|)*sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2) by EUCLID:52;
          then
          |.px.|^2=((|.q.|)*sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2))^2 +(|.q.|*(q
          `2/|.q.|*(1-sn)+sn))^2 by A9,JGRAPH_3:1
            .=(|.q.|)^2*(sqrt(1-(q`2/|.q.|*(1-sn)+sn)^2))^2 +(|.q.|)^2*((q`2
          /|.q.|*(1-sn)+sn))^2;
          then
A16:      |.px.|^2=(|.q.|)^2*(1-(q`2/|.q.|*(1-sn)+sn)^2) +(|.q.|)^2*((q`2
          /|.q.|*(1-sn)+sn))^2 by A13,SQUARE_1:def 2
            .= (|.q.|)^2;
          then
A17:      |.px.|=sqrt(|.q.|^2) by SQUARE_1:22
            .=|.q.| by SQUARE_1:22;
          then
A18:      px<>0.TOP-REAL 2 by A5,TOPRNS_1:23,24;
          (q`2/|.q.|*(1-sn)+sn)>=0+sn by A5,A7,XREAL_1:7;
          then px`2/|.px.| >=sn by A5,A9,A17,TOPRNS_1:24,XCMPLX_1:89;
          then
A19:      (sn-FanMorphE).px =|[ |.px.|*(sqrt(1-((px`2/|.px.|-sn) /(1-sn))
          ^2)), |.px.|* ((px`2/|.px.|-sn)/(1-sn))]| by A1,A2,A15,A14,A18,Th84;
A20:      |.px.|*(sqrt((q`1/|.q.|)^2))=|.q.|*(q`1/|.q.|) by A5,A17,SQUARE_1:22
            .=q`1 by A5,TOPRNS_1:24,XCMPLX_1:87;
A21:      |.px.|* ((px`2/|.px.|-sn)/(1-sn)) =|.q.|* (( ((q`2/|.q.|*(1-sn)
          +sn))-sn)/(1-sn)) by A5,A9,A17,TOPRNS_1:24,XCMPLX_1:89
            .=|.q.|* ( q`2/|.q.|) by A12,XCMPLX_1:89
            .= q`2 by A5,TOPRNS_1:24,XCMPLX_1:87;
          then
          |.px.|*(sqrt(1-((px`2/|.px.|-sn)/(1-sn))^2)) = |.px.|*(sqrt(1-(
          q`2/|.px.|)^2)) by A5,A17,TOPRNS_1:24,XCMPLX_1:89
            .= |.px.|*(sqrt(1-(q`2)^2/(|.px.|)^2)) by XCMPLX_1:76
            .= |.px.|*(sqrt( (|.px.|)^2/(|.px.|)^2-(q`2)^2/(|.px.|)^2)) by A10
,A16,XCMPLX_1:60
            .= |.px.|*(sqrt( ((|.px.|)^2-(q`2)^2)/(|.px.|)^2)) by XCMPLX_1:120
            .= |.px.|*(sqrt( ((q`1)^2+(q`2)^2-(q`2)^2)/(|.px.|)^2)) by A16,
JGRAPH_3:1
            .= |.px.|*(sqrt((q`1/|.q.|)^2)) by A17,XCMPLX_1:76;
          hence ex x being set st x in dom (sn-FanMorphE) & y=(sn-FanMorphE).x
          by A19,A21,A20,A11,EUCLID:53;
        end;
        suppose
A22:      q`2/|.q.|<0 & q`1>=0 & q<>0.TOP-REAL 2;
A23:      1+sn>=0 by A1,XREAL_1:148;
          (1-sn)>0 by A2,XREAL_1:149;
          then
A24:      1-sn+sn>= q`2/|.q.|*(1+sn)+sn by A22,A23,XREAL_1:7;
A25:      1+sn>0 by A1,XREAL_1:148;
          |.q.|<>0 by A22,TOPRNS_1:24;
          then
A26:      |.q.|^2>0 by SQUARE_1:12;
          0<=(q`1)^2 by XREAL_1:63;
          then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`2)^2<=(q`1)^2+(q`2)^2 by
JGRAPH_3:1,XREAL_1:7;
          then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
          then (q`2)^2/(|.q.|)^2 <= 1 by A26,XCMPLX_1:60;
          then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
          then q`2/|.q.|>=-1 by SQUARE_1:51;
          then q`2/|.q.|*(1+sn) >=(-1)*(1+sn) by A25,XREAL_1:64;
          then q`2/|.q.|*(1+sn)+sn-sn >=-1-sn;
          then (q`2/|.q.|*(1+sn)+sn) >=-1 by XREAL_1:9;
          then 1^2>=(q`2/|.q.|*(1+sn)+sn)^2 by A24,SQUARE_1:49;
          then
A27:      1-(q`2/|.q.|*(1+sn)+sn)^2>=0 by XREAL_1:48;
          then
A28:      sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2)>=0 by SQUARE_1:def 2;
A29:      dom (sn-FanMorphE)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
          set px=|[ (|.q.|)*sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2), |.q.|*(q`2/|.q.|*
          (1+sn)+sn)]|;
A30:      px`2 = |.q.|*(q`2/|.q.|*(1+sn)+sn) by EUCLID:52;
A31:      px`1 = (|.q.|)*sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2) by EUCLID:52;
          then
          |.px.|^2=((|.q.|)*sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2))^2 +(|.q.|*(q
          `2/|.q.|*(1+sn)+sn))^2 by A30,JGRAPH_3:1
            .=(|.q.|)^2*(sqrt(1-(q`2/|.q.|*(1+sn)+sn)^2))^2 +(|.q.|)^2*((q`2
          /|.q.|*(1+sn)+sn))^2;
          then
A32:      |.px.|^2=(|.q.|)^2*(1-(q`2/|.q.|*(1+sn)+sn)^2) +(|.q.|)^2*((q`2
          /|.q.|*(1+sn)+sn))^2 by A27,SQUARE_1:def 2
            .= (|.q.|)^2;
          then
A33:      |.px.|=sqrt(|.q.|^2) by SQUARE_1:22
            .=|.q.| by SQUARE_1:22;
          then
A34:      px<>0.TOP-REAL 2 by A22,TOPRNS_1:23,24;
          (q`2/|.q.|*(1+sn)+sn)<=0+sn by A22,A23,XREAL_1:7;
          then px`2/|.px.| <=sn by A22,A30,A33,TOPRNS_1:24,XCMPLX_1:89;
          then
A35:      (sn-FanMorphE).px =|[ |.px.|*(sqrt(1-((px`2/|.px.|-sn) /(1+sn))
          ^2)), |.px.|* ((px`2/|.px.|-sn)/(1+sn))]| by A1,A2,A31,A28,A34,Th84;
A36:      |.px.|*(sqrt((q`1/|.q.|)^2)) =|.q.|*(q`1/|.q.|) by A22,A33,
SQUARE_1:22
            .=q`1 by A22,TOPRNS_1:24,XCMPLX_1:87;
A37:      |.px.|* ((px`2/|.px.|-sn)/(1+sn)) =|.q.|* (( ((q`2/|.q.|*(1+sn)
          +sn))-sn)/(1+sn)) by A22,A30,A33,TOPRNS_1:24,XCMPLX_1:89
            .=|.q.|* ( q`2/|.q.|) by A25,XCMPLX_1:89
            .= q`2 by A22,TOPRNS_1:24,XCMPLX_1:87;
          then
          |.px.|*(sqrt(1-((px`2/|.px.|-sn)/(1+sn))^2)) = |.px.|*(sqrt(1-(
          q`2/|.px.|)^2)) by A22,A33,TOPRNS_1:24,XCMPLX_1:89
            .= |.px.|*(sqrt(1-(q`2)^2/(|.px.|)^2)) by XCMPLX_1:76
            .= |.px.|*(sqrt( (|.px.|)^2/(|.px.|)^2-(q`2)^2/(|.px.|)^2)) by A26
,A32,XCMPLX_1:60
            .= |.px.|*(sqrt( ((|.px.|)^2-(q`2)^2)/(|.px.|)^2)) by XCMPLX_1:120
            .= |.px.|*(sqrt( ((q`1)^2+(q`2)^2-(q`2)^2)/(|.px.|)^2)) by A32,
JGRAPH_3:1
            .= |.px.|*(sqrt((q`1/|.q.|)^2)) by A33,XCMPLX_1:76;
          hence ex x being set st x in dom (sn-FanMorphE) & y=(sn-FanMorphE).x
          by A35,A37,A36,A29,EUCLID:53;
        end;
      end;
      hence thesis by A3,FUNCT_1:def 3;
    end;
    hence thesis by A3,XBOOLE_0:def 10;
  end;
  hence thesis;
end;
