
theorem Th10:
  for W be Normed_AlgebraStr, V be Algebra st
    the AlgebraStr of W = V holds W is Algebra
proof
  let W be Normed_AlgebraStr,V be Algebra such that
A1: the AlgebraStr of W = V;
  reconsider W as non empty AlgebraStr by A1;
A2:for x,y being VECTOR of W holds x + y = y + x
  proof
    let x,y be VECTOR of W;
    reconsider x1 = x, y1 = y as VECTOR of V by A1;
    x + y = x1+y1 by A1;
    then
    x + y =y1 + x1;
    hence x + y = y + x by A1;
  end;
A3:for x,y,z being VECTOR of W holds (x + y) + z = x + (y + z)
  proof
    let x,y,z be VECTOR of W;
    reconsider x1 = x, y1 = y, z1 = z as VECTOR of V by A1;
    (x + y) + z = (x1 + y1) + z1 by A1;
    then
    (x + y) + z = x1 + (y1 + z1) by RLVECT_1:def 3;
    hence (x + y) + z = x + (y + z) by A1;
  end;
A4:for x being VECTOR of W holds x + 0.W = x
  proof
    let x be VECTOR of W;
    reconsider y = x as VECTOR of V by A1;
    x + 0.W = y + 0.V by A1;
    hence x + 0.W = x by RLVECT_1:4;
  end;
A5:for x being Element of W holds x is right_complementable
  proof
    let x be Element of W;
    reconsider x1 = x as Element of V by A1;
    consider v be Element of V such that
A6:   x1 + v = 0.V by ALGSTR_0:def 11;
    reconsider y = v as Element of W by A1;
    x + y = 0.W by A6,A1;
    hence thesis;
  end;
A7:for v,w being Element of W holds v * w = w * v
  proof
    let v,w be Element of W;
    reconsider v1 = v, w1 = w as Element of V by A1;
    v * w = v1*w1 by A1; then
    v * w = w1*v1;
    hence v * w =w*v by A1;
  end;
A8:for a,b,x being Element of W holds (a * b) * x = a * (b * x)
  proof
    let a,b,x be Element of W;
    reconsider y = x, a1 = a, b1 = b as Element of V by A1;
    (a * b) * x = (a1 * b1) * y by A1; then
    (a * b) * x = a1 * (b1 * y) by GROUP_1:def 3;
    hence (a * b) * x = a * (b * x) by A1;
  end;
A9:W is right_unital
  proof
    let x be Element of W;
    reconsider x1 = x as Element of V by A1;
    x*1.W = x1*1.V by A1;
    hence x*1.W = x;
  end;
A10:W is right-distributive
  proof
    let x,y,z being Element of W;
    reconsider x1 = x, y1 = y, z1 = z as Element of V by A1;
    x*(y+z) = x1*(y1+z1) by A1; then
    x*(y+z) = x1*y1 + x1*z1 by VECTSP_1:def 2;
    hence x*(y+z) = x*y + x*z by A1;
  end;
  W is vector-distributive scalar-distributive scalar-associative
    vector-associative
  proof
    thus W is vector-distributive
    proof
      let a be Real;
      let x,y be Element of W;
      reconsider x1 = x, y1 = y as Element of V by A1;
      a*(x+y) = a*(x1+y1) by A1; then
      a*(x+y) = a*x1 + a*y1 by RLVECT_1:def 5;
      hence a*(x+y) = a*x + a*y by A1;
    end;
    thus W is scalar-distributive
    proof
      let a,b be Real;
      let x be Element of W;
      reconsider x1 = x as Element of V by A1;
      (a+b)*x = (a+b)*x1 by A1; then
      (a+b)*x = a*x1 + b*x1 by RLVECT_1:def 6;
      hence (a+b)*x =a*x + b*x by A1;
    end;
    thus W is scalar-associative
    proof
      let a,b be Real;
      let x being Element of W;
      reconsider x1 = x as Element of V by A1;
      (a*b)*x = (a*b)*x1 by A1; then
      (a*b)*x = a*(b*x1) by RLVECT_1:def 7;
      hence (a*b)*x = a*(b*x) by A1;
    end;
    let x,y be Element of W;
    let a be Real;
    reconsider x1 = x, y1 = y as Element of V by A1;
    a*(x*y) = a*(x1*y1) by A1; then
    a*(x*y) = (a*x1)*y1 by FUNCSDOM:def 9;
    hence a*(x*y) = (a*x)*y by A1;
  end;
  hence thesis by A2,A3,A4,A5,A7,A8,A9,A10,ALGSTR_0:def 16,GROUP_1:def 3,def 12
,RLVECT_1:def 2,def 3,def 4;
end;
