reserve x for set;

theorem Th10:
  for L being LATTICE holds
  (ex K being full Sublattice of L st M_3,K are_isomorphic) iff
  ex a,b,c,d,e being Element of L st a,b,c,d,e are_mutually_distinct &
  a"/\"b = a & a"/\"c = a & a"/\"d = a & b"/\"e = b & c"/\"e = c &
  d"/\"e = d & b"/\"c = a & b"/\"d = a & c"/\"d = a & b"\/"c = e &
  b"\/"d = e & c"\/"d = e
proof
  set cn = the carrier of M_3;
  let L be LATTICE;
A1: cn = {0, 1, 2 \ 1 , 3 \ 2, 3} by YELLOW_1:1;
  thus (ex K being full Sublattice of L st M_3,K are_isomorphic) implies ex a,
b,c,d,e being Element of L st a,b,c,d,e are_mutually_distinct &
a"/\"b = a & a"/\"c = a & a"/\"d = a & b"/\"e = b & c
"/\"e = c & d"/\"e = d & b"/\"c = a & b"/\"d = a & c"/\"d = a & b"\/"c = e & b
  "\/"d = e & c"\/"d = e
  proof
    reconsider td = 3\2 as Element of M_3 by A1,ENUMSET1:def 3;
    reconsider dj = 2\1 as Element of M_3 by A1,ENUMSET1:def 3;
    reconsider t = 3 as Element of M_3 by A1,ENUMSET1:def 3;
    reconsider j = 1 as Element of M_3 by A1,ENUMSET1:def 3;
    reconsider cl = the carrier of L as non empty set;
    reconsider z = 0 as Element of M_3 by A1,ENUMSET1:def 3;
    given K being full Sublattice of L such that
A2: M_3,K are_isomorphic;
    consider f being Function of M_3,K such that
A3: f is isomorphic by A2;
A4: K is non empty by A3,WAYBEL_0:def 38;
    then
A5: f is one-to-one monotone by A3,WAYBEL_0:def 38;
    reconsider K as non empty SubRelStr of L by A3,WAYBEL_0:def 38;
    reconsider ck = the carrier of K as non empty set;
A6: ck = rng f by A3,WAYBEL_0:66;
    reconsider g=f as Function of cn,ck;
    reconsider a=g.z,b=g.j,c =g.dj,d=g.td,e=g.t as Element of K;
    reconsider ck as non empty Subset of cl by YELLOW_0:def 13;
A7: b in ck;
A8: c in ck;
A9: e in ck;
A10: d in ck;
    a in ck;
    then reconsider A=a,B=b,C=c,D=d,E=e as Element of L by A7,A8,A10,A9;
    take A,B,C,D,E;
    thus A<>B by A5,WAYBEL_1:def 1;
    thus A<>C by A5,Th2,WAYBEL_1:def 1;
    thus A<>D by A5,Th4,WAYBEL_1:def 1;
    thus A<>E by A5,WAYBEL_1:def 1;
    now
      assume f.j = f.dj;
      then j = dj by A4,A5,WAYBEL_1:def 1;
      then 1 in 1 by Th2,TARSKI:def 1;
      hence contradiction;
    end;
    hence B<>C;
    now
      assume f.j = f.td;
      then
A11:  j = td by A4,A5,WAYBEL_1:def 1;
      0 in j by CARD_1:49,TARSKI:def 1;
      hence contradiction by A11,Th4,TARSKI:def 1;
    end;
    hence B<>D;
    thus B<>E by A5,WAYBEL_1:def 1;
    now
      assume f.dj = f.td;
      then
A12:  dj = td by A4,A5,WAYBEL_1:def 1;
      1 in dj by Th2,TARSKI:def 1;
      hence contradiction by A12,Th4,TARSKI:def 1;
    end;
    hence C<>D;
    now
      assume f.dj = f.t;
      then
A13:  dj = t by A4,A5,WAYBEL_1:def 1;
      0 in t by CARD_1:51,ENUMSET1:def 1;
      hence contradiction by A13,Th2,TARSKI:def 1;
    end;
    hence C<>E;
    now
      assume f.td = f.t;
      then
A14:  td = t by A4,A5,WAYBEL_1:def 1;
      0 in t by CARD_1:51,ENUMSET1:def 1;
      hence contradiction by A14,Th4,TARSKI:def 1;
    end;
    hence D<>E;
    z c= j;
    then z <= j by YELLOW_1:3;
    then a <= b by A3,WAYBEL_0:66;
    then A <= B by YELLOW_0:59;
    hence A "/\" B = A by YELLOW_0:25;
    z c= dj;
    then z <= dj by YELLOW_1:3;
    then a <= c by A3,WAYBEL_0:66;
    then A <= C by YELLOW_0:59;
    hence A "/\" C = A by YELLOW_0:25;
    z c= td;
    then z <= td by YELLOW_1:3;
    then a <= d by A3,WAYBEL_0:66;
    then A <= D by YELLOW_0:59;
    hence A "/\" D = A by YELLOW_0:25;
    Segm 1 c= Segm 3 by NAT_1:39;
    then j <= t by YELLOW_1:3;
    then b <= e by A3,WAYBEL_0:66;
    then B <= E by YELLOW_0:59;
    hence B "/\" E = B by YELLOW_0:25;
    dj c= t
    proof
      let x be object;
      assume x in dj;
      then x=1 by Th2,TARSKI:def 1;
      hence thesis by CARD_1:51,ENUMSET1:def 1;
    end;
    then dj <= t by YELLOW_1:3;
    then c <= e by A3,WAYBEL_0:66;
    then C <= E by YELLOW_0:59;
    hence C"/\"E = C by YELLOW_0:25;
    td <= t by YELLOW_1:3;
    then d <= e by A3,WAYBEL_0:66;
    then D <= E by YELLOW_0:59;
    hence D"/\"E = D by YELLOW_0:25;
    thus B"/\"C = A
    proof
