reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;

theorem Th10:
  (AffineMap(1,0))(#)cosh-sinh is_differentiable_on REAL & for x
  holds (((AffineMap(1,0))(#)cosh-sinh)`|REAL).x=x*sinh.x
proof
A1: dom ((AffineMap(1,0))(#)cosh-sinh) = [#]REAL by FUNCT_2:def 1;
A2: dom (AffineMap(1,0)) = [#]REAL & for x st x in REAL holds AffineMap(1,0)
  .x=1 *x + 0 by FCONT_1:def 4,FUNCT_2:def 1;
  then
A3: AffineMap(1,0) is_differentiable_on REAL by FDIFF_1:23;
A4: dom ((AffineMap(1,0))(#)cosh) = [#]REAL by FUNCT_2:def 1;
  then
A5: ((AffineMap(1,0))(#)cosh) is_differentiable_on REAL by A3,FDIFF_1:21
,SIN_COS2:35;
 hence (AffineMap(1,0))(#)cosh-sinh is_differentiable_on REAL
 by A1,FDIFF_1:19,SIN_COS2:34;
A6: for x st x in REAL holds (((AffineMap(1,0))(#)cosh)`|REAL).x = cosh.x+x*
  sinh.x
  proof
    let x;
    assume
A7: x in REAL;
    (((AffineMap(1,0))(#)cosh)`|REAL).x = cosh.x*diff((AffineMap(1,0)),x)+
    ((AffineMap(1,0)).x) *diff(cosh,x) by A4,A3,FDIFF_1:21,SIN_COS2:35,A7
      .= cosh.x*(((AffineMap(1,0))`|REAL).x) +((AffineMap(1,0)).x)*diff(cosh
    ,x) by A3,FDIFF_1:def 7,A7
      .= cosh.x*1+((AffineMap(1,0)).x)*diff(cosh,x) by A2,FDIFF_1:23,A7
      .= cosh.x+((AffineMap(1,0)).x)*sinh.x by SIN_COS2:35
      .= cosh.x+(1*x + 0)*sinh.x by FCONT_1:def 4
      .= cosh.x+x*sinh.x;
    hence thesis;
  end;
A8:
  for x st x in REAL holds (((AffineMap(1,0))(#)cosh-sinh)`|REAL).x = x* sinh.x
  proof
    let x;
    assume
A9: x in REAL;
    (((AffineMap(1,0))(#)cosh - sinh)`|REAL).x = diff(((AffineMap(1,0))(#)
    cosh),x) - diff(sinh,x) by A1,A5,FDIFF_1:19,SIN_COS2:34,A9
      .= (((AffineMap(1,0))(#)cosh)`|REAL).x - diff(sinh,x)
by A5,FDIFF_1:def 7,A9
      .= cosh.x+x*sinh.x-diff(sinh,x) by A6,A9
      .= cosh.x+x*sinh.x-cosh.x by SIN_COS2:34
      .= x*sinh.x;
    hence thesis;
  end;
  let x;
   x in REAL by XREAL_0:def 1;
  hence thesis by A8;
end;
