reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;
reserve y for set,
  H19,H29 for StableSubgroup of G,
  N19 for normal StableSubgroup of H19,
  s1,s19,s2,s29 for CompositionSeries of G,
  fs for FinSequence of the_stable_subgroups_of G,
  f1,f2 for FinSequence,
  i,j,n for Nat;

theorem Th109:
  s1 is_finer_than s2 & s2 is jordan_holder & len s1 > len s2
  implies ex i st i in dom the_series_of_quotients_of s1 & for H st H = (
  the_series_of_quotients_of s1).i holds H is trivial
proof
  assume
A1: s1 is_finer_than s2;
  assume
A2: s2 is jordan_holder;
  assume
A3: len s1 > len s2;
  then not s1 is strictly_decreasing by A1,A2;
  then
  not for i st i in dom s1 & i+1 in dom s1 for H1,N1 st H1=s1.i & N1=s1.(i
  +1) holds not H1./.N1 is trivial;
  then consider i,H1,N1 such that
A4: i in dom s1 and
A5: i+1 in dom s1 and
A6: H1=s1.i & N1=s1.(i+1) & H1./.N1 is trivial;
  i+1 in Seg len s1 by A5,FINSEQ_1:def 3;
  then
A7: i+1 <= len s1 by FINSEQ_1:1;
  0+1 <= i+1 by XREAL_1:6;
  then
A8: 1 <= len s1 by A7,XXREAL_0:2;
  per cases;
  suppose
    len s1 <= 1;
    then
A9: len s1 = 1 by A8,XXREAL_0:1;
    now
      let i;
      assume i in dom s1;
      then i in Seg 1 by A9,FINSEQ_1:def 3;
      then
A10:  i = 1 by FINSEQ_1:2,TARSKI:def 1;
      assume
A11:  i+1 in dom s1;
      let H1,N1;
      assume H1=s1.i;
      assume N1=s1.(i+1);
      assume H1./.N1 is trivial;
      2 in Seg 1 by A9,A10,A11,FINSEQ_1:def 3;
      hence contradiction by FINSEQ_1:2,TARSKI:def 1;
    end;
    then s1 is strictly_decreasing;
    hence thesis by A1,A2,A3;
  end;
  suppose
A12: len s1 > 1;
    take i;
A13: i+1-1 <= len s1 - 1 by A7,XREAL_1:9;
    i in Seg len s1 by A4,FINSEQ_1:def 3;
    then
A14: 1 <= i by FINSEQ_1:1;
    len s1 = len the_series_of_quotients_of s1 + 1 by A12,Def33;
    then i in Seg len the_series_of_quotients_of s1 by A14,A13;
    hence
A15: i in dom the_series_of_quotients_of s1 by FINSEQ_1:def 3;
    let H;
    assume H = (the_series_of_quotients_of s1).i;
    hence thesis by A6,A12,A15,Def33;
  end;
end;