A15:  now
        assume B"/\"C = D;
        then D <= C by YELLOW_0:23;
        then d <= c by YELLOW_0:60;
        then td <= dj by A3,WAYBEL_0:66;
        then
A16:    td c= dj by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A16,Th2,TARSKI:def 1;
      end;
A17:  now
        assume B"/\"C = B;
        then B <= C by YELLOW_0:25;
        then b <= c by YELLOW_0:60;
        then j <= dj by A3,WAYBEL_0:66;
        then
A18:    j c= dj by YELLOW_1:3;
        0 in j by CARD_1:49,TARSKI:def 1;
        hence contradiction by A18,Th2,TARSKI:def 1;
      end;
A19:  now
        assume B"/\"C = E;
        then E <= C by YELLOW_0:23;
        then e <= c by YELLOW_0:60;
        then t <= dj by A3,WAYBEL_0:66;
        then
A20:    t c= dj by YELLOW_1:3;
        2 in t by CARD_1:51,ENUMSET1:def 1;
        hence contradiction by A20,Th2,TARSKI:def 1;
      end;
A21:  now
        assume B"/\"C = C;
        then C <= B by YELLOW_0:25;
        then c <= b by YELLOW_0:60;
        then dj <= j by A3,WAYBEL_0:66;
        then
A22:    dj c= j by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A22,CARD_1:49,TARSKI:def 1;
      end;
      ex_inf_of {B,C},L by YELLOW_0:21;
      then inf{B,C} in the carrier of K by YELLOW_0:def 16;
      then B"/\"C in rng f by A6,YELLOW_0:40;
      then ex x being object st x in dom f & B"/\"C = f.x by FUNCT_1:def 3;
      hence thesis by A1,A17,A21,A15,A19,ENUMSET1:def 3;
    end;
    thus B"/\"D = A
    proof
A23:  now
        assume B"/\"D = D;
        then D <= B by YELLOW_0:23;
        then d <= b by YELLOW_0:60;
        then td <= j by A3,WAYBEL_0:66;
        then
A24:    td c= j by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A24,CARD_1:49,TARSKI:def 1;
      end;
A25:  now
        assume B"/\"D = C;
        then C <= B by YELLOW_0:23;
        then c <= b by YELLOW_0:60;
        then dj <= j by A3,WAYBEL_0:66;
        then
A26:    dj c= j by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A26,CARD_1:49,TARSKI:def 1;
      end;
A27:  now
        assume B"/\"D = B;
        then B <= D by YELLOW_0:25;
        then b <= d by YELLOW_0:60;
        then j <= td by A3,WAYBEL_0:66;
        then
A28:    j c= td by YELLOW_1:3;
        0 in j by CARD_1:49,TARSKI:def 1;
        hence contradiction by A28,Th4,TARSKI:def 1;
      end;
A29:  now
        assume B"/\"D = E;
        then E <= B by YELLOW_0:23;
        then e <= b by YELLOW_0:60;
        then t <= j by A3,WAYBEL_0:66;
        then
A30:    t c= j by YELLOW_1:3;
        2 in t by CARD_1:51,ENUMSET1:def 1;
        hence contradiction by A30,CARD_1:49,TARSKI:def 1;
      end;
      ex_inf_of {B,D},L by YELLOW_0:21;
      then inf{B,D} in the carrier of K by YELLOW_0:def 16;
      then B"/\"D in rng f by A6,YELLOW_0:40;
      then ex x being object st x in dom f & B"/\"D = f.x by FUNCT_1:def 3;
      hence thesis by A1,A27,A25,A23,A29,ENUMSET1:def 3;
    end;
    thus C"/\"D = A
    proof
A31:  now
        assume C"/\"D = D;
        then D <= C by YELLOW_0:23;
        then d <= c by YELLOW_0:60;
        then td <= dj by A3,WAYBEL_0:66;
        then
A32:    td c= dj by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A32,Th2,TARSKI:def 1;
      end;
A33:  now
        assume C"/\"D = E;
        then E <= C by YELLOW_0:23;
        then e <= c by YELLOW_0:60;
        then t <= dj by A3,WAYBEL_0:66;
        then
A34:    t c= dj by YELLOW_1:3;
        2 in t by CARD_1:51,ENUMSET1:def 1;
        hence contradiction by A34,Th2,TARSKI:def 1;
      end;
A35:  now
        assume C"/\"D = C;
        then C <= D by YELLOW_0:25;
        then c <= d by YELLOW_0:60;
        then dj <= td by A3,WAYBEL_0:66;
        then
A36:    dj c= td by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A36,Th4,TARSKI:def 1;
      end;
A37:  now
        assume C"/\"D = B;
        then B <= C by YELLOW_0:23;
        then b <= c by YELLOW_0:60;
        then j <= dj by A3,WAYBEL_0:66;
        then
