reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th10:
  for C being Subset of N holds ( C <> {} & C is bounded implies
ex r,w st 0<r & w in C & for z being Point of N st z in C holds dist(w,z)<=r )
& (N is symmetric triangle & (ex r,w st 0<r & for z being Point of N st z in C
  holds dist(w,z)<=r) implies C is bounded)
proof
  let C be Subset of N;
  thus C <> {} & C is bounded implies ex r,w st 0<r & w in C & for z being
  Point of N st z in C holds dist(w,z)<=r
  proof
    set w = the Element of C;
    assume
A1: C <> {};
    then reconsider w as Point of N by TARSKI:def 3;
    assume C is bounded;
    then consider r such that
A2: 0<r and
A3: for x,y being Point of N st x in C & y in C holds dist(x,y)<=r;
    take r;
    take w;
    thus 0<r by A2;
    thus w in C by A1;
    let z be Point of N;
    assume z in C;
    hence thesis by A3;
  end;
  assume
A4: N is symmetric;
  assume
A5: N is triangle;
  given r,w such that
A6: 0<r and
A7: for z being Point of N st z in C holds dist(w,z)<=r;
  set s = r+r;
   reconsider N as symmetric MetrStruct by A4;
   reconsider w as Element of N;
  ex s st 0<s & for x,y being Point of N st x in C & y in C holds dist(x, y)<=s
  proof
    take s;
    thus 0<s by A6;
    let x,y be Point of N;
    assume that
A8: x in C and
A9: y in C;
A10: dist(w,x)<=r by A7,A8;
    dist(w,y)<=r by A7,A9;
    then
A11: dist(x,w)+dist(w,y)<=s by A10,XREAL_1:7;
    dist(x,y)<=dist(x,w)+dist(w,y) by A5,METRIC_1:4;
    hence thesis by A11,XXREAL_0:2;
  end;
  hence thesis;
end;
