reserve X for set,
  x,y,z for Element of BooleLatt X,
  s for set;
reserve y for Element of BooleLatt X;
reserve L for Lattice,
  p,q for Element of L;
reserve A for RelStr,
  a,b,c for Element of A;

theorem
  A is with_suprema iff A~ is with_infima
proof
  thus A is with_suprema implies A~ is with_infima
  proof
    assume
A1: for a,b ex c st a <= c & b <= c &
    for c9 being Element of A st a <= c9 & b <= c9 holds c <= c9;
    let x,y be Element of A~;
    consider c such that
A2: ~x <= c and
A3: ~y <= c and
A4: for c9 being Element of A st ~x <= c9 & ~y <= c9 holds c <= c9 by A1;
    take z = c~;
A5: (~x)~ = ~x;
A6: (~y)~ = ~y;
    hence z <= x & z <= y by A2,A3,A5,Th9;
    let z9 be Element of A~;
A7: (~z9)~ = ~z9;
    assume that
A8: z9 <= x and
A9: z9 <= y;
A10: ~x <= ~z9 by A5,A7,A8,Th9;
    ~y <= ~z9 by A6,A7,A9,Th9;
    then c <= ~z9 by A4,A10;
    hence thesis by A7,Th9;
  end;
  assume
A11: for x,y being Element of A~ ex z being Element of A~ st z <= x & z <= y &
  for z9 being Element of A~ st z9 <= x & z9 <= y holds z9 <= z;
  let a,b;
  consider z being Element of A~ such that
A12: z <= a~ and
A13: z <= b~ and
A14: for z9 being Element of A~ st z9 <= a~ & z9 <= b~ holds z9 <= z by A11;
  take c = ~z;
A15: (~z)~ = ~z;
  hence a <= c & b <= c by A12,A13,Th9;
  let c9 be Element of A;
  assume that
A16: a <= c9 and
A17: b <= c9;
A18: c9~ <= a~ by A16,Th9;
  c9~ <= b~ by A17,Th9;
  then c9~ <= z by A14,A18;
  hence thesis by A15,Th9;
end;