A38:    j c= dj by YELLOW_1:3;
        0 in j by CARD_1:49,TARSKI:def 1;
        hence contradiction by A38,Th2,TARSKI:def 1;
      end;
      ex_inf_of {C,D},L by YELLOW_0:21;
      then inf{C,D} in the carrier of K by YELLOW_0:def 16;
      then C"/\"D in rng f by A6,YELLOW_0:40;
      then ex x being object st x in dom f & C"/\"D = f.x by FUNCT_1:def 3;
      hence thesis by A1,A37,A35,A31,A33,ENUMSET1:def 3;
    end;
    thus B"\/"C = E
    proof
A39:  now
        assume B"\/"C = C;
        then C >= B by YELLOW_0:24;
        then c >= b by YELLOW_0:60;
        then dj >= j by A3,WAYBEL_0:66;
        then
A40:    j c= dj by YELLOW_1:3;
        0 in j by CARD_1:49,TARSKI:def 1;
        hence contradiction by A40,Th2,TARSKI:def 1;
      end;
A41:  now
        assume B"\/"C = B;
        then B >= C by YELLOW_0:24;
        then b >= c by YELLOW_0:60;
        then j >= dj by A3,WAYBEL_0:66;
        then
A42:    dj c= j by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A42,CARD_1:49,TARSKI:def 1;
      end;
A43:  now
        assume B"\/"C = D;
        then D >= C by YELLOW_0:22;
        then d >= c by YELLOW_0:60;
        then td >= dj by A3,WAYBEL_0:66;
        then
A44:    dj c= td by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A44,Th4,TARSKI:def 1;
      end;
A45:  now
        assume B"\/"C = A;
        then A >= C by YELLOW_0:22;
        then a >= c by YELLOW_0:60;
        then z >= dj by A3,WAYBEL_0:66;
        then dj c= z by YELLOW_1:3;
        hence contradiction by Th2;
      end;
      ex_sup_of {B,C},L by YELLOW_0:20;
      then sup{B,C} in the carrier of K by YELLOW_0:def 17;
      then B"\/"C in rng f by A6,YELLOW_0:41;
      then ex x being object st x in dom f & B"\/"C = f.x by FUNCT_1:def 3;
      hence thesis by A1,A41,A39,A43,A45,ENUMSET1:def 3;
    end;
    thus B"\/"D = E
    proof
A46:  now
        assume B"\/"D = D;
        then D >= B by YELLOW_0:22;
        then d >= b by YELLOW_0:60;
        then td >= j by A3,WAYBEL_0:66;
        then
A47:    j c= td by YELLOW_1:3;
        0 in j by CARD_1:49,TARSKI:def 1;
        hence contradiction by A47,Th4,TARSKI:def 1;
      end;
A48:  now
        assume B"\/"D = B;
        then B >= D by YELLOW_0:22;
        then b >= d by YELLOW_0:60;
        then j >= td by A3,WAYBEL_0:66;
        then
A49:    td c= j by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A49,CARD_1:49,TARSKI:def 1;
      end;
A50:  now
        assume B"\/"D = C;
        then C >= D by YELLOW_0:22;
        then c >= d by YELLOW_0:60;
        then dj >= td by A3,WAYBEL_0:66;
        then
A51:    td c= dj by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A51,Th2,TARSKI:def 1;
      end;
A52:  now
        assume B"\/"D = A;
        then A >= B by YELLOW_0:22;
        then a >= b by YELLOW_0:60;
        then z >= j by A3,WAYBEL_0:66;
        then j c= z by YELLOW_1:3;
        hence contradiction;
      end;
      ex_sup_of {B,D},L by YELLOW_0:20;
      then sup{B,D} in the carrier of K by YELLOW_0:def 17;
      then B"\/"D in rng f by A6,YELLOW_0:41;
      then ex x being object st x in dom f & B"\/"D = f.x by FUNCT_1:def 3;
      hence thesis by A1,A48,A50,A46,A52,ENUMSET1:def 3;
    end;
    thus C"\/"D = E
    proof
A53:  now
        assume C"\/"D = B;
        then B >= C by YELLOW_0:22;
        then b >= c by YELLOW_0:60;
        then j >= dj by A3,WAYBEL_0:66;
        then
A54:    dj c= j by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        then 1 in 1 by A54;
        hence contradiction;
      end;
A55:  now
        assume C"\/"D = D;
        then D >= C by YELLOW_0:22;
        then d >= c by YELLOW_0:60;
        then td >= dj by A3,WAYBEL_0:66;
        then
A56:    dj c= td by YELLOW_1:3;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A56,Th4,TARSKI:def 1;
      end;
A57:  now
        assume C"\/"D = C;
        then C >= D by YELLOW_0:24;
        then c >= d by YELLOW_0:60;
        then dj >= td by A3,WAYBEL_0:66;
        then
A58:    td c= dj by YELLOW_1:3;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A58,Th2,TARSKI:def 1;
      end;
