reserve X,X1 for set,
  r,s for Real,
  z for Complex,
  RNS for RealNormSpace,
  CNS, CNS1,CNS2 for ComplexNormSpace;

theorem Th10:
  for f be PartFunc of CNS1,CNS2 st f is_uniformly_continuous_on X
  holds z(#)f is_uniformly_continuous_on X
proof
  let f be PartFunc of CNS1,CNS2;
  assume
A1: f is_uniformly_continuous_on X;
  then X c= dom f;
  hence
A2: X c= dom (z(#)f) by VFUNCT_2:def 2;
  now
    per cases;
    suppose
A3:   z=0;
      let r;
      assume
A4:   0<r;
      then consider s such that
A5:   0<s and
      for x1,x2 be Point of CNS1 st x1 in X & x2 in X & ||.x1-x2.||<s
      holds ||.f/.x1-f/.x2.||<r by A1;
      take s;
      thus 0<s by A5;
      let x1,x2 be Point of CNS1;
      assume that
A6:   x1 in X and
A7:   x2 in X and
      ||.x1-x2.||<s;
      ||.(z(#)f)/.x1-(z(#)f)/.x2.|| = ||.z*(f/.x1)-(z(#)f)/.x2.|| by A2,A6,
VFUNCT_2:def 2
        .= ||.0.CNS2 -(z(#)f)/.x2.|| by A3,CLVECT_1:1
        .= ||.0.CNS2 - z*(f/.x2).|| by A2,A7,VFUNCT_2:def 2
        .= ||.0.CNS2 - 0.CNS2.|| by A3,CLVECT_1:1
        .= ||.0.CNS2 .|| by RLVECT_1:13
        .= 0 by NORMSP_0:def 6;
      hence ||.(z(#)f)/.x1-(z(#)f)/.x2.|| <r by A4;
    end;
    suppose
A8:   z<>0;
      let r;
A9:   0<|.z.| by A8,COMPLEX1:47;
      assume 0<r;
      then 0 < r/|.z.| by A9;
      then consider s such that
A10:  0<s and
A11:  for x1,x2 be Point of CNS1 st x1 in X & x2 in X & ||.x1-x2.||<s
      holds ||.f/.x1-f/.x2.||<r/|.z.| by A1;
      take s;
      thus 0<s by A10;
      let x1,x2 be Point of CNS1;
      assume that
A12:  x1 in X and
A13:  x2 in X and
A14:  ||.x1-x2.||<s;
A15:  ||.(z(#)f)/.x1-(z(#)f)/.x2.|| = ||.z*(f/.x1)-(z(#)f)/.x2.|| by A2,A12,
VFUNCT_2:def 2
        .= ||.z*(f/.x1) - z*(f/.x2).|| by A2,A13,VFUNCT_2:def 2
        .= ||.z*(f/.x1 - f/.x2).|| by CLVECT_1:9
        .= |.z.|*||.f/.x1 - f/.x2.|| by CLVECT_1:def 13;
      |.z.|*||.f/.x1-f/.x2.||<r/|.z.|*|.z.| by A9,A11,A12,A13,A14,XREAL_1:68;
      hence ||.(z(#)f)/.x1-(z(#)f)/.x2.|| <r by A9,A15,XCMPLX_1:87;
    end;
  end;
  hence thesis;
end;
