reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th106:
  for f be PartFunc of CNS1,CNS2 st f is_Lipschitzian_on X holds
  z(#)f is_Lipschitzian_on X
proof
  let f be PartFunc of CNS1,CNS2;
  assume
A1: f is_Lipschitzian_on X;
  then consider s be Real such that
A2: 0 < s and
A3: for x1,x2 be Point of CNS1 st x1 in X & x2 in X holds ||. f/.x1-f/.
  x2.||<=s*||. x1-x2.||;
  X c= dom f by A1;
  hence
A4: X c= dom (z(#)f) by VFUNCT_2:def 2;
  now
    per cases;
    suppose
A5:   z=0;
      take s;
      thus 0<s by A2;
      let x1,x2 be Point of CNS1;
      assume that
A6:   x1 in X and
A7:   x2 in X;
      0<=||. x1-x2.|| by CLVECT_1:105;
      then
A8:   s*0<=s*||. x1-x2.|| by A2;
      ||. (z(#)f)/.x1-(z(#)f)/.x2.|| = ||. z*(f/.x1)-(z(#)f)/.x2.|| by A4,A6,
VFUNCT_2:def 2
        .= ||. 0.CNS2-(z(#)f)/.x2.|| by A5,CLVECT_1:1
        .= ||. 0.CNS2 - z*(f/.x2).|| by A4,A7,VFUNCT_2:def 2
        .= ||. 0.CNS2-0.CNS2.|| by A5,CLVECT_1:1
        .= ||. 0.CNS2.|| by RLVECT_1:13
        .= 0 by CLVECT_1:102;
      hence ||. (z(#)f)/.x1-(z(#)f)/.x2.|| <=s*||. x1-x2.|| by A8;
    end;
    suppose
A9:   z<>0;
       reconsider g = |.z.| *s as Real;
      take g;
      0<|.z.| by A9,COMPLEX1:47;
      then 0*s<|.z.|*s by A2,XREAL_1:68;
      hence 0<g;
      let x1,x2 be Point of CNS1;
      assume that
A10:  x1 in X and
A11:  x2 in X;
      0<=|.z.| by COMPLEX1:46;
      then
A12:  |.z.|*||. f/.x1-f/.x2.|| <= |.z.|*(s*||. x1-x2.||) by A3,A10,A11,
XREAL_1:64;
      ||. (z(#)f)/.x1-(z(#)f)/.x2.|| = ||. z*(f/.x1)-(z(#)f)/.x2.|| by A4,A10,
VFUNCT_2:def 2
        .= ||. z*(f/.x1) - z*(f/.x2).|| by A4,A11,VFUNCT_2:def 2
        .= ||. z*(f/.x1 - f/.x2).|| by CLVECT_1:9
        .= |.z.|*||. f/.x1 - f/.x2.|| by CLVECT_1:def 13;
      hence ||. (z(#)f)/.x1-(z(#)f)/.x2.|| <= g*||. x1-x2.|| by A12;
    end;
  end;
  hence thesis;
end;
