reserve y for set,
  x,r,a,b for Real,
  n for Element of NAT,
  Z for open Subset of REAL,
  f,f1,f2,f3 for PartFunc of REAL,REAL;

theorem Th10:
  Z c= dom (( #Z n)*(arcsin)) & Z c=]. -1,1 .[ implies ( #Z n)*(
arcsin) is_differentiable_on Z & for x st x in Z holds ((( #Z n)*arcsin)`|Z).x
  =n*(arcsin.x) #Z (n-1) / sqrt(1-x^2)
proof
  assume that
A1: Z c= dom (( #Z n)*arcsin) and
A2: Z c=]. -1,1 .[;
A3: for x st x in Z holds ( #Z n)*arcsin is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then arcsin is_differentiable_in x by A2,FDIFF_1:9,SIN_COS6:83;
    hence thesis by TAYLOR_1:3;
  end;
  then
A4: ( #Z n)*(arcsin) is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((( #Z n)*(arcsin))`|Z).x = n*(arcsin.x) #Z (n-1)
  / sqrt(1-x^2)
  proof
    let x;
    assume
A5: x in Z;
    then
A6: -1 < x & x < 1 by A2,XXREAL_1:4;
A7: arcsin is_differentiable_in x by A2,A5,FDIFF_1:9,SIN_COS6:83;
    ((( #Z n)*arcsin)`|Z).x = diff(( #Z n)*arcsin,x) by A4,A5,FDIFF_1:def 7
      .=(n*((arcsin.x) #Z (n-1))) * diff(arcsin,x) by A7,TAYLOR_1:3
      .=(n*((arcsin.x) #Z (n-1))) *(1 / sqrt(1-x^2)) by A6,SIN_COS6:83
      .=n*(arcsin.x) #Z (n-1) / sqrt(1-x^2) by XCMPLX_1:99;
    hence thesis;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
