 reserve a,b,c,x for Real;

theorem Hope1:
  b - a > 0 implies
    rng ((AffineMap (1/(b-a),-a/(b-a)) | [.a,b.])) = [.0,1.]
  proof
    set f = AffineMap (1/(b-a),-a/(b-a));
    set g = f | [.a,b.];
    assume
A0: b - a > 0;
    thus rng g c= [.0,1.]
    proof
      let y be object;
      assume
Y0:   y in rng g; then
      consider x being object such that
A1:   x in dom g and
A2:   y = g.x by FUNCT_1:def 3;
Y1:   x in [.a,b.] by A1,RELAT_1:57;
      reconsider xx = x as Real by A1;
      reconsider yy = y as Real by Y0;
S4:   y = f.xx by FUNCT_1:47,A1,A2;
A4:   a <= xx by Y1,XXREAL_1:1;
S2:   f.a = 0 by Ah1;
S5:   f.a <= f.xx by A4,FCONT_1:53,A0;
      xx <= b by Y1,XXREAL_1:1; then
S6:   f.xx <= f.b by A0,FCONT_1:53;
      f.b = 1 by Ab1,A0;
      hence thesis by S4,S2,S5,S6;
    end;
    let y be object;
    assume
V1: y in [.0,1.]; then
    reconsider yy = y as Real;
    set A = 1 / (b-a);
    set B = -a / (b-a);
L2: (f qua Function)" = AffineMap (A",-B/A) by A0,FCONT_1:56; then
L3: (f qua Function)".0 = A" * 0 + -B/A by FCONT_1:def 4
     .= -(((-a) / (b-a))/(1 / (b-a))) by XCMPLX_1:187
     .= -((-a) / 1) by XCMPLX_1:55,A0
     .= a;
    set x = (f qua Function)".yy;
    reconsider xx = x as Real by L2;
X1: -B/A = -(((-a) / (b-a))/(1 / (b-a))) by XCMPLX_1:187
     .= -((-a) / 1) by XCMPLX_1:55,A0
     .= a;
L4: (f qua Function)".1 = A" * 1 + -B/A by FCONT_1:def 4,L2
     .= 1/A + -B/A by XCMPLX_1:215
     .= b-a + a by XCMPLX_1:52,X1
     .= b;
J2: 0 <= yy & yy <= 1 by XXREAL_1:1,V1; then
J3: a <= xx by FCONT_1:53,L2,A0,L3;
    xx <= b by FCONT_1:53,L2,A0,J2,L4; then
J4: x in [.a,b.] by J3;
j5: dom f = REAL by FUNCT_2:def 1;
T1: x in dom g by J4,j5,RELAT_1:57;
    rng f = REAL by FCONT_1:55,A0; then
S2: yy in rng f by XREAL_0:def 1;
    g.((f qua Function)".yy) = f.((f qua Function)".yy) by FUNCT_1:49,J4
       .= yy by A0,S2,FUNCT_1:35;
    hence thesis by T1,FUNCT_1:def 3;
  end;
