reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;
reserve y for set,
  H19,H29 for StableSubgroup of G,
  N19 for normal StableSubgroup of H19,
  s1,s19,s2,s29 for CompositionSeries of G,
  fs for FinSequence of the_stable_subgroups_of G,
  f1,f2 for FinSequence,
  i,j,n for Nat;

theorem Th111:
  1<=i & i<=len s1-1 implies s1.i is strict StableSubgroup of G &
  s1.(i+1) is strict StableSubgroup of G
proof
  assume that
A1: 1<=i and
A2: i<=len s1-1;
A3: 0+i<=1+i by XREAL_1:6;
A4: i+1<=len s1-1+1 by A2,XREAL_1:6;
  then i<=len s1 by A3,XXREAL_0:2;
  then i in Seg len s1 by A1;
  then i in dom s1 by FINSEQ_1:def 3;
  then s1.i is Element of the_stable_subgroups_of G by FINSEQ_2:11;
  hence s1.i is strict StableSubgroup of G by Def11;
  1<=i+1 by A1,A3,XXREAL_0:2;
  then i+1 in Seg len s1 by A4;
  then i+1 in dom s1 by FINSEQ_1:def 3;
  then s1.(i+1) is Element of the_stable_subgroups_of G by FINSEQ_2:11;
  hence thesis by Def11;
end;
