
theorem
  for T being non empty TopStruct,S being sequence of T, x being Point
  of T st not S is_convergent_to x holds ex S1 being subsequence of S st for S2
  being subsequence of S1 holds not S2 is_convergent_to x
proof
  let T be non empty TopStruct,S be sequence of T, x be Point of T;
  assume not S is_convergent_to x;
  then consider A being Subset of T such that
A1: A is open & x in A and
A2: for n being Nat ex m being Nat st n <= m & not
  S.m in A;
  defpred P[set] means not $1 in A;
A3: for n being Element of NAT ex m being Element of NAT st n <= m & P[S.m]
   proof let n be Element of NAT;
    consider m being Nat such that
A4:   n <= m & not S.m in A by A2;
    reconsider m as Element of NAT by ORDINAL1:def 12;
    take m;
    thus thesis by A4;
   end;
  consider S1 being subsequence of S such that
A5: for n being Element of NAT holds P[S1.n] from VALUED_1:sch 1(A3);
  take S1;
  let S2 be subsequence of S1;
  ex U1 being Subset of T st U1 is open & x in U1 &
 for n being Nat ex m being Nat st n <= m & not S2.m in U1
  proof
    take A;
    consider NS being increasing sequence of NAT such that
A6: S2=S1*NS by VALUED_0:def 17;
    thus A is open & x in A by A1;
    let n be Nat;
    take n;
    thus n <= n;
    n in NAT by ORDINAL1:def 12;
    then n in dom S2 by NORMSP_1:12;
    then S2.n=S1.(NS.n) by A6,FUNCT_1:12;
    hence thesis by A5;
  end;
  hence thesis;
end;
