
theorem Th103:
  for X be non empty set, S be SigmaField of X, M be
sigma_Measure of S, f be PartFunc of X,ExtREAL, r be Real st dom f in S & 0 <=
r & dom f <> {} & (for x be object st x in dom f holds f.x = r)
holds integral(M,f) = r * M.(dom f)
proof
  let X be non empty set;
  let S be SigmaField of X;
  let M be sigma_Measure of S;
  let f be PartFunc of X,ExtREAL;
  let r be Real;
  assume that
A1: dom f in S and
A2: 0 <= r and
A3: dom f <> {} and
A4: for x be object st x in dom f holds f.x = r;
    for x be object st x in dom f holds 0 <= f.x by A2,A4; then
a5: f is nonnegative by SUPINF_2:52;
  f is_simple_func_in S by A1,A4,Lm4;
  then consider
  F be Finite_Sep_Sequence of S, a,v be FinSequence of ExtREAL such
  that
A6: F,a are_Re-presentation_of f and
A7: dom v = dom F and
A8: for n be Nat st n in dom v holds v.n = a.n*(M*F).n and
A9: integral(M,f) = Sum v by A3,a5,MESFUNC4:4;
A10: dom f = union rng F by A6,MESFUNC3:def 1;
A11: for n be Nat st n in dom v holds v.n = r * (M*F).n
  proof
    let n be Nat;
    assume
A12: n in dom v;
    then
A13: F.n c= union rng F by A7,FUNCT_1:3,ZFMISC_1:74;
A14: v.n = a.n*(M*F).n by A8,A12;
    per cases;
    suppose
      F.n = {};
      then M.(F.n) = 0 by VALUED_0:def 19;
      then
A15:  (M*F).n = 0 by A7,A12,FUNCT_1:13;
      then v.n = 0 by A14;
      hence thesis by A15;
    end;
    suppose
      F.n <> {};
      then consider x be object such that
A16:  x in F.n by XBOOLE_0:def 1;
      a.n = f.x by A6,A7,A12,A16,MESFUNC3:def 1;
      hence thesis by A4,A10,A13,A14,A16;
    end;
  end;
  reconsider rr=r as R_eal by XXREAL_0:def 1;
  dom v = dom(M*F) by A7,MESFUNC3:8;
  then integral(M,f) = rr * Sum(M*F)
      by A9,A11,MESFUNC3:10
    .= rr * M.(union rng F) by MESFUNC3:9;
  hence thesis by A6,MESFUNC3:def 1;
end;
