reserve n for Nat,
  a,b,c,d for Real,
  s for Real_Sequence;

theorem
  (a <> 1 & for n holds s.n = a|^n) implies Partial_Sums(s).n = (1 - a|^
  (n+1))/(1-a)
proof
  defpred X[Nat] means Partial_Sums(s).$1 = (1 - a|^($1+1))/(1-a);
  assume a<>1;
  then
A1: 1-a <> 0;
  assume
A2: for n holds s.n = a|^n;
A3: for n st X[n] holds X[n+1]
  proof
    let n;
    assume Partial_Sums(s).n = (1 - a|^(n+1))/(1-a);
    hence Partial_Sums(s).(n+1) = (1 - a|^(n+1))/(1-a) + s.(n+1) by
SERIES_1:def 1
      .= (1 - a |^(n+1))/(1-a) + a|^(n+1) * 1 by A2
      .= (1-a|^(n+1))/(1-a)+a|^(n+1)*((1-a)/(1-a)) by A1,XCMPLX_1:60
      .= (1-a|^(n+1))/(1-a)+(a|^(n+1)*(1-a))/(1-a) by XCMPLX_1:74
      .= (1-a|^(n+1) + (a|^(n+1)-a |^ (n+1)*a))/(1-a) by XCMPLX_1:62
      .= (1-a|^(n+1) + (a|^(n+1)-a|^(n+1+1)))/(1-a) by NEWTON:6
      .= (1 - a|^(n+1+1))/(1-a);
  end;
  Partial_Sums(s).0 = s.0 by SERIES_1:def 1
    .= a|^0 by A2
    .= 1 by NEWTON:4
    .= (1-a)/(1-a) by A1,XCMPLX_1:60
    .= (1-a|^(0+1))/(1-a);
  then
A4: X[0];
  for n holds X[n] from NAT_1:sch 2(A4,A3);
  hence thesis;
end;
