reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th107:
  for f be PartFunc of CNS,RNS st f is_Lipschitzian_on X holds r
  (#)f is_Lipschitzian_on X
proof
  let f be PartFunc of CNS,RNS;
  assume
A1: f is_Lipschitzian_on X;
  then consider s be Real such that
A2: 0 < s and
A3: for x1,x2 be Point of CNS st x1 in X & x2 in X holds ||. f/.x1-f/.x2
  .||<=s*||. x1-x2.||;
  X c= dom f by A1;
  hence
A4: X c= dom (r(#)f) by VFUNCT_1:def 4;
  now
    per cases;
    suppose
A5:   r=0;
      take s;
      thus 0<s by A2;
      let x1,x2 be Point of CNS;
      assume that
A6:   x1 in X and
A7:   x2 in X;
      0 <= ||. x1-x2.|| by CLVECT_1:105;
      then
A8:   s*0 <= s*||. x1-x2.|| by A2;
      ||. (r(#)f)/.x1-(r(#)f)/.x2.|| = ||. r*(f/.x1)-(r(#)f)/.x2.|| by A4,A6,
VFUNCT_1:def 4
        .= ||. 0.RNS-(r(#)f)/.x2.|| by A5,RLVECT_1:10
        .= ||. 0.RNS - r*(f/.x2).|| by A4,A7,VFUNCT_1:def 4
        .= ||. 0.RNS-0.RNS.|| by A5,RLVECT_1:10
        .= ||. 0.RNS.|| by RLVECT_1:13
        .= 0 by NORMSP_1:1;
      hence ||. (r(#)f)/.x1-(r(#)f)/.x2.|| <=s*||. x1-x2.|| by A8;
    end;
    suppose
A9:   r<>0;
       reconsider g = |.r.| *s as Real;
      take g;
      0<|.r.| by A9,COMPLEX1:47;
      then 0*s<|.r.|*s by A2,XREAL_1:68;
      hence 0<g;
      let x1,x2 be Point of CNS;
      assume that
A10:  x1 in X and
A11:  x2 in X;
      0<=|.r.| by COMPLEX1:46;
      then
A12:  |.r.|*||. f/.x1-f/.x2.|| <= |.r.|*(s*||. x1-x2.||) by A3,A10,A11,
XREAL_1:64;
      ||. (r(#)f)/.x1-(r(#)f)/.x2.|| = ||. r*(f/.x1)-(r(#)f)/.x2.|| by A4,A10,
VFUNCT_1:def 4
        .= ||. r*(f/.x1) - r*(f/.x2).|| by A4,A11,VFUNCT_1:def 4
        .= ||. r*(f/.x1 - f/.x2).|| by RLVECT_1:34
        .= |.r.|*||. f/.x1 - f/.x2.|| by NORMSP_1:def 1;
      hence ||. (r(#)f)/.x1-(r(#)f)/.x2.|| <= g*||. x1-x2.|| by A12;
    end;
  end;
  hence thesis;
end;
