reserve r,r1,g for Real,
  n,m,k for Nat,
  seq,seq1, seq2 for Real_Sequence,
  f,f1,f2 for PartFunc of REAL,REAL,
  x for set;
reserve r,r1,r2,g,g1,g2 for Real;

theorem
  f is convergent_in+infty & lim_in+infty f=0 & (for r ex g st r<g & g
  in dom f & f.g<>0) & (ex r st for g st g in dom f /\ right_open_halfline(r)
  holds 0<=f.g) implies f^ is divergent_in+infty_to+infty
proof
  assume that
A1: f is convergent_in+infty & lim_in+infty f=0 and
A2: for r ex g st r<g & g in dom f & f.g<>0;
  given r such that
A3: for g st g in dom f/\ right_open_halfline(r) holds 0<=f.g;
  thus for r1 ex g1 st r1<g1 & g1 in dom(f^)
  proof
    let r1;
    consider g1 such that
A4: r1<g1 and
A5: g1 in dom f and
A6: f.g1<>0 by A2;
    take g1;
    thus r1<g1 by A4;
    not f.g1 in {0} by A6,TARSKI:def 1;
    then not g1 in f"{0} by FUNCT_1:def 7;
    then g1 in dom f\f"{0} by A5,XBOOLE_0:def 5;
    hence thesis by RFUNCT_1:def 2;
  end;
  let s be Real_Sequence;
  assume that
A7: s is divergent_to+infty and
A8: rng s c=dom(f^);
  consider k such that
A9: for n st k<=n holds r<s.n by A7;
A10: rng(s^\k)c=rng s by VALUED_0:21;
  dom(f^)=dom f\f"{0} by RFUNCT_1:def 2;
  then
A11: dom(f^)c=dom f by XBOOLE_1:36;
  then
A12: rng s c=dom f by A8;
  then
A13: rng(s^\k)c=dom f by A10;
A14: f/*(s^\k) is non-zero by A8,A10,RFUNCT_2:11,XBOOLE_1:1;
  now
    let n;
A15: n in NAT by ORDINAL1:def 12;
    r<s.(n+k) by A9,NAT_1:12;
    then r<(s^\k).n by NAT_1:def 3;
    then (s^\k).n in {g2: r<g2};
    then (s^\k).n in rng(s^\k) & (s^\k).n in right_open_halfline(r) by
VALUED_0:28,XXREAL_1:230;
    then (s^\k).n in dom f/\right_open_halfline(r) by A13,XBOOLE_0:def 4;
    then
A16: 0<= f.((s^\k).n) by A3;
    (f/*(s^\k)).n<>0 by A14,SEQ_1:5;
    hence 0<(f/*(s^\k)).n by A12,A10,A16,FUNCT_2:108,XBOOLE_1:1,A15;
  end;
  then
A17: for n holds 0<=n implies 0<(f/*(s^\k)).n;
  s^\k is divergent_to+infty by A7,Th26;
  then f/*(s^\k) is convergent & lim(f/*(s^\k))=0 by A1,A13,Def12;
  then
A18: (f/*(s^\k))" is divergent_to+infty by A17,Th35;
  (f/*(s^\k))"=((f/*s)^\k)" by A8,A11,VALUED_0:27,XBOOLE_1:1
    .=((f/*s)")^\k by SEQM_3:18
    .=((f^)/*s)^\k by A8,RFUNCT_2:12;
  hence thesis by A18,Th7;
end;
