reserve X for non empty set;
reserve e for set;
reserve x for Element of X;
reserve f,g for PartFunc of X,ExtREAL;
reserve S for SigmaField of X;
reserve F for Function of RAT,S;
reserve p,q for Rational;
reserve r for Real;
reserve n,m for Nat;
reserve A,B for Element of S;

theorem Th10:
  for C being non empty set, f being PartFunc of C,ExtREAL, r be Real
  st f is real-valued holds r(#)f is real-valued
proof
  let C be non empty set;
  let f be PartFunc of C,ExtREAL;
  let r be Real;
  assume
A1: f is real-valued;
   for x being Element of C st x in dom(r(#)f) holds |.(r(#)f).x .| < +infty
  proof
    let x be Element of C;
    assume
A2: x in dom(r(#)f);
then  x in dom f by MESFUNC1:def 6;
then A3: |. f.x .| < +infty by A1;
then  -(+infty) < f.x by EXTREAL1:21;
then A4: -infty < f.x by XXREAL_3:def 3;
 f.x < +infty by A3,EXTREAL1:21;
   then reconsider y = f.x as Element of REAL by A4,XXREAL_0:14;
   reconsider yy = f.x as Element of ExtREAL;
   reconsider ry = r*y as Element of REAL by XREAL_0:def 1;
A5: -infty < (ry) by XXREAL_0:12;
A6: (ry) < +infty by XXREAL_0:9;
A7: -infty <  r *  y by A5;
A8:  r *  y = r * yy by XXREAL_3:def 5
       .= (r(#)f).x by A2,MESFUNC1:def 6;
then A9: -(+infty) < (r(#)f).x by A7,XXREAL_3:def 3;
 (r(#)f).x < +infty by A6,A8;
    hence thesis by A9,EXTREAL1:22;
  end;
  hence thesis;
end;
