reserve T,T1,T2,S for non empty TopSpace;

theorem Th10: :: BORSUK_1:def 2
  for X,Y being non empty TopSpace,f being Function of X,Y holds f
is continuous iff for p being Point of X,V being Subset of Y st f.p in V & V is
  open holds ex W being Subset of X st p in W & W is open & f.:W c= V
proof
  let X,Y be non empty TopSpace,f be Function of X,Y;
A1: [#]Y <> {};
A2: dom f=the carrier of X by FUNCT_2:def 1;
  hereby
    assume
A3: f is continuous;
    thus for p being Point of X,V being Subset of Y st f.p in V & V is open
    holds ex W being Subset of X st p in W & W is open & f.:W c= V
    proof
      let p be Point of X,V be Subset of Y;
      assume f.p in V & V is open;
      then
A4:   f"V is open & p in f"V by A2,A1,A3,FUNCT_1:def 7,TOPS_2:43;
      f.:(f"V) c= V by FUNCT_1:75;
      hence thesis by A4;
    end;
  end;
  assume
A5: for p being Point of X,V being Subset of Y st f.p in V & V is open
  holds ex W being Subset of X st p in W & W is open & f.:W c= V;
  for G being Subset of Y st G is open holds f"G is open
  proof
    let G be Subset of Y;
    assume
A6: G is open;
    for z being set holds z in f"G iff ex Q being Subset of X st Q is
    open & Q c= f"G & z in Q
    proof
      let z be set;
      now
        assume
A7:     z in f"G;
        then reconsider p=z as Point of X;
        f.z in G by A7,FUNCT_1:def 7;
        then consider W being Subset of X such that
A8:     p in W & W is open and
A9:     f.:W c= G by A5,A6;
A10:    W c= f"(f.:W) by A2,FUNCT_1:76;
        f"(f.:W) c= f"G by A9,RELAT_1:143;
        hence ex Q being Subset of X st Q is open & Q c= f"G & z in Q by A8,A10
,XBOOLE_1:1;
      end;
      hence thesis;
    end;
    hence thesis by TOPS_1:25;
  end;
  hence thesis by A1,TOPS_2:43;
end;
