reserve p, q for FinSequence,
  e,X for set,
  i, j, k, m, n for Nat,
  G for Graph;
reserve x,y,v,v1,v2,v3,v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for oriented Chain of G;

theorem Th10:
  c <> {} & vs1 is_oriented_vertex_seq_of c & vs2 is_oriented_vertex_seq_of c
  implies vs1 = vs2
proof
  assume that
A1: c <>{} and
A2: vs1 is_oriented_vertex_seq_of c and
A3: vs2 is_oriented_vertex_seq_of c;
A4: len vs1 = len c + 1 by A2;
A5: len vs2 = len c + 1 by A3;
  for n be Nat st 1<=n & n<=len vs1 holds vs1.n=vs2.n
  proof
    let n be Nat;
    assume that
A6: 1<=n and
A7: n<=len vs1;
A8: n<=len c +1 by A2,A7;
    per cases;
    suppose n<len c +1;
      then
A9:  n<=len c by NAT_1:13;
      then c.n orientedly_joins vs1/.n, vs1/.(n+1) by A2,A6;
      then
A10:  (the Source of G).(c.n) = vs1/.n;
      c.n orientedly_joins vs2/.n, vs2/.(n+1) by A3,A6,A9;
      then
A11:  (the Source of G).(c.n) = vs2/.n;
      vs1.n=vs1/.n by A6,A7,FINSEQ_4:15;
      hence thesis by A4,A5,A6,A7,A10,A11,FINSEQ_4:15;
    end;
    suppose n>=len c+1;
      then
A12:  n=len c+1 by A8,XXREAL_0:1;
      then
A13:  n-1=len c;
A14:  0+1<=len c by A1,NAT_1:13;
      then
A15:  n-1=n-'1 by A12,NAT_D:39;
A16:  n-'1=len c by A13,A14,NAT_D:39;
      then
      c.(n-'1) orientedly_joins vs1/.(n-'1), vs1/.((n-'1)+1) by A2,A14;
      then
A17:  (the Target of G).(c.(n-'1)) = vs1/.((n-'1)+1);
      c.(n-'1) orientedly_joins vs2/.(n-'1), vs2/.((n-'1)+1) by A3,A14,A16;
      then
A18:  (the Target of G).(c.(n-'1)) = vs2/.((n-'1)+1);
      vs1.n=vs1/.n by A6,A7,FINSEQ_4:15;
      hence thesis by A4,A5,A6,A7,A15,A17,A18,FINSEQ_4:15;
    end;
  end;
  hence thesis by A4,A5,FINSEQ_1:14;
end;
