reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th90:
  for A being Subset of TOP-REAL n st A is bounded holds BDD A is bounded
proof
  let A be Subset of TOP-REAL n;
  assume A is bounded;
  then consider r being Real such that
A1: for q being Point of TOP-REAL n st q in A holds |.q.|<r by Th21;
  per cases;
  suppose
A2: n>=1;
    set a=r;
    reconsider P=(REAL n)\ {q : (|.q.|) < a } as Subset of TOP-REAL n by
EUCLID:22;
A3: P c= A`
    proof
      let z be object;
      assume
A4:   z in P;
      then reconsider q0=z as Point of TOP-REAL n;
      not z in {q : (|.q.|) < a } by A4,XBOOLE_0:def 5;
      then (|.q0.|) >= a;
      then not q0 in A by A1;
      hence thesis by XBOOLE_0:def 5;
    end;
    then
A5: Down(P,A`)=P by XBOOLE_1:28;
    now
      per cases;
      suppose
        n>=2;
        then
A6:     P is connected by Th40;
        now
          assume not BDD A is bounded;
          then consider q being Point of TOP-REAL n such that
A7:       q in BDD A and
A8:       not |.q.|<r by Th21;
          consider y being set such that
A9:       q in y and
A10:      y in {B3 where B3 is Subset of TOP-REAL n: B3
          is_inside_component_of A} by A7,TARSKI:def 4;
          consider B3 being Subset of TOP-REAL n such that
A11:      y=B3 and
A12:      B3 is_inside_component_of A by A10;
          q in the carrier of TOP-REAL n;
          then
A13:      q in REAL n by EUCLID:22;
          B3 is_a_component_of A` by A12;
          then consider B4 being Subset of (TOP-REAL n) | A` such that
