reserve Al for QC-alphabet;
reserve PHI for Consistent Subset of CQC-WFF(Al),
        p,q,r,s for Element of CQC-WFF(Al),
        A for non empty set,
        J for interpretation of Al,A,
        v for Element of Valuations_in(Al,A),
        m,n,i,j,k for Nat,
        l for CQC-variable_list of k,Al,
        P for QC-pred_symbol of k,Al,
        x,y,z for bound_QC-variable of Al,
        b for QC-symbol of Al,
        PR for FinSequence of [:set_of_CQC-WFF-seq(Al),Proof_Step_Kinds:];
reserve Al2 for Al-expanding QC-alphabet,
        J2 for interpretation of Al2,A,
        Jp for interpretation of Al,A,
        v2 for Element of Valuations_in(Al2,A),
        vp for Element of Valuations_in(Al,A);

theorem
  for Al2 being Al-expanding QC-alphabet,
  THETA being Subset of CQC-WFF(Al2) st PHI c= THETA holds
   for A2 being non empty set, J2 being interpretation of Al2,A2,
   v2 being Element of Valuations_in (Al2,A2) st J2,v2 |= THETA holds
   ex A,J,v st J,v |= PHI
proof
  let Al2 be Al-expanding QC-alphabet,
  THETA be Subset of CQC-WFF(Al2) such that
A1: PHI c= THETA;
  let A2 be non empty set, J2 be interpretation of Al2,A2,
      v2 be Element of Valuations_in(Al2,A2) such that
A2:  J2,v2 |= THETA;
  set A = A2;
A3: QC-pred_symbols(Al) c= QC-pred_symbols(Al2) by Th3;
  set Jp = J2|QC-pred_symbols(Al);
  reconsider Jp as Function of QC-pred_symbols(Al),relations_on A
   by A3,FUNCT_2:32;
  for P being Element of QC-pred_symbols(Al),
  r being Element of relations_on A st Jp.P = r holds
  r = empty_rel(A) or the_arity_of P = the_arity_of r
  proof
    let P be Element of QC-pred_symbols(Al),
        r be Element of relations_on A such that
A4:     Jp.P = r;
    P is Element of QC-pred_symbols(Al2) by Th3,TARSKI:def 3;
    then consider Q being Element of QC-pred_symbols(Al2) such that
A5: P = Q;
A6: P`1 = 7+the_arity_of P & Q`1 = 7+the_arity_of Q by QC_LANG1:def 8;
    Jp.P = J2.Q by A5,FUNCT_1:49;
    hence thesis by A4,A5,A6,VALUAT_1:def 5;
  end;
  then reconsider Jp as interpretation of Al,A by VALUAT_1:def 5;
A7: bound_QC-variables(Al) c= bound_QC-variables(Al2) by Th4;
  set vp = v2|bound_QC-variables(Al);
  reconsider vp as Function of bound_QC-variables(Al),A
   by A7, FUNCT_2:32;
A8: Funcs(bound_QC-variables(Al),A) = Valuations_in(Al,A) by VALUAT_1:def 1;
  reconsider vp as Element of Valuations_in(Al,A) by A8,FUNCT_2:8;
  for r being Element of CQC-WFF(Al) holds
  r in PHI implies Jp,vp |= r
  proof
    let r be Element of CQC-WFF(Al) such that
A9: r in PHI;
    J2,v2 |= Al2-Cast(r) by A1,A2,A9,CALCUL_1:def 11;
    hence thesis by Th9;
  end;
  hence thesis by CALCUL_1:def 11;
end;