A59:  now
        assume C"\/"D = A;
        then A >= C by YELLOW_0:22;
        then a >= c by YELLOW_0:60;
        then z >= dj by A3,WAYBEL_0:66;
        then dj c= z by YELLOW_1:3;
        hence contradiction by Th2;
      end;
      ex_sup_of {C,D},L by YELLOW_0:20;
      then sup{C,D} in the carrier of K by YELLOW_0:def 17;
      then C"\/"D in rng f by A6,YELLOW_0:41;
      then ex x being object st x in dom f & C"\/"D = f.x by FUNCT_1:def 3;
      hence thesis by A1,A53,A57,A55,A59,ENUMSET1:def 3;
    end;
  end;
  thus (ex a,b,c,d,e being Element of L st (a,b,c,d,e are_mutually_distinct &
  a"/\"b = a & a"/\"c = a & a"/\"d = a & b
"/\"e = b & c"/\"e = c & d"/\"e = d & b"/\"c = a & b"/\"d = a & c"/\"d = a & b
"\/"c = e & b"\/"d = e & c"\/" d = e)) implies ex K being full Sublattice of L
  st M_3,K are_isomorphic
  proof
    given a,b,c,d,e being Element of L such that
AAA: a,b,c,d,e are_mutually_distinct and
A70: a"/\"b = a and
A71: a"/\"c = a and
A72: a"/\"d = a and
A73: b"/\"e = b and
A74: c"/\"e = c and
A75: d"/\" e = d and
A76: b"/\"c = a and
A77: b"/\"d = a and
A78: c"/\"d = a and
A79: b"\/"c = e and
A80: b"\/"d = e and
A81: c"\/" d = e;
    set ck = {a,b,c,d,e};
    reconsider ck as Subset of L;
    set K = subrelstr ck;
A82: the carrier of K = ck by YELLOW_0:def 15;
A83: K is meet-inheriting
    proof
      let x,y be Element of L;
      assume that
A84:  x in the carrier of K and
A85:  y in the carrier of K and
      ex_inf_of {x,y},L;
      per cases by A82,A84,A85,ENUMSET1:def 3;
      suppose
        x=a & y=a;
        then inf{x,y} = a"/\"a by YELLOW_0:40;
        then inf{x,y} = a by YELLOW_5:2;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=b;
        then inf{x,y} = a"/\"b by YELLOW_0:40;
        hence thesis by A70,A82,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=c;
        then inf{x,y} = a"/\"c by YELLOW_0:40;
        hence thesis by A71,A82,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=d;
        then inf{x,y} = a"/\"d by YELLOW_0:40;
        hence thesis by A72,A82,ENUMSET1:def 3;
      end;
      suppose
A86:    x=a & y=e;
A87:    c <= e by A74,YELLOW_0:25;
        a <= c by A71,YELLOW_0:25;
        then a <= e by A87,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then inf {x,y} = a by A86,YELLOW_0:40;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=a;
        then inf{x,y} = a"/\"b by YELLOW_0:40;
        hence thesis by A70,A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=b;
        then inf{x,y} = b"/\"b by YELLOW_0:40;
        then inf{x,y} = b by YELLOW_5:2;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=c;
        then inf{x,y} = b"/\"c by YELLOW_0:40;
        hence thesis by A76,A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=d;
        then inf{x,y} = b"/\"d by YELLOW_0:40;
        hence thesis by A77,A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=e;
        then inf{x,y} = b"/\"e by YELLOW_0:40;
        hence thesis by A73,A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=a;
        then inf{x,y} = a"/\"c by YELLOW_0:40;
        hence thesis by A71,A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=b;
        then inf{x,y} = b"/\"c by YELLOW_0:40;
        hence thesis by A76,A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=c;
        then inf{x,y} = c"/\"c by YELLOW_0:40;
        then inf{x,y} = c by YELLOW_5:2;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=d;
        then inf{x,y} = c"/\"d by YELLOW_0:40;
        hence thesis by A78,A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=e;
        then inf{x,y} = c"/\"e by YELLOW_0:40;
        hence thesis by A74,A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=a;
        then inf{x,y} = a"/\"d by YELLOW_0:40;
        hence thesis by A72,A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=b;
        then inf{x,y} = b"/\"d by YELLOW_0:40;
        hence thesis by A77,A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=c;
        then inf{x,y} = c"/\"d by YELLOW_0:40;
        hence thesis by A78,A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=d;
        then inf{x,y} = d"/\"d by YELLOW_0:40;
        then inf{x,y} = d by YELLOW_5:2;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=e;
        then inf{x,y} = d"/\"e by YELLOW_0:40;
        hence thesis by A75,A82,ENUMSET1:def 3;
      end;
      suppose
A88:    x=e & y=a;
A89:    c <= e by A74,YELLOW_0:25;
        a <= c by A71,YELLOW_0:25;
        then a <= e by A89,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then inf {x,y} = a by A88,YELLOW_0:40;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=b;
        then inf{x,y} = b"/\"e by YELLOW_0:40;
        hence thesis by A73,A82,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=c;
        then inf{x,y} = c"/\"e by YELLOW_0:40;
        hence thesis by A74,A82,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=d;
        then inf{x,y} = d"/\"e by YELLOW_0:40;
        hence thesis by A75,A82,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=e;
        then inf{x,y} = e"/\"e by YELLOW_0:40;
        then inf{x,y} = e by YELLOW_5:2;
        hence thesis by A82,ENUMSET1:def 3;
      end;
    end;
    K is join-inheriting
    proof
      let x,y be Element of L;
      assume that