A14:      B4 = B3 and
A15:      B4 is a_component by CONNSP_1:def 6;
          for q2 being Point of TOP-REAL n st q2=q holds |.q2.| >= a by A8;
          then not q in {q2 where q2 is Point of TOP-REAL n: (|.q2.|) < a };
          then q in P by A13,XBOOLE_0:def 5;
          then P /\ B4<>{}((TOP-REAL n) | A`) by A9,A11,A14,XBOOLE_0:def 4;
          then P meets B4;
          then
A16:      P c= B4 by A5,A6,A15,CONNSP_1:36,46;
          B3 is bounded by A12;
          hence contradiction by A2,A14,A16,Th41,RLTOPSP1:42;
        end;
        hence thesis;
      end;
      suppose
A17:    n<2;
        {q where q is Point of TOP-REAL n: for r2 being Real st q=|[r2]|
        holds r2>=a} c= the carrier of TOP-REAL n
        proof
          let z be object;
          assume z in {q where q is Point of TOP-REAL n: for r2 being Real
          st q=|[r2]| holds r2>=a};
          then ex q being Point of TOP-REAL n st q=z & for r2 being Real st q=
          |[r2]| holds r2>=a;
          hence thesis;
        end;
        then reconsider
        P2={q where q is Point of TOP-REAL n: for r2 being Real st
        q=|[r2]| holds r2>=a} as Subset of TOP-REAL n;
        {q where q is Point of TOP-REAL n: for r2 being Real st q=|[r2]|
        holds r2<=-a} c= the carrier of TOP-REAL n
        proof
          let z be object;
          assume z in {q where q is Point of TOP-REAL n: for r2 being Real
          st q=|[r2]| holds r2<=-a};
          then ex q being Point of TOP-REAL n st q=z & for r2 being Real st q=
          |[r2]| holds r2<=-a;
          hence thesis;
        end;
        then reconsider
        P1={q where q is Point of TOP-REAL n: for r2 being Real st
        q=|[r2]| holds r2<=-a} as Subset of TOP-REAL n;
        n<1+1 by A17;
        then
    n<=1 by NAT_1:13;
        then
A18:    n=1 by A2,XXREAL_0:1;
A19:    P c= P1 \/ P2
        proof
          let z be object;
          assume
A20:      z in P;
          then reconsider q0=z as Point of TOP-REAL n;
          consider r3 being Real such that
A21:      q0=<*r3*> by A18,JORDAN2B:20;
          not z in {q : (|.q.|) < a } by A20,XBOOLE_0:def 5;
          then (|.q0.|) >= a;
          then
A22:      |.r3.|>=a by A21,Th4;
          per cases by A22,SEQ_2:1;
          suppose
            -a>=r3;
            then for r2 being Real st q0=|[r2]| holds r2<=-a by A21,JORDAN2B:23
;
            then q0 in P1;
            hence thesis by XBOOLE_0:def 3;
          end;
          suppose
            r3>=a;
            then for r2 being Real st q0=|[r2]| holds r2>=a by A21,JORDAN2B:23;
            then q0 in P2;
            hence thesis by XBOOLE_0:def 3;
          end;
        end;
        P1 \/ P2 c= P
        proof
          let z be object;
          assume
A23:      z in P1 \/ P2;
          per cases by A23,XBOOLE_0:def 3;
          suppose
A24:        z in P1;
            then
A25:        ex q being Point of TOP-REAL n st q=z & for r2 being Real st q
            =|[r2]| holds r2<=-a;
            for q2 being Point of TOP-REAL n st q2=z holds |.q2.| >= a
            proof
              let q2 be Point of TOP-REAL n;
              consider r3 being Real such that
A26:          q2=<*r3*> by A18,JORDAN2B:20;
              assume
A27:          q2=z;
              then
A28:          r3<=-a by A25,A26;
              now
                per cases;
                case
                  a<0;
                  hence |.r3.| >=a by COMPLEX1:46;
                end;
                case
                  a>=0;
                  then -a<=-0;
                  then |.r3.|=-r3 by A28,ABSVALUE:30;
                  hence |.r3.|>=a by A25,A27,A26,XREAL_1:25;
                end;
              end;
              hence thesis by A26,Th4;
            end;
            then
A29:        not z in {q2 where q2 is Point of TOP-REAL n: |.q2.| < a };
            z in the carrier of TOP-REAL n by A24;
            then z in REAL n by EUCLID:22;
            hence thesis by A29,XBOOLE_0:def 5;
          end;
          suppose
A30:        z in P2;
            then
A31:        ex q being Point of TOP-REAL n st q=z & for r2 being Real st q
            =|[r2]| holds r2>=a;
            for q2 being Point of TOP-REAL n st q2=z holds |.q2.| >= a
            proof
              let q2 be Point of TOP-REAL n;
              consider r3 being Real such that
A32:          q2=<*r3*> by A18,JORDAN2B:20;
              assume q2=z;
              then
A33:          r3>=a by A31,A32;
              now
                per cases;
                suppose
                  a<0;
                  hence |.r3.|>=a by COMPLEX1:46;
                end;
                suppose
                  a>=0;
                  hence |.r3.| >=a by A33,ABSVALUE:def 1;
                end;
              end;
              hence thesis by A32,Th4;
            end;
            then
A34:        not z in {q2 where q2 is Point of TOP-REAL n: |.q2.| < a };
            z in the carrier of TOP-REAL n by A30;
            then z in REAL n by EUCLID:22;
            hence thesis by A34,XBOOLE_0:def 5;
          end;
        end;
        then
A35:    P=P1 \/ P2 by A19;
        then P2 c= P by XBOOLE_1:7;
        then
A36:    Down(P2,A`)=P2 by A3,XBOOLE_1:1,28;
        for w1,w2 being Point of TOP-REAL n st w1 in P2 & w2 in P2 holds
        LSeg(w1,w2) c= P2
        proof
          let w1,w2 be Point of TOP-REAL n;
          assume that
A37:      w1 in P2 and
A38:      w2 in P2;
A39:      ex q2 being Point of TOP-REAL n st q2=w2 & for r2 being Real st
          q2=|[r2]| holds r2>=a by A38;
          consider r3 being Real such that
A40:      w1=<*r3*> by A18,JORDAN2B:20;
          consider r4 being Real such that
A41:      w2=<*r4*> by A18,JORDAN2B:20;
A42:      ex q1 being Point of TOP-REAL n st q1=w1 & for r2 being Real st
          q1=|[r2]| holds r2>=a by A37;
          thus LSeg(w1,w2) c= P2
          proof
            let z be object;
            assume z in LSeg(w1,w2);
            then consider r2 such that
A43:        z=(1-r2)*w1 + r2*w2 and
A44:        0 <= r2 and
A45:        r2 <= 1;
            reconsider q4=z as Point of TOP-REAL n by A43;
            (1-r2)*w1=|[(1-r2)*r3]| & r2*w2=|[r2*r4]| by A18,A40,A41,
