reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f1,f2 be PartFunc of RNS,CNS st f1 is_Lipschitzian_on X & f2
  is_Lipschitzian_on X1 holds f1-f2 is_Lipschitzian_on X /\ X1
proof
  let f1,f2 be PartFunc of RNS,CNS;
  assume that
A1: f1 is_Lipschitzian_on X and
A2: f2 is_Lipschitzian_on X1;
A3: f1 is_Lipschitzian_on X /\ X1 by A1,Th99,XBOOLE_1:17;
  then consider s be Real such that
A4: 0<s and
A5: for x1,x2 be Point of RNS st x1 in X /\ X1 & x2 in X /\ X1 holds
  ||. f1/.x1-f1/.x2.||<=s*||. x1-x2.||;
A6: f2 is_Lipschitzian_on X /\ X1 by A2,Th99,XBOOLE_1:17;
  then
A7: X /\ X1 c= dom f2;
  X /\ X1 c= dom f1 by A3;
  then X /\ X1 c= dom f1 /\ dom f2 by A7,XBOOLE_1:19;
  hence
A8: X /\ X1 c= dom (f1-f2) by VFUNCT_1:def 2;
  consider g be Real such that
A9: 0<g and
A10: for x1,x2 be Point of RNS st x1 in X /\ X1 & x2 in X /\ X1 holds
  ||. f2/.x1-f2/.x2.||<=g*||. x1-x2.|| by A6;
  take p=s+g;
  0+0<s+g by A4,A9;
  hence 0<p;
  let x1,x2 be Point of RNS;
  assume that
A11: x1 in X/\X1 and
A12: x2 in X/\X1;
A13: ||. f2/.x1-f2/.x2.||<=g*||. x1-x2.|| by A10,A11,A12;
  ||. f1/.x1-f1/.x2.||<=s*||. x1-x2.|| by A5,A11,A12;
  then
A14: ||. f1/.x1-f1/.x2.||+||. f2/.x1-f2/.x2.||<= s*||. x1-x2.||+g*||. x1-x2
  .|| by A13,XREAL_1:7;
  ||. (f1-f2)/.x1-(f1-f2)/.x2.|| = ||. f1/.x1 - f2/.x1-(f1-f2)/.x2.|| by A8,A11
,VFUNCT_1:def 2
    .= ||. f1/.x1 - f2/.x1 - (f1/.x2-f2/.x2).|| by A8,A12,VFUNCT_1:def 2
    .= ||. f1/.x1 - (f2/.x1 + (f1/.x2-f2/.x2)).|| by RLVECT_1:27
    .= ||. f1/.x1 - (f1/.x2 + f2/.x1-f2/.x2).|| by RLVECT_1:28
    .= ||. f1/.x1 - (f1/.x2 + (f2/.x1-f2/.x2)).|| by RLVECT_1:28
    .= ||. f1/.x1 - f1/.x2 - (f2/.x1-f2/.x2).|| by RLVECT_1:27;
  then ||. (f1-f2)/.x1-(f1-f2)/.x2.|| <=||. f1/.x1-f1/.x2.||+||. f2/.x1-f2 /.
  x2.|| by CLVECT_1:104;
  hence thesis by A14,XXREAL_0:2;
end;
