reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;

theorem Th10:
  for f,g holds
  INTERSECTION({ LSeg(f,i) where i is Nat : 1 <= i & i+1 <= len f }
  , { LSeg(g,j) where j is Nat : 1 <= j & j+1 <= len g }) is finite
proof
  deffunc F(set,set)=$1 /\ $2;
  let f,g;
  set AL = { LSeg(f,i) where i is Nat : 1 <= i & i+1 <= len f };
  set BL = { LSeg(g,j) where j is Nat: 1 <= j & j+1 <= len g };
  set IN = { F(X,Y) where X is Subset of TOP-REAL 2, Y is Subset of TOP-REAL 2
  : X in AL & Y in BL };
A1: BL is finite by SPPOL_1:23;
  set C = INTERSECTION(AL,BL);
A2: C c= IN
  proof
    let a be object;
    assume a in C;
    then consider X,Y such that
A3: X in AL & Y in BL and
A4: a = X /\ Y by SETFAM_1:def 5;
    (ex i st X = LSeg(f,i) & 1 <= i & i+1 <= len f )& ex j st Y = LSeg(g,
    j) & 1 <= j & j+1 <= len g by A3;
    then reconsider X,Y as Subset of TOP-REAL 2;
    X /\ Y in IN by A3;
    hence thesis by A4;
  end;
A5: AL is finite by SPPOL_1:23;
  IN is finite from FRAENKEL:sch 22(A5,A1);
  hence thesis by A2;
end;
