reserve i,k,n,m for Element of NAT;
reserve a,b,r,r1,r2,s,x,x1,x2 for Real;
reserve A for non empty closed_interval Subset of REAL;
reserve X for set;

theorem Th10:
  for f being PartFunc of REAL,REAL st A c= dom f & f|A is
  continuous holds f|A is bounded
proof
  let f be PartFunc of REAL,REAL;
  assume
A1: A c= dom f;
  assume f|A is continuous;
  then
A2: f.:A is real-bounded by A1,FCONT_1:29,RCOMP_1:10;
  then consider a be Real such that
A3: a is UpperBound of f.:A by XXREAL_2:def 10;
A4: for r be Real st r in f.:A holds r <= a by A3,XXREAL_2:def 1;
  consider b be Real such that
A5: b is LowerBound of f.:A by A2,XXREAL_2:def 9;
A6: for r be Real st r in f.:A holds b <= r by A5,XXREAL_2:def 2;
  for x being object st x in A /\ dom f holds b <= f.x
  proof
    let x be object;
    assume x in A /\ dom f;
    then x in A & x in dom f by XBOOLE_0:def 4;
    then f.x in f.:A by FUNCT_1:def 6;
    hence thesis by A6;
  end;
  then
A7: f|A is bounded_below by RFUNCT_1:71;
  for x being object st x in A /\ dom f holds f.x <= a
  proof
    let x be object;
    assume x in A /\ dom f;
    then x in A & x in dom f by XBOOLE_0:def 4;
    then f.x in f.:A by FUNCT_1:def 6;
    hence thesis by A4;
  end;
  then f|A is bounded_above by RFUNCT_1:70;
  hence thesis by A7;
end;