JORDAN2B:21;
            then
A46:        z=|[(1-r2)*r3+r2*r4]| by A18,A43,JORDAN2B:22;
            for r5 being Real st q4=|[r5]| holds r5>=a
            proof
              let r5 be Real;
              assume q4=|[r5]|;
              then
A47:          r5=(1-r2)*r3+r2*r4 by A46,JORDAN2B:23;
              1-r2>=0 by A45,XREAL_1:48;
              then
A48:          (1-r2)*r3>=(1-r2)*(a) by A42,A40,XREAL_1:64;
              r2*r4>=r2*(a) & (1-r2)*(a)+r2*(a)=a by A39,A41,A44,XREAL_1:64;
              hence thesis by A47,A48,XREAL_1:7;
            end;
            hence thesis;
          end;
        end;
        then P2 is convex by JORDAN1:def 1;
        then
A49:    Down(P2,A`) is connected by A36,CONNSP_1:46;
        P1 c= P by A35,XBOOLE_1:7;
        then
A50:    Down(P1,A`)=P1 by A3,XBOOLE_1:1,28;
A51:    now
          assume P2 is bounded;
          then consider r being Real such that
A52:      for q being Point of TOP-REAL n st q in P2 holds |.q.|<r by Th21;
          0<=|.r.| & 0<=|.a.| by COMPLEX1:46;
          then
A53:      |.|.r.|+|.a.|.|=|.r.|+|.a.| by ABSVALUE:def 1;
          set p3=|[(|.r.|+|.a.|)]|;
A54:      |.r.|<=|.r.|+|.a.| by COMPLEX1:46,XREAL_1:31;
          for r5 being Real st p3=|[r5]| holds r5>=a
          proof
            let r5 be Real;
            assume p3=|[r5]|;
            then
A55:        r5=(|.r.|+|.a.|) by JORDAN2B:23;
            a<=|.a.| & |.a.|<=|.a.|+|.r.| by ABSVALUE:4,COMPLEX1:46,XREAL_1:31;
            hence thesis by A55,XXREAL_0:2;
          end;
          then
A56:      p3 in P2 by A18;
          |.p3.|=|.(|.r.|+|.a.|).| & r<=|.r.| by Th4,ABSVALUE:4;
          hence contradiction by A52,A56,A53,A54,XXREAL_0:2;
        end;
A57:    now
          assume P1 is bounded;
          then consider r being Real such that
A58:      for q being Point of TOP-REAL n st q in P1 holds |.q.|<r by Th21;
          0<=|.r.| & 0<=|.a.| by COMPLEX1:46;
          then
A59:      |.(|.r.|+|.a.|).|=|.r.|+|.a.| by ABSVALUE:def 1;
          set p3=|[-(|.r.|+|.a.|)]|;
A60:      r<=|.r.| & |.r.|<=|.r.|+|.a.| by ABSVALUE:4,COMPLEX1:46,XREAL_1:31;
          for r5 being Real st p3=|[r5]| holds r5<=-a
          proof
            let r5 be Real;
            a<=|.a.| by ABSVALUE:4;
            then
A61:        -|.a.|<=-a by XREAL_1:24;
            |.a.|<=|.a.|+|.r.| by COMPLEX1:46,XREAL_1:31;
            then
A62:        -|.a.|>= -(|.a.|+|.r.|) by XREAL_1:24;
            assume p3=|[r5]|;
            then r5=-(|.r.|+|.a.|) by JORDAN2B:23;
            hence thesis by A61,A62,XXREAL_0:2;
          end;
          then
A63:      p3 in P1 by A18;
          |.p3.|=|.-(|.r.|+|.a.|).| by Th4
            .=|.(|.r.|+|.a.|).| by COMPLEX1:52;
          hence contradiction by A58,A63,A59,A60,XXREAL_0:2;
        end;
        for w1,w2 being Point of TOP-REAL n st w1 in P1 & w2 in P1 holds
        LSeg(w1,w2) c= P1
        proof
          let w1,w2 be Point of TOP-REAL n;
          assume that
A64:      w1 in P1 and
A65:      w2 in P1;
          consider r4 being Real such that
A66:      w2=<*r4*> by A18,JORDAN2B:20;
          ex q2 being Point of TOP-REAL n st q2=w2 & for r2 being Real st
          q2=|[r2]| holds r2<=-a by A65;
          then
