
theorem Th10:
  for C being FormalContext for O being Subset of the carrier of C
for A being Subset of the carrier' of C holds A c= (ObjectDerivation(C)).O iff
  [:O,A:] c= the Information of C
proof
  let C be FormalContext;
  let O be Subset of the carrier of C;
  let A be Subset of the carrier' of C;
A1: [:O,A:] c= the Information of C implies A c= (ObjectDerivation(C)).O
  proof
    assume
A2: [:O,A:] c= the Information of C;
    let x be object;
    assume
A3: x in A;
    then reconsider x as Attribute of C;
    for o being Object of C st o in O holds o is-connected-with x
    proof
      let o be Object of C;
      consider z being set such that
A4:   z = [o,x];
      assume o in O;
      then z in [:O,A:] by A3,A4,ZFMISC_1:def 2;
      hence thesis by A2,A4;
    end;
    then
    x in {a where a is Attribute of C : for o being Object of C st o in O
    holds o is-connected-with a};
    hence thesis by Def2;
  end;
  A c= (ObjectDerivation(C)).O implies [:O,A:] c= the Information of C
  proof
    assume A c= (ObjectDerivation(C)).O;
    then
A5: A c= {a where a is Attribute of C : for o being Object of C st o in O
    holds o is-connected-with a} by Def2;
    let z be object;
    assume z in [:O,A:];
    then consider x,y being object such that
A6: x in O and
A7: y in A and
A8: z = [x,y] by ZFMISC_1:def 2;
    reconsider y as Attribute of C by A7;
    reconsider x as Object of C by A6;
    y in {a where a is Attribute of C : for o being Object of C st o in O
    holds o is-connected-with a} by A5,A7;
    then
    ex y9 being Attribute of C st y9 = y & for o being Object of C st o in
    O holds o is-connected-with y9;
    then x is-connected-with y by A6;
    hence thesis by A8;
  end;
  hence thesis by A1;
end;
