reserve p,p1,p2,p3,q for Point of TOP-REAL 2;

theorem Th10:
  for P being compact non empty Subset of TOP-REAL 2, q1,q2,q3
  being Point of TOP-REAL 2 st P is being_simple_closed_curve & LE q1,q2,P & LE
q2,q3,P & not(q1=q2 & q1=W-min(P)) & not(q2=q3 & q2=W-min(P)) holds Segment(q1,
  q2,P)/\ Segment(q2,q3,P)={q2}
proof
  let P be compact non empty Subset of TOP-REAL 2, q1,q2,q3 be Point of
  TOP-REAL 2;
  assume that
A1: P is being_simple_closed_curve and
A2: LE q1,q2,P and
A3: LE q2,q3,P and
A4: not(q1=q2 & q1=W-min(P)) and
A5: not(q2=q3 & q2=W-min(P));
A6: Upper_Arc(P) is_an_arc_of W-min(P),E-max(P) by A1,JORDAN6:def 8;
  thus Segment(q1,q2,P)/\ Segment(q2,q3,P) c= {q2}
  proof
    let x be object;
    assume
A7: x in Segment(q1,q2,P)/\ Segment(q2,q3,P);
    then
A8: x in Segment(q2,q3,P) by XBOOLE_0:def 4;
A9: x in Segment(q1,q2,P) by A7,XBOOLE_0:def 4;
    now
      per cases;
      case
        q3<>W-min(P);
        then x in {p: LE q2,p,P & LE p,q3,P} by A8,Def1;
        then
A10:    ex p st p=x & LE q2,p,P & LE p,q3,P;
        per cases;
        suppose
          q2<>W-min(P);
          then x in {p2: LE q1,p2,P & LE p2,q2,P} by A9,Def1;
          then ex p2 st p2=x & LE q1,p2,P & LE p2,q2,P;
          hence x=q2 by A1,A10,JORDAN6:57;
        end;
        suppose
A11:      q2=W-min(P);
          then LE q1,q2,Upper_Arc(P),W-min(P),E-max(P) by A2,JORDAN6:def 10;
          hence x=q2 by A4,A6,A11,JORDAN6:54;
        end;
      end;
      case
A12:    q3=W-min(P);
        then x in {p1: LE q2,p1,P or q2 in P & p1=W-min(P)} by A8,Def1;
        then consider p1 such that
A13:    p1=x and
A14:    LE q2,p1,P or q2 in P & p1=W-min(P);
        p1 in {p: LE q1,p,P & LE p,q2,P} by A5,A9,A12,A13,Def1;
        then ex p st p=p1 & LE q1,p,P & LE p,q2,P;
        hence x=q2 by A1,A3,A12,A13,A14,JORDAN6:57;
      end;
    end;
    hence thesis by TARSKI:def 1;
  end;
  let x be object;
  assume x in {q2};
  then x=q2 by TARSKI:def 1;
  then x in Segment(q1,q2,P) & x in Segment(q2,q3,P) by A1,A2,A3,Th6;
  hence thesis by XBOOLE_0:def 4;
end;
