
theorem Th9:
  for R being non empty transitive RelStr, s being sequence of R
  st R is well_founded & s is non-increasing
  holds ex p being Nat st for r being Nat st p <= r
  holds s.p = s.r
proof
  let R be non empty transitive RelStr, s be sequence of R such that
A1: R is well_founded and
A2: s is non-increasing;
  set cr = the carrier of R, ir = the InternalRel of R;
A3: ir is_well_founded_in cr by A1;
A4: dom s = NAT by FUNCT_2:def 1;
  rng s c= cr by RELAT_1:def 19;
  then consider a being object such that
A5: a in rng s and
A6: ir-Seg(a) misses rng s by A3,WELLORD1:def 3;
A7: ir-Seg(a) /\ rng s = {} by A6,XBOOLE_0:def 7;
  consider i being object such that
A8: i in dom s and
A9: s.i = a by A5,FUNCT_1:def 3;
  reconsider i as Nat by A8;
  assume not thesis;
  then consider r being Nat such that
A10: i <= r and
A11: s.i <> s.r;
  i < r by A10,A11,XXREAL_0:1;
  then [s.r,s.i] in ir by A2,Th8;
  then
A12: s.r in ir-Seg(a) by A9,A11,WELLORD1:1;
  reconsider r as Element of NAT by ORDINAL1:def 12;
  s.r in rng s by A4,FUNCT_1:3;
  hence contradiction by A7,A12,XBOOLE_0:def 4;
end;
