
theorem Th10:
  for X being set for R being non empty Subset-Family of bool X, F
  being Subset-Family of X st F = the set of all
 Intersect x where x is Element of R holds Intersect F = Intersect union R
proof
  let X be set;
  let R be non empty Subset-Family of bool X, F be Subset-Family of X such
  that
A1: F = the set of all  Intersect x where x is Element of R;
  hereby
    let c be object;
    assume
A2: c in Intersect F;
    for Y being set st Y in union R holds c in Y
    proof
      let Y be set;
      assume Y in union R;
      then consider d being set such that
A3:   Y in d and
A4:   d in R by TARSKI:def 4;
      reconsider d as Subset-Family of X by A4;
      reconsider d as Subset-Family of X;
      Intersect d in F by A1,A4;
      then c in Intersect d by A2,SETFAM_1:43;
      hence thesis by A3,SETFAM_1:43;
    end;
    hence c in Intersect union R by A2,SETFAM_1:43;
  end;
  let c be object;
  assume
A5: c in Intersect union R;
  for Y be set st Y in F holds c in Y
  proof
    let Y be set;
    assume Y in F;
    then consider x being Element of R such that
A6: Y = Intersect x by A1;
    Intersect union R c= Intersect x by SETFAM_1:44,ZFMISC_1:74;
    hence thesis by A5,A6;
  end;
  hence thesis by A5,SETFAM_1:43;
end;
