reserve p,q for Rational;
reserve g,m,m1,m2,n,n1,n2 for Nat;
reserve i,i1,i2,j,j1,j2 for Integer;
reserve R for Ring, F for Field;

theorem Th105:
for p being Prime,
    F being p-characteristic (Z/p)-homomorphic Field,
    f being Homomorphism of Z/p,F holds f = canHom_Z/(p,F)
proof
let p be Prime, F be p-characteristic (Z/p)-homomorphic Field,
    f be Homomorphism of Z/p,F;
set g = canHom_Z/(p,F);
A1: f is unity-preserving;
A2: g is unity-preserving additive multiplicative;
A3: dom f = the carrier of Z/p by FUNCT_2:def 1
        .= dom g by FUNCT_2:def 1;
A4: 1.(Z/p) = 1 by INT_3:14,INT_2:def 4;
reconsider p1 = p-1 as Element of NAT by INT_1:3;
A5: p1 + 1 = p;
defpred P[Nat] means for j being Element of Z/p st j = $1 holds f.j = g.j;
f.0 = f.(0.(Z/p)) by NAT_1:44,SUBSET_1:def 8
   .= 0.F by RING_2:6
   .= g.(0.(Z/p)) by RING_2:6
   .= g.0 by NAT_1:44,SUBSET_1:def 8;
then A6: P[0];
A7: for k being Element of NAT st 0<=k & k<p1 holds P[k] implies P[k+1]
   proof
   let k be Element of NAT;
   assume A8: 0 <= k & k < p1;
   assume A9: P[k];
   reconsider e = 1 as Element of Segm(p) by A4;
   k < p by A5,A8,NAT_1:13; then
   reconsider z = k as Element of Z/p by NAT_1:44;
   reconsider z0 = z as Element of Segm(p);
   A10: k+1 < p1 + 1 by A8,XREAL_1:6; then
   reconsider z1 = k+1 as Element of Segm(p) by NAT_1:44;
   reconsider z1 as Element of Z/p;
   A11: z + 1.Z/p = (addint(p)).(k,1) by INT_3:14,INT_2:def 4
           .= z0 + e by A10,INT_3:7
           .= k + 1;
   f.z1 = f.z + f.(1.Z/p) by A11,VECTSP_1:def 20
       .= g.z + g.(1.Z/p) by A9,A1,A2
       .= g.z1 by A11,A2;
   hence P[k+1];
   end;
A12: for k be Element of NAT st 0 <= k & k <= p1 holds P[k]
   from INT_1:sch 7(A6,A7);
now let x be object;
  assume x in dom f;
  then reconsider a = x as Element of Segm(p);
  a < p1 + 1 by NAT_1:44;
  then a <= p-1 by NAT_1:13;
  hence f.x = g.x by A12;
  end;
hence thesis by A3;
end;