A90:  x in the carrier of K and
A91:  y in the carrier of K and
      ex_sup_of {x,y},L;
      per cases by A82,A90,A91,ENUMSET1:def 3;
      suppose
        x=a & y=a;
        then sup{x,y} = a"\/"a by YELLOW_0:41;
        then sup{x,y} = a by YELLOW_5:1;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=b;
        then x"\/"y = b by A70,Th5;
        then sup{x,y} = b by YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=c;
        then x"\/"y = c by A71,Th5;
        then sup{x,y} = c by YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=a & y=d;
        then x"\/"y = d by A72,Th5;
        then sup{x,y} = d by YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A92:    x=a & y=e;
A93:    c <= e by A74,YELLOW_0:25;
        a <= c by A71,YELLOW_0:25;
        then a <= e by A93,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then a"\/"e = e by Th5;
        then sup {x,y} = e by A92,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A94:    x=b & y=a;
        a"\/"b = b by A70,Th5;
        then sup{x,y} = b by A94,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=b;
        then sup{x,y} = b"\/"b by YELLOW_0:41;
        then sup{x,y} = b by YELLOW_5:1;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=c;
        then sup{x,y} = b"\/"c by YELLOW_0:41;
        hence thesis by A79,A82,ENUMSET1:def 3;
      end;
      suppose
        x=b & y=d;
        then sup{x,y} = b"\/"d by YELLOW_0:41;
        hence thesis by A80,A82,ENUMSET1:def 3;
      end;
      suppose
A95:    x=b & y=e;
        b"\/"e = e by A73,Th5;
        then sup{x,y} = e by A95,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A96:    x=c & y=a;
        c"\/"a = c by A71,Th5;
        then sup{x,y} = c by A96,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=b;
        then sup{x,y} = b"\/"c by YELLOW_0:41;
        hence thesis by A79,A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=c;
        then sup{x,y} = c"\/"c by YELLOW_0:41;
        then sup{x,y} = c by YELLOW_5:1;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=c & y=d;
        then sup{x,y} = c"\/"d by YELLOW_0:41;
        hence thesis by A81,A82,ENUMSET1:def 3;
      end;
      suppose
A97:    x=c & y=e;
        c"\/"e = e by A74,Th5;
        then sup{x,y} = e by A97,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=a;
        then x"\/"y = d by A72,Th5;
        then sup{x,y} = d by YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=b;
        then sup{x,y} = b"\/"d by YELLOW_0:41;
        hence thesis by A80,A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=c;
        then sup{x,y} = c"\/"d by YELLOW_0:41;
        hence thesis by A81,A82,ENUMSET1:def 3;
      end;
      suppose
        x=d & y=d;
        then sup{x,y} = d"\/"d by YELLOW_0:41;
        then sup{x,y} = d by YELLOW_5:1;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A98:    x=d & y=e;
        d"\/"e = e by A75,Th5;
        then sup{x,y} = e by A98,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A99:    x=e & y=a;
A100:   c <= e by A74,YELLOW_0:25;
        a <= c by A71,YELLOW_0:25;
        then a <= e by A100,ORDERS_2:3;
        then a"/\"e = a by YELLOW_0:25;
        then a"\/"e = e by Th5;
        then sup {x,y} = e by A99,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A101:   x=e & y=b;
        b"\/"e = e by A73,Th5;
        then sup{x,y} = e by A101,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A102:   x=e & y=c;
        c"\/"e = e by A74,Th5;
        then sup{x,y} = e by A102,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
A103:   x=e & y=d;
        d"\/"e = e by A75,Th5;
        then sup{x,y} = e by A103,YELLOW_0:41;
        hence thesis by A82,ENUMSET1:def 3;
      end;
      suppose
        x=e & y=e;
        then sup{x,y} = e"\/"e by YELLOW_0:41;
        then sup{x,y} = e by YELLOW_5:1;
        hence thesis by A82,ENUMSET1:def 3;
      end;
    end;
    then reconsider K as non empty full Sublattice of L by A83,YELLOW_0:def 15;
    take K;
    thus M_3,K are_isomorphic
    proof
      reconsider t = 3 as Element of M_3 by A1,ENUMSET1:def 3;
      reconsider td = 3\2 as Element of M_3 by A1,ENUMSET1:def 3;
      reconsider dj = 2\1 as Element of M_3 by A1,ENUMSET1:def 3;
A104: now
A105:   2 in t by CARD_1:51,ENUMSET1:def 1;
        assume dj=t;
        hence contradiction by A105,Th2,TARSKI:def 1;
      end;
A106: now
A107:   0 in t by CARD_1:51,ENUMSET1:def 1;
        assume td=t;
        hence contradiction by A107,Th4,TARSKI:def 1;
      end;
      reconsider j = 1 as Element of M_3 by A1,ENUMSET1:def 3;
      reconsider z = 0 as Element of M_3 by A1,ENUMSET1:def 3;
      defpred P[object,object] means
for X being Element of M_3 st X=$1 holds ((X =
z implies $2 = a) & (X = j implies $2 = b) & (X = dj implies $2 = c) & (X = td
      implies $2 = d) & (X = t implies $2 = e));
A108: now
        assume
A109:   j=dj;
        1 in dj by Th2,TARSKI:def 1;
        hence contradiction by A109;
      end;
A110: now
        assume
A111:   j=td;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A111,CARD_1:49,TARSKI:def 1;
      end;
A112: now
        assume