A67:      r4<=-a by A66;
          consider r3 being Real such that
A68:      w1=<*r3*> by A18,JORDAN2B:20;
          ex q1 being Point of TOP-REAL n st q1=w1 & for r2 being Real st
          q1=|[r2]| holds r2<=-a by A64;
          then
A69:      r3<=-a by A68;
          thus LSeg(w1,w2) c= P1
          proof
            let z be object;
            assume z in LSeg(w1,w2);
            then consider r2 such that
A70:        z=(1-r2)*w1 + r2*w2 and
A71:        0 <= r2 and
A72:        r2 <= 1;
            reconsider q4=z as Point of TOP-REAL n by A70;
A73:        r2*w2=|[r2*r4]| by A18,A66,JORDAN2B:21;
            (1-r2)*w1 = (1-r2)*|[r3]| by A68
              .=|[(1-r2)*r3]| by JORDAN2B:21;
            then
A74:        z=|[(1-r2)*r3+r2*r4]| by A18,A70,A73,JORDAN2B:22;
            for r5 being Real st q4=|[r5]| holds r5<=-a
            proof
              let r5 be Real;
              assume q4=|[r5]|;
              then
A75:          r5=(1-r2)*r3+r2*r4 by A74,JORDAN2B:23;
              1-r2>=0 by A72,XREAL_1:48;
              then
A76:          (1-r2)*r3<=(1-r2)*(-a) by A69,XREAL_1:64;
              r2*r4<=r2*(-a) & (1-r2)*(-a)+r2*(-a)=-a by A67,A71,XREAL_1:64;
              hence thesis by A75,A76,XREAL_1:7;
            end;
            hence thesis;
          end;
        end;
        then P1 is convex by JORDAN1:def 1;
        then
A77:    Down(P1,A`) is connected by A50,CONNSP_1:46;
        now
          assume not BDD A is bounded;
          then consider q being Point of TOP-REAL n such that
A78:      q in BDD A and
A79:      not |.q.|<r by Th21;
          consider y being set such that
A80:      q in y and
A81:      y in {B3 where B3 is Subset of TOP-REAL n: B3
          is_inside_component_of A} by A78,TARSKI:def 4;
          consider B3 being Subset of TOP-REAL n such that
A82:      y=B3 and
A83:      B3 is_inside_component_of A by A81;
          q in the carrier of TOP-REAL n;
          then
A84:      q in REAL n by EUCLID:22;
          for q2 being Point of TOP-REAL n st q2=q holds |.q2.| >= a by A79;
          then not q in {q2 where q2 is Point of TOP-REAL n: |.q2.| < a };
          then
A85:      q in P by A84,XBOOLE_0:def 5;
          B3 is_a_component_of A` by A83;
          then consider B4 being Subset of (TOP-REAL n) | A` such that
A86:      B4 = B3 and
A87:      B4 is a_component by CONNSP_1:def 6;
          per cases by A19,A85,XBOOLE_0:def 3;
          suppose
            q in P1;
            then P1 /\ B4<>{}((TOP-REAL n) | A`) by A80,A82,A86,XBOOLE_0:def 4;
            then
A88:        P1 meets B4;
            B3 is bounded by A83;
            hence contradiction
             by A50,A57,A77,A86,A87,A88,CONNSP_1:36,RLTOPSP1:42;
          end;
          suppose
            q in P2;
            then P2 /\ B4<>{}((TOP-REAL n) | A`) by A80,A82,A86,XBOOLE_0:def 4;
            then
A89:        P2 meets B4;
            B3 is bounded by A83;
            hence contradiction
             by A36,A51,A49,A86,A87,A89,CONNSP_1:36,RLTOPSP1:42;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  suppose
    n<1;
    then n<0+1;
    then
A90: n=0 by NAT_1:13;
    for q2 being Point of TOP-REAL n holds |.q2.|<1
    proof
      let q2 be Point of TOP-REAL n;
      q2=0.TOP-REAL n by A90,EUCLID:77;
      hence thesis by TOPRNS_1:23;
    end;
    then for q2 being Point of TOP-REAL n st q2 in [#] (TOP-REAL n) holds |.
    q2.|<1;
    then [#](TOP-REAL n) is bounded by Th21;
    hence thesis by RLTOPSP1:42;
  end;
end;
