reserve n for Element of NAT,
  a, r for Real,
  x for Point of TOP-REAL n;
reserve n for Element of NAT,
  r for non negative Real,
  s, t, x for Point of TOP-REAL n;
reserve n for non zero Element of NAT,
  s, t, o for Point of TOP-REAL n;

theorem Th10:
  for r being positive Real, o being Point of TOP-REAL 2,
  Y being non empty SubSpace of Tdisk(o,r) st Y = Tcircle(o,r) holds not Y
  is_a_retract_of Tdisk(o,r)
proof
  let r be positive Real, o be Point of TOP-REAL 2, Y be non empty
  SubSpace of Tdisk(o,r) such that
A1: Y = Tcircle(o,r);
  set y0 = the Point of Y;
  set X = Tdisk(o,r);
A2: y0 in the carrier of Y;
  the carrier of Tcircle(o,r) = Sphere(o,r) & Sphere(o,r) c= cl_Ball(o,r)
  by TOPREAL9:17,TOPREALB:9;
  then reconsider x0 = y0 as Point of X by A1,A2,Th3;
  reconsider a0 = 0, a1 = 1 as Point of I[01] by BORSUK_1:def 14,def 15;
  set C = the constant Loop of x0;
A3: C = I[01] --> x0 by BORSUK_2:5
    .= (the carrier of I[01]) --> y0;
  then reconsider D = C as Function of I[01], Y;
A4: D = I[01] --> y0 & D.a0 = y0 by A3,FUNCOP_1:7;
  y0,y0 are_connected & D.a1 = y0 by A3,FUNCOP_1:7;
  then reconsider D as constant Loop of y0 by A4,BORSUK_2:def 2;
  given R being continuous Function of X,Y such that
A5: R is being_a_retraction;
  the carrier of pi_1(Y,y0) = { Class(EqRel(Y,y0),D) }
  proof
    set E = EqRel(Y,y0);
    hereby
      let x be object;
      assume x in the carrier of pi_1(Y,y0);
      then consider f0 being Loop of y0 such that
A6:   x = Class(E,f0) by TOPALG_1:47;
      reconsider g0 = f0 as Loop of x0 by TOPALG_2:1;
      g0,C are_homotopic by TOPALG_2:2;
      then consider f being Function of [:I[01],I[01]:], X such that
A7:   f is continuous and
A8:   for s being Point of I[01] holds f.(s,0) = g0.s & f.(s,1) = C.s
& for t being Point of I[01] holds f.(0,t) = x0 & f.(1,t) = x0;
      f0,D are_homotopic
      proof
        take F = R*f;
        thus F is continuous by A7;
        let s be Point of I[01];
        thus F.(s,0) = F. [s,a0] .= R.(f.(s,0)) by FUNCT_2:15
          .= R.(g0.s) by A8
          .= f0.s by A5;
        thus F.(s,1) = F. [s,a1] .= R.(f.(s,1)) by FUNCT_2:15
          .= R.(C.s) by A8
          .= D.s by A5;
        thus F.(0,s) = F. [a0,s] .= R.(f.(0,s)) by FUNCT_2:15
          .= R.x0 by A8
          .= y0 by A5;
        thus F.(1,s) = F. [a1,s] .= R.(f.(1,s)) by FUNCT_2:15
          .= R.x0 by A8
          .= y0 by A5;
      end;
      then x = Class(E,D) by A6,TOPALG_1:46;
      hence x in { Class(E,D) } by TARSKI:def 1;
    end;
    let x be object;
    assume x in { Class(E,D) };
    then
A9: x = Class(E,D) by TARSKI:def 1;
    D in Loops y0 by TOPALG_1:def 1;
    then x in Class E by A9,EQREL_1:def 3;
    hence thesis by TOPALG_1:def 5;
  end;
  hence contradiction by A1;
end;