A113:   dj=td;
        2 in td by Th4,TARSKI:def 1;
        hence contradiction by A113,Th2,TARSKI:def 1;
      end;
A114: for x being object st x in cn ex y being object st y in ck & P[x,y]
      proof
        let x be object;
        assume
A115:   x in cn;
        per cases by A1,A115,ENUMSET1:def 3;
        suppose
A116:     x = 0;
          take y=a;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of M_3;
          thus thesis by A116,Th2,Th4;
        end;
        suppose
A117:     x=1;
          take y=b;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of M_3;
          thus thesis by A108,A110,A117;
        end;
        suppose
A118:     x = 2\1;
          take y=c;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of M_3;
          thus thesis by A108,A112,A104,A118,Th2;
        end;
        suppose
A119:     x = 3 \ 2;
          take y=d;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of M_3;
          thus thesis by A110,A112,A106,A119,Th4;
        end;
        suppose
A120:     x = 3;
          take y=e;
          thus y in ck by ENUMSET1:def 3;
          let X be Element of M_3;
          thus thesis by A104,A106,A120;
        end;
      end;
      consider f being Function of cn,ck such that
A121: for x being object st x in cn holds P[x,f.x] from FUNCT_2:sch 1(
      A114);
      reconsider f as Function of M_3,K by A82;
A122: now
        let x,y be Element of M_3;
        assume
A123:   f.x = f.y;
        thus x=y
        proof
          per cases by A1,ENUMSET1:def 3;
          suppose
            x = z & y = z;
            hence thesis;
          end;
          suppose
            x = j & y = j;
            hence thesis;
          end;
          suppose
            x = dj & y = dj;
            hence thesis;
          end;
          suppose
            x = td & y = td;
            hence thesis;
          end;
          suppose
            x = t & y = t;
            hence thesis;
          end;
          suppose
A124:       x = z & y = j;
            then f.x=a by A121;
            hence thesis by AAA,A121,A123,A124;
          end;
          suppose
A125:       x = z & y = dj;
            then f.x=a by A121;
            hence thesis by AAA,A121,A123,A125;
          end;
          suppose
A126:       x = z & y = td;
            then f.x=a by A121;
            hence thesis by AAA,A121,A123,A126;
          end;
          suppose
A127:       x = z & y = t;
            then f.x=a by A121;
            hence thesis by AAA,A121,A123,A127;
          end;
          suppose
A128:       x = j & y = z;
            then f.x=b by A121;
            hence thesis by AAA,A121,A123,A128;
          end;
          suppose
A129:       x = j & y = dj;
            then f.x=b by A121;
            hence thesis by AAA,A121,A123,A129;
          end;
          suppose
A130:       x = j & y = td;
            then f.x=b by A121;
            hence thesis by AAA,A121,A123,A130;
          end;
          suppose
A131:       x = j & y = t;
            then f.x=b by A121;
            hence thesis by AAA,A121,A123,A131;
          end;
          suppose
A132:       x = dj & y = z;
            then f.x=c by A121;
            hence thesis by AAA,A121,A123,A132;
          end;
          suppose
A133:       x = dj & y = j;
            then f.x=c by A121;
            hence thesis by AAA,A121,A123,A133;
          end;
          suppose
A134:       x = dj & y = td;
            then f.x=c by A121;
            hence thesis by AAA,A121,A123,A134;
          end;
          suppose
A135:       x = dj & y = t;
            then f.x=c by A121;
            hence thesis by AAA,A121,A123,A135;
          end;
          suppose
A136:       x = td & y = z;
            then f.x=d by A121;
            hence thesis by AAA,A121,A123,A136;
          end;
          suppose
A137:       x = td & y = j;
            then f.x=d by A121;
            hence thesis by AAA,A121,A123,A137;
          end;
          suppose
A138:       x = td & y = dj;
            then f.x=d by A121;
            hence thesis by AAA,A121,A123,A138;
          end;
          suppose
A139:       x = td & y = t;
            then f.x=d by A121;
            hence thesis by AAA,A121,A123,A139;
          end;
          suppose
A140:       x = t & y = z;
            then f.x=e by A121;
            hence thesis by AAA,A121,A123,A140;
          end;
          suppose
A141:       x = t & y = j;
            then f.x=e by A121;
            hence thesis by AAA,A121,A123,A141;
          end;
          suppose
A142:       x = t & y = dj;
            then f.x=e by A121;
            hence thesis by AAA,A121,A123,A142;
          end;
          suppose
A143:       x = t & y = td;
            then f.x=e by A121;
            hence thesis by AAA,A121,A123,A143;
          end;
        end;
      end;
A144: rng f c= ck
      proof
        let y be object;
        assume y in rng f;
        then consider x being object such that
A145:   x in dom f and
A146:   y=f.x by FUNCT_1:def 3;
        reconsider x as Element of M_3 by A145;
        x = z or x = j or x = dj or x = td or x = t by A1,ENUMSET1:def 3;
        then y=a or y=d or y=c or y=b or y=e by A121,A146;
        hence thesis by ENUMSET1:def 3;
      end;
A147: dom f = the carrier of M_3 by FUNCT_2:def 1;
      ck c= rng f
      proof
        let y be object;
        assume
A148:   y in ck;
        per cases by A148,ENUMSET1:def 3;
        suppose
