
theorem Th10:
  for C being FormalContext for CP being strict FormalConcept of C
  holds "/\"({ConceptStr(#O,A#) where O is Subset of the carrier of C, A is
  Subset of the carrier' of C : ex a being Attribute of C st a in the Intent of
  CP & O = (AttributeDerivation(C)).{a} & A = (ObjectDerivation(C)).((
  AttributeDerivation(C)).{a})}, ConceptLattice(C)) = CP
proof
  let C be FormalContext;
  let CP be strict FormalConcept of C;
  set D = {ConceptStr(#O,A#) where O is Subset of the carrier of C, A is
  Subset of the carrier' of C : ex a being Attribute of C st a in the Intent of
  CP & O = (AttributeDerivation(C)).{a} & A = (ObjectDerivation(C)).((
  AttributeDerivation(C)).{a})};
A1: for CP9 being Element of ConceptLattice(C) st CP9 is_less_than D holds
  CP9 [= @CP
  proof
    let CP9 be Element of ConceptLattice(C);
    assume
A2: CP9 is_less_than D;
A3: the Intent of CP c= the Intent of (CP9)@
    proof
      let x be object;
      assume
A4:   x in the Intent of CP;
      then reconsider x as Element of the carrier' of C;
      set Ax = (ObjectDerivation(C)).((AttributeDerivation(C)).{x});
      set Ox = (AttributeDerivation(C)).{x};
      reconsider Cx = ConceptStr(#Ox,Ax#) as strict FormalConcept of C by
CONLAT_1:21;
      Cx in {ConceptStr(#O,A#) where O is Subset of the carrier of C, A
is Subset of the carrier' of C : ex a being Attribute of C st a in the Intent
      of CP & O = (AttributeDerivation(C)).{a} & A = (ObjectDerivation(C)).((
      AttributeDerivation(C)).{a}) } by A4;
      then CP9 [= @Cx by A2;
      then
A5:   (CP9)@ is-SubConcept-of (@Cx)@ by CONLAT_1:43;
      {x} c= Ax by CONLAT_1:6;
      then
A6:   x in the Intent of Cx by ZFMISC_1:31;
      Cx = (@Cx)@ by CONLAT_1:def 21;
      then the Intent of Cx c= the Intent of (CP9)@ by A5,CONLAT_1:28;
      hence thesis by A6;
    end;
    CP = (@CP)@ by CONLAT_1:def 21;
    then (CP9)@ is-SubConcept-of (@CP)@ by A3,CONLAT_1:28;
    hence thesis by CONLAT_1:43;
  end;
  @CP is_less_than D
  proof
    let q be Element of ConceptLattice(C);
    assume q in D;
    then consider O being Subset of the carrier of C, A being Subset of the
    carrier' of C such that
A7: q = ConceptStr(#O,A#) and
A8: ex a being Attribute of C st a in the Intent of CP & O = (
AttributeDerivation(C)).{a} & A = (ObjectDerivation(C)).((AttributeDerivation(C
    )).{a});
    consider a being Attribute of C such that
A9: a in the Intent of CP and
A10: O = (AttributeDerivation(C)).{a} and
    A = (ObjectDerivation(C)).((AttributeDerivation(C)).{a}) by A8;
A11: {a} c= the Intent of CP by A9,ZFMISC_1:31;
    (AttributeDerivation(C)).(the Intent of CP) = the Extent of CP & the
Extent of q@ = (AttributeDerivation(C)).{a} by A7,A10,CONLAT_1:def 10,def 21;
    then the Extent of CP c= the Extent of q@ by A11,CONLAT_1:4;
    then
A12: CP is-SubConcept-of q@ by CONLAT_1:def 16;
    CP = (@CP)@ by CONLAT_1:def 21;
    hence thesis by A12,CONLAT_1:43;
  end;
  hence thesis by A1,LATTICE3:34;
end;
