reserve n,m,k for Nat,
        p,q for n-element XFinSequence of NAT,
        i1,i2,i3,i4,i5,i6 for Element of n,
        a,b,c,d,e for Integer;

theorem Th10:
  for a,b,c,i1,i2,i3 holds
    {p: ex z be Nat st a*p.i1 = b*p.i2+ z*c*p.i3}
      is diophantine Subset of n -xtuples_of NAT
proof
  let a,b,c be Integer,i1,i2,i3 be Element of n;
  set F=F_Real;
  set n1=n+1;
  set D = {p: ex z be Nat st a*p.i1 = b*p.i2+ z*c*p.i3};
  D c= n -xtuples_of NAT
  proof
    let y be object;
    assume y in D;
    then ex p st
    y=p & ex z be Nat st a*p.i1 = b*p.i2+ z*c*p.i3;
    hence thesis by HILB10_2:def 5;
  end;
  then reconsider D as Subset of n -xtuples_of NAT;
  per cases;
  suppose n=0;
    then D is diophantine Subset of n -xtuples_of NAT;
    hence thesis;
  end;
  suppose A1: n<>0;
    A2: n< n1 by NAT_1:13;
    n in Segm n1 by A2,NAT_1:44;
    then reconsider I=i1,J=i2,K=i3,N=n as Element of n1
    by Th2;
    reconsider ar=a,br=b,cr = c as integer Element of F by XREAL_0:def 1;
    set Q=ar*1_1(I,F) - br*1_1(J,F)-cr*1_1(K,F)*'1_1(N,F);
    reconsider Q
    as INT -valued Polynomial of n+1,F_Real;
    for s be object holds
      s in D iff ex x be n-element XFinSequence of NAT,
      y be 1-element XFinSequence of NAT st
      s=x &  eval(Q,@(x^y)) = 0
    proof
      let s be object;
      thus s in D implies ex x be n-element XFinSequence of NAT,
        y be 1-element XFinSequence of NAT st
        s=x &  eval(Q,@(x^y)) = 0
      proof
        assume s in D;
        then consider p such that
        A3: s=p & ex z be Nat st a*p.i1 = b*p.i2+ z*c*p.i3;
        consider z be Nat such that
        A4:a*p.i1 = b*p.i2+ z*c*p.i3 by A3;
        reconsider z as Element of NAT by ORDINAL1:def 12;
        reconsider Z=<%z%> as 1-element XFinSequence of NAT;
        take p,Z;
        set P=@(p^Z);
        A5: len p = n by CARD_1:def 7;
        then
        A6: P.I = p.i1 & P.J = p.i2 & P.K = p.i3
        by A1, AFINSQ_1:def 3;
        A7: eval(1_1(I,F),P) = P.I & eval(1_1(J,F),P) = P.J &
            eval(1_1(K,F),P) = P.K & eval(1_1(N,F),P) =P.N &
              eval(1_(n1,F),P) = 1.F by Th1,POLYNOM2:21;
        A8: eval(cr*(1_1(K,F) *' 1_1(N,F)),P)
        = cr*eval(1_1(K,F) *' 1_1(N,F),P) by POLYNOM7:29
        .= cr*(eval(1_1(K,F),P)*eval(1_1(N,F),P)) by  POLYNOM2:25
        .= c*(P.K * P.N) by A7;
        eval(Q,P) =
        eval(ar*1_1(I,F) - br*1_1(J,F),P) - eval(cr*1_1(K,F)*'1_1(N,F),P)
        by POLYNOM2:24
        .=eval(ar*1_1(I,F),P)-eval(br*1_1(J,F),P)-eval(cr*1_1(K,F)*'1_1(N,F),P)
        by POLYNOM2:24
        .=ar*eval(1_1(I,F),P)-eval(br*1_1(J,F),P)-eval(cr*1_1(K,F)*'1_1(N,F),P)
        by POLYNOM7:29
        .=ar*eval(1_1(I,F),P)-br*eval(1_1(J,F),P)-eval(cr*1_1(K,F)*'1_1(N,F),P)
        by POLYNOM7:29
        .= ar * P.I - br* P.J - c*P.K * P.N by A7,A8
        .= a * (p.i1) - b* (p.i2) - c*(p.i3)*z by A5,AFINSQ_1:36,A6
        .= 0 by A4;
        hence thesis by A3;
      end;
      given p be n-element XFinSequence of NAT,
      Z be 1-element XFinSequence of NAT such that
      A9: s=p &  eval(Q,@(p^Z)) = 0;
      set P=@(p^Z);
      len p = n by CARD_1:def 7;then
      A10: P.I = p.i1 & P.J = p.i2 & P.K = p.i3
      by A1, AFINSQ_1:def 3;
      A11: eval(1_1(I,F),P) = P.I & eval(1_1(J,F),P) = P.J &
      eval(1_1(K,F),P) = P.K & eval(1_1(N,F),P) =P.N &
      eval(1_(n1,F),P) = 1.F by Th1,POLYNOM2:21;
      A12: eval(cr*(1_1(K,F) *' 1_1(N,F)),P)
      = cr*eval(1_1(K,F) *' 1_1(N,F),P) by POLYNOM7:29
      .= cr*(eval(1_1(K,F),P)*eval(1_1(N,F),P))
      by  POLYNOM2:25
      .= c*(P.K * P.N) by A11;
      eval(Q,P) =
      eval(ar*1_1(I,F) - br*1_1(J,F),P) - eval(cr*1_1(K,F)*'1_1(N,F),P)
      by POLYNOM2:24
      .=eval(ar*1_1(I,F),P)-eval(br*1_1(J,F),P) - eval(cr*1_1(K,F)*'1_1(N,F),P)
      by POLYNOM2:24
      .= ar*eval(1_1(I,F),P)-eval(br*1_1(J,F),P)-eval(cr*1_1(K,F)*'1_1(N,F),P)
      by POLYNOM7:29
      .= ar * eval(1_1(I,F),P) - br*eval(1_1(J,F),P) - c*(P.K * P.N)
      by A12,POLYNOM7:29
      .= a * (p.i1) - b* (p.i2) - c*(p.i3)*(P.N) by A10,A11;
      then a*p.i1 = b*p.i2+ (P.N)*c*p.i3 by A9;
      hence s in D by A9;
    end;
    then D is diophantine;
    hence thesis;
  end;
end;