A149:     y=a;
          a = f.z by A121;
          hence thesis by A147,A149,FUNCT_1:def 3;
        end;
        suppose
A150:     y=b;
          b=f.j by A121;
          hence thesis by A147,A150,FUNCT_1:def 3;
        end;
        suppose
A151:     y=c;
          c = f.dj by A121;
          hence thesis by A147,A151,FUNCT_1:def 3;
        end;
        suppose
A152:     y=d;
          d=f.td by A121;
          hence thesis by A147,A152,FUNCT_1:def 3;
        end;
        suppose
A153:     y=e;
          e=f.t by A121;
          hence thesis by A147,A153,FUNCT_1:def 3;
        end;
      end;
      then
A154: rng f = ck by A144;
A155: for x,y being Element of M_3 holds x <= y iff f.x <= f.y
      proof
        let x,y be Element of M_3;
        thus x <= y implies f.x <= f.y
        proof
          assume
A156:     x <= y;
          per cases by A1,ENUMSET1:def 3;
          suppose
            x=z & y=z;
            hence thesis;
          end;
          suppose
A157:       x=z & y=j;
            then
A158:       f.y = b by A121;
A159:       a <= b by A70,YELLOW_0:25;
            f.x = a by A121,A157;
            hence thesis by A158,A159,YELLOW_0:60;
          end;
          suppose
A160:       x=z & y=dj;
            then
A161:       f.y = c by A121;
A162:       a <= c by A71,YELLOW_0:25;
            f.x = a by A121,A160;
            hence thesis by A161,A162,YELLOW_0:60;
          end;
          suppose
A163:       x=z & y=td;
            then
A164:       f.y = d by A121;
A165:       a <= d by A72,YELLOW_0:25;
            f.x = a by A121,A163;
            hence thesis by A164,A165,YELLOW_0:60;
          end;
          suppose
A166:       x=z & y=t;
A167:       c <= e by A74,YELLOW_0:25;
            a <= c by A71,YELLOW_0:25;
            then
A168:       a <= e by A167,ORDERS_2:3;
A169:       f.y = e by A121,A166;
            f.x = a by A121,A166;
            hence thesis by A169,A168,YELLOW_0:60;
          end;
          suppose
            x=j & y=z;
            then j c= z by A156,YELLOW_1:3;
            hence thesis;
          end;
          suppose
            x=j & y=j;
            hence thesis;
          end;
          suppose
A170:       x=j & y=dj;
            0 in j by CARD_1:49,TARSKI:def 1;
            then not j c= dj by Th2,TARSKI:def 1;
            hence thesis by A156,A170,YELLOW_1:3;
          end;
          suppose
A171:       x=j & y=td;
            0 in j by CARD_1:49,TARSKI:def 1;
            then not j c= td by Th4,TARSKI:def 1;
            hence thesis by A156,A171,YELLOW_1:3;
          end;
          suppose
A172:       x=j & y=t;
            then
A173:       f.y = e by A121;
A174:       b <= e by A73,YELLOW_0:25;
            f.x = b by A121,A172;
            hence thesis by A173,A174,YELLOW_0:60;
          end;
          suppose
            x=dj & y=z;
            then dj c= z by A156,YELLOW_1:3;
            hence thesis by Th2;
          end;
          suppose
A175:       x=dj & y=j;
A176:       not 1 in j;
            1 in dj by Th2,TARSKI:def 1;
            then not dj c= j by A176;
            hence thesis by A156,A175,YELLOW_1:3;
          end;
          suppose
            x=dj & y=dj;
            hence thesis;
          end;
          suppose
A177:       x=dj & y=td;
            1 in dj by Th2,TARSKI:def 1;
            then not dj c= td by Th4,TARSKI:def 1;
            hence thesis by A156,A177,YELLOW_1:3;
          end;
          suppose
A178:       x=dj & y=t;
            then
A179:       f.y = e by A121;
A180:       c <= e by A74,YELLOW_0:25;
            f.x = c by A121,A178;
            hence thesis by A179,A180,YELLOW_0:60;
          end;
          suppose
            x=td & y=z;
            then td c= z by A156,YELLOW_1:3;
            hence thesis by Th4;
          end;
          suppose
A181:       x=td & y=j;
            2 in td by Th4,TARSKI:def 1;
            then not td c= j by CARD_1:49,TARSKI:def 1;
            hence thesis by A156,A181,YELLOW_1:3;
          end;
          suppose
A182:       x=td & y=dj;
            2 in td by Th4,TARSKI:def 1;
            then not td c= dj by Th2,TARSKI:def 1;
            hence thesis by A156,A182,YELLOW_1:3;
          end;
          suppose
            x=td & y=td;
            hence thesis;
          end;
          suppose
A183:       x=td & y=t;
            then
A184:       f.y = e by A121;
A185:       d <= e by A75,YELLOW_0:25;
            f.x = d by A121,A183;
            hence thesis by A184,A185,YELLOW_0:60;
          end;
          suppose
            x=t & y=z;
            then t c= z by A156,YELLOW_1:3;
            hence thesis;
          end;
          suppose
A186:       x=t & y=j;
A187:       not 1 in j;
            1 in t by CARD_1:51,ENUMSET1:def 1;
            then not t c= j by A187;
            hence thesis by A156,A186,YELLOW_1:3;
          end;
          suppose
