reserve R for Ring,
  I for Ideal of R,
  a, b for Element of R;

theorem
  Class EqRel(R,{0.R}) = rng singleton the carrier of R
proof
  set E = EqRel(R,{0.R});
  set f = singleton the carrier of R;
A1: dom f = the carrier of R by FUNCT_2:def 1;
  thus Class E c= rng f
  proof
    let A be object;
    assume A in Class E;
    then consider x being object such that
A2: x in the carrier of R and
A3: A = Class(E,x) by EQREL_1:def 3;
    reconsider x as Element of R by A2;
A4: Class(E,x) = {x}
    proof
      thus Class(E,x) c= {x}
      proof
        let a be object;
        assume
A5:     a in Class(E,x);
        then reconsider a as Element of R;
        [a,x] in E by A5,EQREL_1:19;
        then a-x in {0.R} by Def5;
        then a-x = 0.R by TARSKI:def 1;
        then a = x by RLVECT_1:21;
        hence thesis by TARSKI:def 1;
      end;
      let a be object;
      x-x = 0.R by RLVECT_1:15;
      then
A6:   x-x in {0.R} by TARSKI:def 1;
      assume a in {x};
      then a = x by TARSKI:def 1;
      then [a,x] in E by A6,Def5;
      hence thesis by EQREL_1:19;
    end;
    f.x = {x} by SETWISEO:def 6;
    hence thesis by A1,A3,A4,FUNCT_1:def 3;
  end;
  let A be object;
  assume A in rng f;
  then consider w being object such that
A7: w in dom f and
A8: f.w = A by FUNCT_1:def 3;
  f.w = {w} by A7,SETWISEO:def 6
    .= Class(E,w) by A7,Th9;
  hence thesis by A7,A8,EQREL_1:def 3;
end;
