reserve K,F for Ring;
reserve V,W for VectSp of K;
reserve l for Linear_Combination of V;
reserve T for linear-transformation of V,W;

theorem Th38A:
  for K being Field
  for V being finite-dimensional VectSp of K,
  W being Subspace of V holds
  ex S being Linear_Compl of W,
  T being linear-transformation of S, VectQuot(V,W)
  st T is bijective &
  for v being Vector of V st v in S holds T.v = v+ W
  proof
    let K be Field;
    let V be finite-dimensional VectSp of K,
    W be Subspace of V;
    set S = the Linear_Compl of W;
    set aC = addCoset(V,W);
    set C = CosetSet(V,W);
    set Vq = VectQuot(V,W);
    defpred P[Vector of V,Vector of Vq] means $2 = $1 + W;
    A2:
    now
      let v be Vector of V;
      reconsider y=v+W as Vector of Vq by VECTSP10:23;
      take y;
      thus P[v, y];
    end;
    consider ff be Function of the carrier of V, the carrier of Vq such that
    A7: for v being Vector of V holds P[v, ff.v] from FUNCT_2:sch 3(A2);
    set T = ff| the carrier of S;
    S1: the carrier of S c= the carrier of V by VECTSP_4:def 2;
    then reconsider T as Function of the carrier of S,the carrier of Vq
    by FUNCT_2:32;
    P1: for v being Vector of V st v in S holds T.v = v+ W
    proof
      let v be Vector of V;
      assume v in S;
      hence T.v = ff.v by FUNCT_1:49
      .= v+W by A7;
    end;
    now
      let a, b be Vector of S;
      reconsider a1 = a, b1 = b as Vector of V by S1;
      A91: a1 in S & b1 in S;
      a1+b1 = a+b by VECTSP_4:13; then
      A94: a1+b1 in S;
      A95: T.a = a1+W by P1,A91;
      A96: T.b = b1+W by P1,A91;
      thus T.(a+b) = T.(a1+b1) by VECTSP_4:13
      .= (a1+b1) + W by A94,P1
      .= T.a + T.b by A95,A96,VECTSP10:26;
    end; then
    AD: T is additive;
    now
      let a be Vector of S;
      let r be Element of K;
      reconsider a1 = a as Vector of V by S1;
      A91: a1 in S;
      r*a = r*a1 by VECTSP_4:14; then
      A94: r*a1 in S;
      A95: T.a = a1+W by P1,A91;
      thus T.(r*a) = T.(r*a1) by VECTSP_4:14
      .= (r*a1) + W by A94,P1
      .= r*T.a by A95,VECTSP10:25;
    end;
    then T is homogeneous;
    then reconsider T as linear-transformation of S,Vq by AD;
    A100: V is_the_direct_sum_of S,W by VECTSP_5:def 5;
    the carrier of Vq c= rng T
    proof
      let y be object;
      assume y in the carrier of Vq;
      then consider a be Vector of V such that
      A10: y = a+W by VECTSP10:22;
      the ModuleStr of V = S+W by A100,VECTSP_5:def 4;
      then a in S+W;
      then consider s, w be Element of V such that
      A12: s in S & w in W & a = s + w by VECTSP_5:1;
      reconsider s0 = s as Vector of S by A12;
      reconsider B = s+W as Vector of Vq by VECTSP10:23;
      reconsider A = a+W, Z = w+W as Vector of Vq by VECTSP10:23;
      Z = zeroCoset (V,W) by A12,VECTSP_4:49
      .= 0.Vq by VECTSP10:def 6; then
      A13: B = B+Z
      .= A by A12,VECTSP10:26;
      T.s0 = y by A10,A12,A13,P1;
      hence y in rng T by FUNCT_2:4;
    end;
    then rng T = the carrier of Vq; then
    A14: T is onto;
    X1: for x1,x2 being object st x1 in the carrier of S
    & x2 in the carrier of S & T.x1 = T.x2 holds x1 = x2
    proof
      let x1,x2 be object;
      assume A15: x1 in the carrier of S
      & x2 in the carrier of S & T.x1 = T.x2;
      then reconsider a1=x1,a2=x2 as Vector of V by S1;
      A16: a1 in S & a2 in S by A15;
      A17: T.x1 = a1+W by P1,A16;
      T.x2 = a2+W by P1,A16;
      then consider w be Element of V such that
      A19: w in W & a2 = a1 + w by A15,A17,VECTSP_4:42,VECTSP_4:55;
      A20: a2-a1 = w +(a1 -a1) by A19,RLVECT_1:28
      .= w + 0.V by VECTSP_1:19
      .= w;
      a2-a1 in S by A16,VECTSP_4:23;
      then a2-a1 in S /\ W by A19,A20,VECTSP_5:3;
      then a2-a1 in (0).V by A100,VECTSP_5:def 4;
      then a2-a1 = 0.V by VECTSP_4:35;
      hence x1 = x2 by RLVECT_1:21;
    end;
    take S, T;
    thus thesis by A14,P1,X1,FUNCT_2:19;
  end;