A188:       x=t & y=dj;
            2 in t by CARD_1:51,ENUMSET1:def 1;
            then not t c= dj by Th2,TARSKI:def 1;
            hence thesis by A156,A188,YELLOW_1:3;
          end;
          suppose
A189:       x=t & y=td;
            0 in t by CARD_1:51,ENUMSET1:def 1;
            then not t c= td by Th4,TARSKI:def 1;
            hence thesis by A156,A189,YELLOW_1:3;
          end;
          suppose
            x=t & y=t;
            hence thesis;
          end;
        end;
        thus f.x <= f.y implies x <= y
        proof
A190:     dj c= t
          proof
            let X be object;
            assume X in dj;
            then X=1 by Th2,TARSKI:def 1;
            hence thesis by CARD_1:51,ENUMSET1:def 1;
          end;
A191:     f.y in ck by A147,A154,FUNCT_1:def 3;
A192:     f.x in ck by A147,A154,FUNCT_1:def 3;
          assume
A193:     f.x <= f.y;
          per cases by A192,A191,ENUMSET1:def 3;
          suppose
            f.x = a & f.y = a;
            hence thesis by A122;
          end;
          suppose
A194:       f.x = a & f.y = b;
            f.z = a by A121;
            then z=x by A122,A194;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A195:       f.x = a & f.y = c;
            f.z = a by A121;
            then z=x by A122,A195;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A196:       f.x = a & f.y = d;
            f.z = a by A121;
            then z=x by A122,A196;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
A197:       f.x = a & f.y = e;
            f.z = a by A121;
            then z=x by A122,A197;
            then x c= y;
            hence thesis by YELLOW_1:3;
          end;
          suppose
            f.x = b & f.y = a;
            then b <= a by A193,YELLOW_0:59;
            hence thesis by AAA,A70,YELLOW_0:25;
          end;
          suppose
            f.x = b & f.y = b;
            hence thesis by A122;
          end;
          suppose
            f.x = b & f.y = c;
            then b <= c by A193,YELLOW_0:59;
            hence thesis by AAA,A76,YELLOW_0:25;
          end;
          suppose
            f.x = b & f.y = d;
            then b <= d by A193,YELLOW_0:59;
            hence thesis by AAA,A77,YELLOW_0:25;
          end;
          suppose
A198:       f.x = b & f.y = e;
            f.t = e by A121;
            then
A199:       t = y by A122,A198;
            f.j = b by A121;
            then
A200:            j=x by A122,A198;
            Segm 1 c= Segm 3 by NAT_1:39;
            hence thesis by YELLOW_1:3,A200,A199;
          end;
          suppose
            f.x = c & f.y = a;
            then c <= a by A193,YELLOW_0:59;
            hence thesis by AAA,A71,YELLOW_0:25;
          end;
          suppose
            f.x = c & f.y = b;
            then c <= b by A193,YELLOW_0:59;
            hence thesis by AAA,A76,YELLOW_0:25;
          end;
          suppose
            f.x = c & f.y = c;
            hence thesis by A122;
          end;
          suppose
            f.x = c & f.y = d;
            then c <= d by A193,YELLOW_0:59;
            hence thesis by AAA,A78,YELLOW_0:25;
          end;
          suppose
A201:       f.x = c & f.y = e;
            f.t = e by A121;
            then
A202:       t = y by A122,A201;
            f.dj = c by A121;
            then dj = x by A122,A201;
            hence thesis by A190,A202,YELLOW_1:3;
          end;
          suppose
            f.x = d & f.y = a;
            then d <= a by A193,YELLOW_0:59;
            hence thesis by AAA,A72,YELLOW_0:25;
          end;
          suppose
            f.x = d & f.y = b;
            then d <= b by A193,YELLOW_0:59;
            hence thesis by AAA,A77,YELLOW_0:25;
          end;
          suppose
            f.x = d & f.y = c;
            then d <= c by A193,YELLOW_0:59;
            hence thesis by AAA,A78,YELLOW_0:25;
          end;
          suppose
            f.x = d & f.y = d;
            hence thesis by A122;
          end;
          suppose
A203:       f.x = d & f.y = e;
            f.t = e by A121;
            then
A204:       t = y by A122,A203;
            f.td = d by A121;
            then td=x by A122,A203;
            hence thesis by A204,YELLOW_1:3;
          end;
          suppose
A205:       f.x = e & f.y = a;
A206:       a <= b by A70,YELLOW_0:25;
            e <= a by A193,A205,YELLOW_0:59;
            then e <= b by A206,ORDERS_2:3;
            hence thesis by AAA,A73,YELLOW_0:25;
          end;
          suppose
            f.x = e & f.y = b;
            then e <= b by A193,YELLOW_0:59;
            hence thesis by AAA,A73,YELLOW_0:25;
          end;
          suppose
            f.x = e & f.y = c;
            then e <= c by A193,YELLOW_0:59;
            hence thesis by AAA,A74,YELLOW_0:25;
          end;
          suppose
            f.x = e & f.y = d;
            then e <= d by A193,YELLOW_0:59;
            hence thesis by AAA,A75,YELLOW_0:25;
          end;
          suppose
            f.x = e & f.y = e;
            hence thesis by A122;
          end;
        end;
      end;
      take f;
      f is one-to-one by A122;
      hence thesis by A82,A154,A155,WAYBEL_0:66;
    end;
  end;
end;
