reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem
  for a being Real,p being Point of TOP-REAL 2 st a>0 & p in L~SpStSeq D
  holds ex q being Point of TOP-REAL 2 st q in UBD (L~SpStSeq D) & |.p-q.|<a
proof
  let a be Real,p be Point of TOP-REAL 2;
  assume that
A1: a>0 and
A2: p in L~SpStSeq D;
  set q1 = the Element of UBD (L~SpStSeq D);
  set A=L~SpStSeq D;
  A`<>{} by SPRECT_1:def 3;
  then consider A1,A2 being Subset of TOP-REAL 2 such that
A3: A` = A1 \/ A2 and
  A1 misses A2 and
A4: (Cl A1) \ A1 = (Cl A2) \ A2 and
A5: A=(Cl A1) \ A1 and
A6: for C1,C2 being Subset of (TOP-REAL 2) | A` st C1 = A1 & C2 = A2 holds
C1 is a_component & C2 is a_component
by Th82;
A7: Down(A2,A`)=A2 by A3,XBOOLE_1:21;
  UBD A is_outside_component_of A by Th53;
  then UBD (L~SpStSeq D) is_a_component_of A`;
  then consider B1 being Subset of (TOP-REAL 2) | A` such that
A8: B1 = UBD (L~SpStSeq D) and
A9: B1 is a_component by CONNSP_1:def 6;
  B1 c= [#]((TOP-REAL 2) | A`);
  then
A10: UBD (L~SpStSeq D) c= A1 \/ A2 by A3,A8,PRE_TOPC:def 5;
A11: Down(A1,A`)=A1 by A3,XBOOLE_1:21;
  then
A12: Down(A1,A`) is a_component by A6,A7;
A13: Down(A2,A`) is a_component by A6,A11,A7;
A14: UBD (L~SpStSeq D) <>{} by Th80;
  then
A15: q1 in UBD (L~SpStSeq D);
  per cases by A10,A15,XBOOLE_0:def 3;
  suppose
    q1 in A1;
    then B1 /\ Down(A1,A`)<>{}((TOP-REAL 2) | A`) by A11,A8,A14,XBOOLE_0:def 4;
    then B1 meets Down(A1,A`);
    then B1=Down(A1,A`) by A12,A9,CONNSP_1:35;
    then
A16: p in Cl(UBD (L~SpStSeq D)) by A2,A5,A11,A8,XBOOLE_0:def 5;
    reconsider ep=p as Point of Euclid 2 by TOPREAL3:8;
    reconsider G2=Ball(ep,a) as Subset of TOP-REAL 2 by TOPREAL3:8;
    the distance of Euclid 2 is Reflexive by METRIC_1:def 6;
    then dist(ep,ep)=0;
    then
A17: p in Ball(ep,a) by A1,METRIC_1:11;
    G2 is open by GOBOARD6:3;
    then (UBD (L~SpStSeq D)) meets G2 by A16,A17,PRE_TOPC:def 7;
    then consider t2 being object such that
A18: t2 in UBD (L~SpStSeq D) and
A19: t2 in G2 by XBOOLE_0:3;
    reconsider qt2=t2 as Point of TOP-REAL 2 by A18;
    |.p-qt2.|<a by A19,Th87;
    hence thesis by A18;
  end;
  suppose
    q1 in A2;
    then B1 /\ Down(A2,A`)<>{}((TOP-REAL 2) | A`) by A7,A8,A14,XBOOLE_0:def 4;
    then B1 meets Down(A2,A`);
    then B1=Down(A2,A`) by A13,A9,CONNSP_1:35;
    then
A20: p in Cl(UBD (L~SpStSeq D)) by A2,A4,A5,A7,A8,XBOOLE_0:def 5;
    reconsider ep=p as Point of Euclid 2 by TOPREAL3:8;
    reconsider G2=Ball(ep,a) as Subset of TOP-REAL 2 by TOPREAL3:8;
    (the distance of (Euclid 2)) is Reflexive by METRIC_1:def 6;
    then dist(ep,ep)=0;
    then
A21: p in Ball(ep,a) by A1,METRIC_1:11;
    G2 is open by GOBOARD6:3;
    then (UBD (L~SpStSeq D)) meets G2 by A20,A21,PRE_TOPC:def 7;
    then consider t2 being object such that
A22: t2 in (UBD (L~SpStSeq D)) and
A23: t2 in G2 by XBOOLE_0:3;
    reconsider qt2=t2 as Point of TOP-REAL 2 by A22;
    |.p-qt2.|<a by A23,Th87;
    hence thesis by A22;
  end;
end;
