reserve F for Field;
reserve S for OrtSp of F;
reserve a,b,c,d,p,q,r,x,y,z for Element of S;
reserve k,l for Element of F;

theorem
  1_F+1_F <> 0.F & (ex a st a<>0.S) implies ex b st not b _|_ b
proof
  set 1F = 1_F,0V = 0.S;
  assume that
A1: 1_F+1_F<>0.F and
A2: ex a st a<>0.S;
  consider a such that
A3: a<>0.S by A2;
  assume
A4: not thesis;
A5: for c,d holds c _|_ d
  proof
    let c,d;
    d _|_ d & c _|_ c by A4;
    then d+c _|_ d-c by Th9;
    then
A6: d-c _|_ d+c by Th2;
    d+c _|_ d+c by A4;
    then (d+c)+((-c)+d) _|_ d+c by A6,Def1;
    then ((d+c)+(-c))+d _|_ d+c by RLVECT_1:def 3;
    then (d+(c+(-c)))+d _|_ d+c by RLVECT_1:def 3;
    then (d+0V)+d _|_ d+c by RLVECT_1:5;
    then d+d _|_ d+c by RLVECT_1:4;
    then (1F)*d+d _|_ d+c;
    then (1F)*d+(1F)*d _|_ d+c;
    then (1F+1F)*d _|_ d+c by VECTSP_1:def 15;
    then (1F+1F)"*((1F+1F)*d) _|_ d+c by Def1;
    then ((1F+1F)"*(1F+1F))*d _|_ d+c by VECTSP_1:def 16;
    then (1F)*d _|_ d+c by A1,VECTSP_1:def 10;
    then d _|_ d+c;
    then
A7: d+c _|_ d by Th2;
    -d _|_ d by A4,Th6;
    then -d+(d+c) _|_ d by A7,Def1;
    then (-d+d)+c _|_ d by RLVECT_1:def 3;
    then 0V+c _|_ d by RLVECT_1:5;
    hence thesis by RLVECT_1:4;
  end;
  ex c st not c _|_ a & not c _|_ a & not c _|_ a & not c _|_ a by A3,Def1;
  hence contradiction by A5;
end;
