reserve I,J for set,i,j,x for object,
  S for non empty ManySortedSign;

theorem Th10:
  for I be non empty set, S be non void non empty ManySortedSign,
A be MSAlgebra-Family of I,S, o be OperSymbol of S, f be Function st f in dom (
Frege (A?.o)) holds dom f = I & (for i be Element of I holds f.i in Args(o,A.i)
  ) & rng f c= Funcs(dom(the_arity_of o),|.A.|)
proof
  let I be non empty set, S be non void non empty ManySortedSign, A be
  MSAlgebra-Family of I,S, o be OperSymbol of S, f be Function;
  assume
A1: f in dom (Frege (A?.o));
A2: dom (A?.o) = I by PARTFUN1:def 2;
A3: dom (Frege (A?.o)) = product doms (A?.o) by PARTFUN1:def 2;
A4: dom doms (A?.o) = dom(A?.o) by FUNCT_6:def 2;
  hence dom f = I by A1,A3,A2,CARD_3:9;
  thus
A5: for i be Element of I holds f.i in Args(o,A.i)
  proof
    let i be Element of I;
    (A?.o).i = Den(o,A.i) & f.i in (doms(A?.o)).i by A1,A3,A2,A4,Th7,CARD_3:9;
    then f.i in dom Den(o,A.i) by A2,FUNCT_6:22;
    hence thesis by FUNCT_2:def 1;
  end;
  let x be object;
  assume x in rng f;
  then consider y be object such that
A6: y in dom f and
A7: x = f.y by FUNCT_1:def 3;
  reconsider y as Element of I by A1,A3,A2,A4,A6,CARD_3:9;
  set X = the carrier' of S, AS = (the Sorts of A.y)# * the Arity of S, Ar =
the Arity of S, Cr = the carrier of S, So = the Sorts of A.y, a = the_arity_of
  o;
A8: dom Ar = X by FUNCT_2:def 1;
  then
A9: dom AS = dom Ar by PARTFUN1:def 2;
A10: Args(o,A.y) = AS.o by MSUALG_1:def 4
    .= (So# qua ManySortedSet of Cr*).(Ar.o) by A8,A9,FUNCT_1:12
    .=(So# qua ManySortedSet of Cr*).(the_arity_of o) by MSUALG_1:def 1
    .= product (So*(the_arity_of o)) by FINSEQ_2:def 5;
  x in Args(o,A.y) by A5,A7;
  then consider g be Function such that
A11: g = x and
A12: dom g = dom (So*a) and
A13: for i being object st i in dom (So * a) holds g.i in (So * a).i
by A10,CARD_3:def 5;
A14: rng a c= Cr & dom So = Cr by FINSEQ_1:def 4,PARTFUN1:def 2;
  then
A15: dom (So * a) = dom a by RELAT_1:27;
A16: rng g c= |.A.y.|
  proof
    let i be object;
    assume i in rng g;
    then consider j being object such that
A17: j in dom g and
A18: g.j = i by FUNCT_1:def 3;
    a.j in rng a by A12,A15,A17,FUNCT_1:def 3;
    then
A19: So.(a.j) in rng So by A14,FUNCT_1:def 3;
    i in (So * a).j by A12,A13,A17,A18;
    then i in So.(a.j) by A12,A17,FUNCT_1:12;
    hence thesis by A19,TARSKI:def 4;
  end;
  |.A.y.| in the set of all |.A.i.| where i is Element of I;
  then |.A.y.| c= union the set of all |.A.i.| where i is Element of I
  by ZFMISC_1:74;
  then rng g c= |.A.| by A16;
  hence thesis by A11,A12,A15,FUNCT_2:def 2;
end;
