 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x0 in dom cosec & x1 in dom cosec implies
  [!cosec(#)cosec,x0,x1!] = 4*(sin(x1+x0)*sin(x1-x0))
  /((cos(x0+x1)-cos(x0-x1))^2*(x0-x1))
proof
  assume
A1:x0 in dom cosec & x1 in dom cosec;
A2:sin.x0<>0 & sin.x1<>0 by A1,RFUNCT_1:3;
  [!cosec(#)cosec,x0,x1!] = (cosec.x0*cosec.x0-(cosec(#)cosec).x1)/(x0-x1)
                                                         by VALUED_1:5
    .= (cosec.x0*cosec.x0-cosec.x1*cosec.x1)/(x0-x1) by VALUED_1:5
    .= ((sin.x0)"*cosec.x0-cosec.x1*cosec.x1)/(x0-x1) by A1,RFUNCT_1:def 2
    .= ((sin.x0)"*(sin.x0)"-cosec.x1*cosec.x1)/(x0-x1) by A1,RFUNCT_1:def 2
    .= ((sin.x0)"*(sin.x0)"-(sin.x1)"*cosec.x1)/(x0-x1) by A1,RFUNCT_1:def 2
    .= (((sin.x0)")^2-((sin.x1)")^2)/(x0-x1) by A1,RFUNCT_1:def 2
    .= ((1/sin.x0-1/sin.x1)*(1/sin.x0+1/sin.x1))/(x0-x1)
    .= (((1*sin.x1-1*sin.x0)/(sin.x0*sin.x1))*(1/sin.x0+1/sin.x1))/(x0-x1)
                                                       by A2,XCMPLX_1:130
    .= (((sin.x1-sin.x0)/(sin.x0*sin.x1))*((sin.x1+sin.x0)/(sin.x0*sin.x1)))
       /(x0-x1) by A2,XCMPLX_1:116
    .= (((sin.x1-sin.x0)*(sin.x1+sin.x0))/((sin.x0*sin.x1)*(sin.x0*sin.x1)))
       /(x0-x1) by XCMPLX_1:76
    .= ((sin(x1)*sin(x1)-sin(x0)*sin(x0))/((sin(x0)*sin(x1))^2))/(x0-x1)
    .= ((sin(x1+x0)*sin(x1-x0))/((sin(x0)*sin(x1))^2))/(x0-x1)
                                                              by SIN_COS4:37
    .= ((sin(x1+x0)*sin(x1-x0))
       /((-(1/2)*(cos(x0+x1)-cos(x0-x1)))^2))/(x0-x1) by SIN_COS4:29
    .= (1*(sin(x1+x0)*sin(x1-x0))
       /((1/4)*(cos(x0+x1)-cos(x0-x1))^2))/(x0-x1)
    .= ((1/(1/4))*((sin(x1+x0)*sin(x1-x0))
       /(cos(x0+x1)-cos(x0-x1))^2))/(x0-x1) by XCMPLX_1:76
    .= (4*(sin(x1+x0)*sin(x1-x0)))/(cos(x0+x1)-cos(x0-x1))^2/(x0-x1)
    .= 4*(sin(x1+x0)*sin(x1-x0))/((cos(x0+x1)-cos(x0-x1))^2*(x0-x1))
                                                     by XCMPLX_1:78;
  hence thesis;
end;
