reserve i,j,n,n1,n2,m,k,l,u for Nat,
        i1,i2,i3,i4,i5,i6 for Element of n,
        p,q for n-element XFinSequence of NAT,
        a,b,c,d,e,f for Integer;

theorem Th9:
  for n being Ordinal,b being bag of n,r being Real st r >= 1
    for x being Function of n, the carrier of F_Real st
      for i being object st i in dom x holds |. x.i .| <= r holds
  |. eval(b,x).| <= r |^ (degree b)
proof
  let n be Ordinal,b be bag of n,r be Real such that
A1: r >= 1;
  let x be Function of n, F_Real such that
A2: for i be object st i in dom x holds |. x.i .| <= r;
  reconsider FR=F_Real as Field;
  reconsider X=x as Function of n, the carrier of F_Real;
  set sgm = SgmX(RelIncl n, support b),B=b*sgm;
A3: rng sgm c= n = dom b by PARTFUN1:def 2,RELAT_1:def 19;
  then
A4: dom (b*sgm) = dom sgm by RELAT_1:27;
  then
A5: len (b*sgm)=len sgm by FINSEQ_3:29;
  dom x= n by FUNCT_2:def 1;
  then
A6: dom (x*sgm) = dom sgm by A3,RELAT_1:27;
  consider y be FinSequence of FR such that
A7: len y = len sgm & eval(b,x) = Product y and
A8: for i being Element of NAT st 1 <= i & i <= len y holds
    y/.i = power(F_Real).((x * sgm)/.i,B/.i) by POLYNOM2:def 2;
  rng B c= NAT by VALUED_0:def 6;
  then reconsider B as FinSequence of NAT by FINSEQ_1:def 4;
  reconsider Y=y as FinSequence of F_Real;
  defpred P[Nat] means $1 <= len y implies Product (y|$1) is Real &
    for P be Real st P=Product (y|$1) holds |. P .| <= r|^ Sum (B|$1);
  reconsider ZERO=0 as Nat;
  y|ZERO=<*>the carrier of F_Real;
  then Product (y|ZERO) = 1_ F_Real by GROUP_4:8;
  then
A9: P[0] by NEWTON:4;
A10: for i st P[i] holds P[i+1]
  proof
    let i be Nat;set i1=i+1;
    assume that
A11:  P[i] and
A12:  i1 <= len y;
    reconsider yi1= y/.i1 ,Pi=Product (y|i) as Real;
A13:  |. Pi .| <= r|^ Sum (B|i) by A12,A11,NAT_1:13;
    i1 in dom y by A12,NAT_1:11,FINSEQ_3:25;
    then y|i1 = (y|i)^<*y.i1*> & y.i1 = y/.i1 by FINSEQ_5:10,PARTFUN1:def 6;
    then
A14:  Product (y|i1) = Product (y|i) * (y/.i1) by GROUP_4:6
      .= Pi * yi1 by BINOP_2:def 11;
    thus Product (y|i1) is Real;
    let P be Real such that
A15:  P=Product (y|i1);
A16:  |. P .| = |.Pi.| * |.yi1.| by A15,A14,COMPLEX1:65;
    i1 in dom B by A7,A12,A4,NAT_1:11,FINSEQ_3:25;
    then
A17:  B|i1 = (B|i)^<*B.i1*> & B.i1 = B/.i1 & B.i1 = b.(sgm.i1)
      by FINSEQ_5:10,PARTFUN1:def 6,FUNCT_1:12;
    then Sum (B|i1) = Sum(B|i) + (B/.i1) by RVSUM_1:74;
    then
A18:  r|^ Sum (B|i1) = (r |^ Sum (B|i)) * (r|^ (B/.i1)) by NEWTON:8;
A19:  |.yi1.| <= r|^ (B/.i1)
    proof
      y/.i1 = power(F_Real).((x * sgm)/.i1,B/.i1) by A8,A12,NAT_1:11
        .= ((x * sgm)/.i1) |^ (B/.i1) by NIVEN:7;
      then
A20:  |.yi1.| = |.(x * sgm)/.i1.| |^ (B/.i1) by TAYLOR_2:1;
      i1 in dom (x * sgm) by A6,A7,A12,NAT_1:11,FINSEQ_3:25;
      then
A21:    (x * sgm)/.i1 = (x * sgm).i1 & (x * sgm).i1 = x.(sgm.i1)
        & sgm.i1 in dom x & i1 in dom sgm by PARTFUN1:def 6,FUNCT_1:11,12;
      RelIncl n linearly_orders support b by PRE_POLY:82;
      then sgm.i1 in rng sgm = support b by A21,FUNCT_1:def 3,PRE_POLY:def 2;
      then B/.i1 <>0 by A17,PRE_POLY:def 7;
      then
A22:    B/.i1 >=1+0 by NAT_1:13;
      per cases by COMPLEX1:46;
      suppose |. (x * sgm)/.i1.| >0;
        hence thesis by A20,A2,A21,PREPOWER:9;
      end;
      suppose |.(x * sgm)/.i1.|=0;
        then |.(x * sgm)/.i1.| |^ (B/.i1) = 0 by A22,NEWTON:11;
        hence thesis by A1,A20;
      end;
    end;
A23:  |.Pi.|>=0 by COMPLEX1:46;
    |.yi1.|>=0 by COMPLEX1:46;
    hence thesis by A13,A18,A23,A16,A19,XREAL_1:66;
  end;
  for i holds P[i] from NAT_1:sch 2(A9,A10);
  then P[len y]; then
  |. eval(b,x) .| <= r|^ Sum (B|len B) by A5,A7;
  hence thesis by Th4;
end;
